Hive DDL数据定义

目录

创建数据库

修改数据库

查询数据库

删除数据库

创建表

管理表

 外部表

内部表与外部表的相互转换

分区表

分区表注意事项

修改表

删除表

---

创建数据库

1）创建一个数据库，数据库在 HDFS 上的默认存储路径是/user/hive/warehouse/*.db。

hive (default)> create database db_hive;

2）避免要创建的数据库已经存在错误，增加 if not exists 判断。（标准写法）

hive (default)> create database if not exists db_hive;

3）创建一个数据库，指定数据库在 HDFS 上存放的位置

hive (default)> create database db_hive2 location '/db_hive2.db';

修改数据库

用户可以使用 ALTER DATABASE 命令为某个数据库的 DBPROPERTIES 设置键-值对属性值，来描述这个数据库的属性信息。数据库的其他元数据信息都是不可更改的，包括数据库名和数据库所在的目录位置。

hive (default)> alter database db_hive set dbproperties('createtime'='20170830');

查看修改结果：

hive> desc database extended db_hive;
# 结果
db_name comment location owner_name owner_type parameters
db_hive hdfs://hadoop102:8020/user/hive/warehouse/db_hive.db root USER
{createtime=20170830}

查询数据库

显示数据库

hive> show databases;

过滤显示查询的数据库

hive> show databases like 'db_hive*';

查看数据库详情

1）显示数据库信息

hive> desc database db_hive;

2）显示数据库详细信息，extended

hive> desc database extended db_hive;

切换当前数据库

hive (default)> use db_hive;

 

删除数据库

1）删除空数据库

hive>drop database db_hive2;

2）如果删除的数据库不存在，最好采用 if exists 判断数据库是否存在

hive> drop database if exists db_hive2;

3）如果数据库不为空，可以采用 cascade 命令，强制删除

hive> drop database db_hive cascade;

 

创建表

1）建表语法

CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name
    [(col_name data_type [COMMENT col_comment], ...)]
    [COMMENT table_comment]
    [PARTITIONED BY (col_name data_type [COMMENT col_comment], ...)]
    [CLUSTERED BY (col_name, col_name, ...)
    [SORTED BY (col_name [ASC|DESC], ...)] INTO num_buckets BUCKETS]
    [ROW FORMAT row_format]
    [STORED AS file_format]
    [LOCATION hdfs_path]

2）字段解释说明：

（1）CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。
（2）EXTERNAL 关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际数据的路径（LOCATION），Hive 创建内部表时，会将数据移动到数据仓库指向的路径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。
（3）COMMENT：为表和列添加注释。
（4）PARTITIONED BY 创建分区表
（5）CLUSTERED BY 创建分桶表
（6）SORTED BY 不常用
（7）ROW FORMAT
DELIMITED  [FIELDS  TERMINATED  BY  char]  [COLLECTION  ITEMSTERMINATED BY char]
[MAP KEYS TERMINATED BY char] [LINES TERMINATED BY char]
| SERDE serde_name [WITH SERDEPROPERTIES (property_name=property_value,
property_name=property_value, ...)]
用户在建表的时候可以自定义 SerDe 或者使用自带的 SerDe。如果没有指定 ROW FORMAT 或者 ROW FORMAT DELIMITED，将会使用自带的 SerDe。在建表的时候，用户还需要为表指定列，用户在指定表的列的同时也会指定自定义d的SerDe，Hive 通过 SerDe确定表的具体的列的数据。

（8）STORED AS 指定存储文件类型
常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、RCFILE（列式存储格式文件）如果文件数据是纯文本，可以使用 STORED AS TEXTFILE。如果数据需要压缩，使用 STORED AS SEQUENCEFILE。
（9）LOCATION ：指定表在 HDFS 上的存储位置。
（10）LIKE 允许用户复制现有的表结构，但是不复制数据。

  

管理表

1）理论

默认创建的表都是所谓的管理表，有时也被称为内部表。因为这种表，Hive 会（或多或少地）控制着数据的生命周期。Hive 默认情况下会将这些表的数据存储在由配置项hive.metastore.warehouse.dir(例如，/user/hive/warehouse)所定义的目录的子目录下。 当我们删除一个管理表时，Hive也会删除这个表中数据。管理表不适合和其他工具共享数据。

2 ）案例实操

1.普通创建表：

create table if not exists student2(
    id int, name string
)
row format delimited fields terminated by '\t'
stored as textfile
location '/user/hive/warehouse/student2';

2.根据查询结果创建表（查询的结果会添加到新创建的表中）：

create table if not exists student3
as select id, name from student;

3.根据已经存在的表结构创建表

create table if not exists student4 like student;

4.查询表的类型

hive (default)> desc formatted student2;

Table Type: MANAGED_TABLE

 外部表

1）理论

因为表是外部表，所以 Hive 并非认为其完全拥有这份数据。删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉。

2）管理表和外部表的使用场景：

每天将收集到的网站日志定期流入 HDFS 文本文件。在外部表（原始日志表）的基础上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过 SELECT+INSERT进入内部表。

3）创建外部表

create external table if not exists default.dept(
    deptno int,
    dname string,
    loc int
)
row format delimited fields terminated by '\t';

查看类型：desc formatted dept;

Table Type: EXTERNAL_TABLE

 

内部表与外部表的相互转换

1.查询表的类型

hive (default)> desc formatted student2;

Table Type: MANAGED_TABLE

2.修改内部表student2为外部表

alter table student2 set tblproperties('EXTERNAL'='TRUE');

3.查询表的类型

hive (default)> desc formatted student2;

Table Type: EXTERNAL_TABLE

4.修改外部表student2为内部表

alter table student2 set tblproperties('EXTERNAL'='FALSE');

5.查询表的类型

hive (default)> desc formatted student2;

Table Type: MANAGED_TABLE

 

分区表

分区表实际上就是对应一个 HDFS 文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。Hive 中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。在查询时通过 WHERE 子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多。

分区表基本操作

1）引入分区表（需要根据日期对日志进行管理）

/user/hive/warehouse/log_partition/20170702/20170702.log
/user/hive/warehouse/log_partition/20170703/20170703.log
/user/hive/warehouse/log_partition/20170704/20170704.log

2）创建分区表语法

hive (default)> create table dept_partition(
    deptno int, dname string, loc string
)
partitioned by (month string)
row format delimited fields terminated by '\t';

3）加载数据到分区表中

hive  (default)>  load  data  local  inpath  '/opt/module/datas/dept.txt'  into  table
default.dept_partition partition(month='201709');
hive  (default)>  load  data  local  inpath  '/opt/module/datas/dept.txt'  into  table
default.dept_partition partition(month='201708');
hive  (default)>  load  data  local  inpath  '/opt/module/datas/dept.txt'  into  table
default.dept_partition partition(month='201707');

注意：创建分区表的时候用的是partitioned、加载数据到分区用的是partition

4）查询分区表中数据

单分区查询:

hive (default)> select * from dept_partition where month='201709';

多分区联合查询:

hive (default)> select * from dept_partition 
where month='201709' or month='201708' or month='201707';

或

hive (default)> select * from dept_partition where month='201709'
union
select * from dept_partition where month='201708'
union
select * from dept_partition where month='201707';

5）增加分区

创建单个分区

hive (default)> alter table dept_partition add partition(month='201706') ;

同时创建多个分区

hive  (default)>  alter  table  dept_partition  add  partition(month='201705') partition(month='201704');

6）删除分区

删除单个分区

hive (default)> alter table dept_partition drop partition (month='201704')

同时删除多个分区

hive (default)> alter table dept_partition drop partition (month='201705'), partition (month='201706');

注意：添加分区时候用空格创建多个分区，二删除分区的时候以逗号删除多个分区！

7）查看分区表有多少分区

hive> show partitions dept_partition;

8）查看分区表结构

hive> desc formatted dept_partition;

分区表注意事项

1）创建二级分区表

hive (default)> create table dept_partition2(
    deptno int, dname string, loc string
)
partitioned by (month string, day string)
row format delimited fields terminated by '\t';

2）正常的加载数据

     1.加载数据到二级分区表中

hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition2 partition(month='201709', day='13');

     2.查询分区数据

hive (default)> select * from dept_partition2 where month='201709' and day='13';

 

3）把数据直接上传到分区目录上，让分区表和数据产生关联的两种方式

     1.方式一：上传数据后修复

      创建自定义分区目录并上传数据

hive(default)>dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=12;

hive(default)>dfs -put /opt/module/datas/dept.txt /user/hive/warehouse/dept_partition2/month=201709/day=12;

    查询数据

            （查询不到刚上传的数据,在非分区表是可以通过select * from 表名，来查到信息的。原因是该分区表没有建立元数据信息我们就直接自建分目录并上传数据，需要修复才可以添加元数据信息到分区表中。）

hive(default)>select * from dept_partition2 where month='201709' and day='12';

    执行修复命令

hive> msck repair table dept_partition2;

    再次查询数据

hive(default)>select * from dept_partition2 where month='201709' and day='12';

（2）方式二：上传数据后添加分区

    创建自定义分区目录并上传数据

hive(default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=11;
hive(default)>dfs -put /opt/module/datas/dept.txt /user/hive/warehouse/dept_partition2/month=201709/day=11;

   执行添加分区 

hive(default)>alter table dept_partition2 add partition(month='201709', day='11');

   查询数据

hive(default)> select * from dept_partition2 where month='201709' and day='11';

（3）方式三：上传数据后 load 数据到分区(常用)

   创建目录

hive(default)>dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=10;

   上传数据

hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table dept_partition2 partition(month='201709',day='10');

    查询数据

hive (default)> select * from dept_partition2 where month='201709' and day='10';

 

修改表

重命名表

（1）语法

ALTER TABLE table_name RENAME TO new_table_name

（2）实操案例

hive (default)> alter table dept_partition2 rename to dept_partition3;

增加、修改和删除表分区

     添加分区：

ALTER TABLE table_name ADD PARTITION (partCol = 'value1') location 'loc1'; //示例

ALTER TABLE table_name ADD IF NOT EXISTS PARTITION (dt='20130101') LOCATION '/user/hadoop/warehouse/table_name/dt=20130101'; //一次添加一个分区

ALTER TABLE page_view ADD PARTITION (dt='2008-08-08', country='us') location '/path/to/us/part080808' PARTITION (dt='2008-08-09', country='us') location '/path/to/us/part080809';  //一次添加多个分区

     删除分区：

ALTER TABLE login DROP IF EXISTS PARTITION (dt='2008-08-08');

ALTER TABLE page_view DROP IF EXISTS PARTITION (dt='2008-08-08', country='us');

     修改分区：

ALTER TABLE table_name PARTITION (dt='2008-08-08') SET LOCATION "new location";

ALTER TABLE table_name PARTITION (dt='2008-08-08') RENAME TO PARTITION (dt='20080808');

增加/ 修改/ 替换列信息

1）语法

      更新列

ALTER TABLE table_name CHANGE [COLUMN] col_old_name col_new_name column_type [COMMENT col_comment] [FIRST|AFTER column_name]

     增加和替换列

ALTER TABLE table_name ADD|REPLACE COLUMNS (col_name data_type [COMMENT col_comment], ...)

注：ADD 是代表新增一字段，字段位置在所有列后面(partition 列前)，REPLACE 则是表示替换表中所有字段。

2）实操案例

         （1）查询表结构

hive> desc dept_partition;

         （2）添加列

hive (default)> alter table dept_partition add columns(deptdesc string);

         （3）更新列

hive (default)> alter table dept_partition change column deptdesc desc int;

         （4）替换列

hive (default)> alter table dept_partition replace columns(deptno string, dname string, loc string);

 

删除表

hive (default)> drop table dept_partition;

官方手册中文版参考：http://www.cnblogs.com/fanzhenyong/p/9746796.html#_label1