基于 Arduino 的温度+湿度传感器

虽然根本不懂电路，但经过查阅资料，总算是实现了。在这里做一个记录，以免忘记。

开发环境

硬件

• Arduino uno r3 开发板，点我看Arduino各版本的比较，uno的第3个版本，也是目前市面上用于学习最多的板子，意大利原版的价格是20欧，淘宝山寨板的价格是20元左右。
• 温度湿度传感器，型号DHT11，几块钱，淘宝上都有。
• 杜邦线，1块钱10根（注意分公母，区别是插还是被插）。
• 针排，1块钱很多根，结合杜邦线连接板子和传感器。
• USB线，特制的，方口的一头接板子，另一头接电脑（供电和调试），板子一般都会送。

软件

• Arduino IDE 最新版，点我下载
• 用于MacOS的USB转串口驱动，点我下载

文档

• DHT11说明书，点我下载
• Arduino 原理图，点我下载
• Arduino 板子简介

操作步骤

硬件

1. Arduino 5V供电，直接用USB线接入电脑即可。红灯和绿灯会亮。
2. DHT11有3个引脚，分别是VDD, DATA, GND，用3根杜邦线连接后，根据颜色连接Arduino的引脚，对应关系是VDD接5V，DATA接Digital口的任一个（2~13），GND接GND(地线)。
3. 注意：要连接DHT11和板子，需要用到针排和杜邦线。将杜邦线扯开一点，因为板子上需要用到的3个引脚距离有点远，将要用到的3个针排一个个扯开，使劲儿将中间的黑塑料撸到中间，让两头露出的针一样多，以便两边都容易插的稳固一些。所以连接的方式是：板子的三个引脚–>针排<–>杜邦线<–>DHT11。
4. 注意不要将VDD和GND接反了，以防板子或模块被烧。
5. 接完的效果如图:
   

程序

1. 启动Arduino IDE
2. 设置偏好，比如语言和项目保存路径，如图：
3. 检查驱动是否安装正确，在Tools –> Ports 下查看是否有串口，如如果下图这样：
   那可能是驱动没有安装好。否则应该出现一个类似/dev/xxxSerial的选项。这时候就需要试试fdti和USB虚拟串口的驱动了。MacOS还需要执行 nvram boot-args=”kext-dev-mode=1” 并重启。
4. 确认Tools-> Board 选中的是 Arduino Uno 这一项。

5. 默认的新项目是这样的，如下图：

   一个 setup()函数和一个loop()函数，分别用于初始化和主逻辑。而loop()是会一直死循环执行的。

6. 这里提一下工具栏各项的功能：
   对号：编译代码
   向右的箭头：上传二进制文件到板子上
   文件图标：新建项目窗口
   向上的箭头：打开例子代码，IDE自带了几十个小例子。
   向下的箭头：保存代码
   右上角的放大镜：打开串口输出监视器，用于查看Serial.print()的输出，相当于debug的一种方式了。
   右上角的下拉三角的New Tab，可以添加新文件到项目中。

7. 具体代码：
   
   1. 需要引用dht11的一个库，包括dht11.h和dht11.cpp，具体参考 通过New Tab的方式加入项目中。

double Fahrenheit(double celsius) 
{
        return 1.8 * celsius + 32;
}    //摄氏温度度转化为华氏温度

double Kelvin(double celsius)
{
        return celsius + 273.15;
}     //摄氏温度转化为开氏温度

// 露点（点在此温度时，空气饱和并产生露珠）
// 参考: [url=http://wahiduddin.net/calc/density_algorithms.htm]http://wahiduddin.net/calc/density_algorithms.htm[/url] 
double dewPoint(double celsius, double humidity)
{
        double A0= 373.15/(273.15 + celsius);
        double SUM = -7.90298 * (A0-1);
        SUM += 5.02808 * log10(A0);
        SUM += -1.3816e-7 * (pow(10, (11.344*(1-1/A0)))-1) ;
        SUM += 8.1328e-3 * (pow(10,(-3.49149*(A0-1)))-1) ;
        SUM += log10(1013.246);
        double VP = pow(10, SUM-3) * humidity;
        double T = log(VP/0.61078);   // temp var
        return (241.88 * T) / (17.558-T);
}

// 快速计算露点，速度是5倍dewPoint()
// 参考: [url=http://en.wikipedia.org/wiki/Dew_point]http://en.wikipedia.org/wiki/Dew_point[/url]
double dewPointFast(double celsius, double humidity)
{
        double a = 17.271;
        double b = 237.7;
        double temp = (a * celsius) / (b + celsius) + log(humidity/100);
        double Td = (b * temp) / (a - temp);
        return Td;
}

#include "dht11.h"

dht11 DHT11;

#define DHT11PIN 4

void setup()
{
  Serial.begin(9600);
  Serial.println("DHT11 TEST PROGRAM ");
  Serial.print("LIBRARY VERSION: ");
  Serial.println(DHT11LIB_VERSION);
  Serial.println();
}

void loop()
{
  Serial.println("\n");

  int chk = DHT11.read(DHT11PIN);

  Serial.print("Read sensor: ");
  switch (chk)
  {
    case DHTLIB_OK: 
                Serial.println("OK"); 
                break;
    case DHTLIB_ERROR_CHECKSUM: 
                Serial.println("Checksum error"); 
                break;
    case DHTLIB_ERROR_TIMEOUT: 
                Serial.println("Time out error"); 
                break;
    default: 
                Serial.println("Unknown error"); 
                break;
  }

  Serial.print("Humidity (%): ");
  Serial.println((float)DHT11.humidity, 2);

  Serial.print("Temperature (oC): ");
  Serial.println((float)DHT11.temperature, 2);

  Serial.print("Temperature (oF): ");
  Serial.println(Fahrenheit(DHT11.temperature), 2);

  Serial.print("Temperature (K): ");
  Serial.println(Kelvin(DHT11.temperature), 2);

  Serial.print("Dew Point (oC): ");
  Serial.println(dewPoint(DHT11.temperature, DHT11.humidity));

  Serial.print("Dew PointFast (oC): ");
  Serial.println(dewPointFast(DHT11.temperature, DHT11.humidity));

  delay(2000);
}

编译并上传到板子上，打开串口监视器，可以看到温度和湿度的输出，还是很快的：

可以看到温度摄氏 24度，湿度13%（北京还是挺干燥的，赶紧打开了加湿器），自制温度计就这样完成了。中午去买了一个蓝牙模块，接下来想通过蓝牙把温度传给手机。

总结

1. 由于不懂电路知识，看不懂原理图，接哪个引脚都花了很长时间。
2. DHT11的输出一共有40位数据，高位先出，8bit湿度整数数据+8bit湿度小数数据+8bit温度整数数据+8bit温度小数数据+8bit校验和。检验和是前4个8位数据相加结果的后8位。
3. 没有相应的驱动导致找不到串口花费了不少时间。

参考引用

http://www.arduino.cn/thread-1429-1-2.html
http://www.arduino.cc/en/Main/arduinoBoardUno