「2011NOIP提高组」Mayan 游戏（Mayan Puzzle）
Mayan游戏（Mayan Puzzle）是一个较考验脑力的游戏，2011年的提高组复赛题上，我们见到了它。
CodeVS[1136]:
Mayan puzzle 是最近流行起来的一个游戏。游戏界面是一个7 行5 列的棋盘，上面堆放着一些方块，方块不能悬空堆放，即方块必须放在最下面一行，或者放在其他方块之上。游戏通关是指在规定的步数内消除所有的方块，消除方块的规则如下：
1、每步移动可以且仅可以沿横向（即向左或向右）拖动某一方块一格：当拖动这一方块时，如果拖动后到达的位置（以下称目标位置）也有方块，那么这两个方块将交换位置（参见输入输出样例说明中的图6 到图7）；如果目标位置上没有方块，那么被拖动的方块将从
原来的竖列中抽出，并从目标位置上掉落。
2、任一时刻，如果在一横行或者竖列上有连续三个或者三个以上相同颜色的方块，则
它们将立即被消除（参见图1 到图3）。
注意：
a) 如果同时有多组方块满足消除条件，几组方块会同时被消除（例如下面图4，三个颜色为1 的方块和三个颜色为2 的方块会同时被消除，最后剩下一个颜色为2 的方块）。
b) 当出现行和列都满足消除条件且行列共享某个方块时，行和列上满足消除条件的所有方块会被同时消除（例如下面图5 所示的情形，5 个方块会同时被消除）。
3、方块消除之后，消除位置之上的方块将掉落，掉落后可能会引起新的方块消除。注意：掉落的过程中将不会有方块的消除。上面图 1 到图3 给出了在棋盘上移动一块方块之后棋盘的变化。棋盘的左下角方块的坐标为（0, 0），将位于（3, 3）的方块向左移动之后，游戏界面从图1 变成图2 所示的状态，此时在一竖列上有连续三块颜色为4 的方块，满足消除条件，消除连续3 块颜色为4 的方块后，上方的颜色为3 的方块掉落，形成图3 所示的局面。
【输入输出样例说明】
样例输入的游戏局面依次移动的三步是：
（2，1）处的方格向右移动，
（3，1）处的方格向右移动，
（3，0）处的方格向右移动，最后可以将棋盘上所有方块消除。
共6 行。
第一行为一个正整数 n，表示要求游戏通关的步数。
接下来的 5 行，描述7*5 的游戏界面。每行若干个整数，每两个整数之间用一个空格隔开，每行以一个0 结束，自下向上表示每竖列方块的颜色编号（颜色不多于10 种，从1 开始顺序编号，相同数字表示相同颜色）。
输入数据保证初始棋盘中没有可以消除的方块。
如果有解决方案，输出n 行，每行包含3 个整数x，y，g，表示一次移动，每两个整数之间用一个空格隔开，其中（x，y）表示要移动的方块的坐标，g 表示移动的方向，1 表示向右移动，-1 表示向左移动。注意：多组解时，按照x 为第一关健字，y 为第二关健字，1优先于-1，给出一组字典序最小的解。游戏界面左下角的坐标为（0，0）。
如果没有解决方案，输出一行，包含一个整数-1。
3
1 0
2 1 0
2 3 4 0
3 1 0
2 4 3 4 0
2 1 1
3 1 1
3 0 1
对于 30%的数据，初始棋盘上的方块都在棋盘的最下面一行；
对于 100%的数据，0 < n ≤ 5。
［以下转自cnblog］
本题为NOIP2011day1第三题，初看题目感觉似乎挺难的，不仅是一条线上可以消掉，还有可能十字形的也可以消掉，还可能多组一起消掉，还可能会掉下来之后又可以消掉（头都大了……）。
但其实仔细分析一下，这题并不难，无论怎么消，都得要满足三个以上的方块是同颜色，于是，我们在每一次消除的时候，可以设一个数组，它相邻的两个方块和它的颜色相同的话，就代表要消除，标记起来，然后搜索一遍整个棋盘后，要消除的就全部标记了，消除即可。
然后整个深搜的过程中有一个优化，就是只需要往右边搜，（题目中说1优先于-1就是在提醒我们，往右边搜与往左边搜其实是一样的）这样也大大降低了编程复杂度，只需要判断一下如果两边有一个方格为空格的话，就判断哪个是空格（不能移动空格，因此如果左边为空格就需要记录-1），如果两边都为空格的话就没必要移动了（移了也是白移，浪费步数，相信没人玩游戏的时候会这么傻）。还有最重要的一点，请看题目描述中的加粗字（这不是我加粗的，是题目本身加粗的），这意味着什么？你是不是很头疼还要算一算步数？可实际上，数据告诉我们，这不是计算机学会做过的数据就是题目描述有问题！
Pascal代码：
type
arr=array[0..5,0..7] of longint;
var
a:arr;
x,y,g:array[0..6] of longint;
n,step,i,j,t:longint;
procedure swap(var a:longint;var b:longint);
var
t:longint;
begin
t:=a;
a:=b;
b:=t;
end;
procedure print;
var
i:longint;
begin
for i:=1 to n do//没错这就是bug!!!我直接从1到n输出了，当时还没反应过来，仔细的同学们可以改为step
writeln(x[i],' ',y[i],' ',g[i]);
end;
function clean:longint;//删除的操作，1为删除了东西，0为没删除东西
var
f:arr;
i,j,k:longint;
begin
fillchar(f,sizeof(f),0);
k:=0;
for i:=0 to 4 do
for j:=0 to 6 do
if a[i,j]<>0 then
begin
if (i>0)and(i<4)and(a[i,j]=a[i-1,j])and(a[i,j]=a[i+1,j]) then
begin
f[i,j]:=1;
f[i-1,j]:=1;
f[i+1,j]:=1;
end;
if (j>0)and(j<6)and(a[i,j]=a[i,j-1])and(a[i,j]=a[i,j+1]) then
begin
f[i,j]:=1;
f[i,j-1]:=1;
f[i,j+1]:=1;
end;
end;
for i:=0 to 4 do
for j:=0 to 6 do
if f[i,j]<>0 then
begin
k:=1;
a[i,j]:=0;
end;
exit(k);
end;
procedure fall;//下落操作
var
i,j,k:longint;
begin
for i:=0 to 4 do
for j:=1 to 6 do
if (a[i,j]<>0)and(a[i,j-1]=0) then
begin
k:=j;
while(k>0)and(a[i,k-1]=0) do
dec(k);
a[i,k]:=a[i,j];
a[i,j]:=0;
end;
end;
function finish:boolean;
var
i,j:longint;
begin
for i:=0 to 4 do
for j:=0 to 6 do
if a[i,j]<>0 then
exit(false);
exit(true);
end;
procedure dfs;
var
i,j,k,l:longint;
b:arr;
begin
if step<>0 then
swap(a[x[step],y[step]],a[x[step]+g[step],y[step]]);//交换上一步的两个格子
repeat
fall;
until clean=0;//注意！先下落后删除，这里卡了好久，哭死了
if step=n then
if finish then
begin
print;
halt;
end
else
exit;
for i:=0 to 4 do
for j:=0 to 6 do
begin
if a[i,j]<>0 then
begin
inc(step);
if (i<4)and(a[i,j]<>a[i+1,j]) then
begin
x[step]:=i;
y[step]:=j;
g[step]:=1;
for k:=0 to 4 do
for l:=0 to 6 do
b[k,l]:=a[k,l];
dfs;
for k:=0 to 4 do
for l:=0 to 6 do
a[k,l]:=b[k,l];
end;
if (i>0)and(a[i-1,j]=0) then
begin
x[step]:=i;
y[step]:=j;
g[step]:=-1;
for k:=0 to 4 do
for l:=0 to 6 do
b[k,l]:=a[k,l];
dfs;
for k:=0 to 4 do
for l:=0 to 6 do
a[k,l]:=b[k,l];
end;
dec(step);
end;
end;
exit;
end;
begin
readln(n);
for i:=0 to 4 do
begin
t:=-1;
repeat
inc(t);
read(a[i,t]);
until a[i,t]=0;
end;
dfs;
writeln(-1);
end.