Hive 数据操作DML详解

数据导入

 

1.向表中装载数据（Load）

1.1 语法

        hive> load data [local] inpath '/opt/module/datas/student.txt' [overwrite] into table student [partition (partcol1=val1,…)];

    ① load data:表示加载数据

    ② local:表示从本地加载数据到hive表；否则从HDFS加载数据到hive表

    ③ inpath:表示加载数据的路径

    ④ overwrite:表示覆盖表中已有数据，否则表示追加

    ⑤ into table:表示加载到哪张表

    ⑥ student:表示具体的表

    ⑦ partition:表示上传到指定分区

1.2 实操案例

    创建一张表

    hive (default)> create table student(id string, name string) row format delimited fields terminated by '\t';

    ① 加载本地文件到hive

        hive (default)> load data local inpath '/opt/module/datas/student.txt' into table default.student;

    ② 加载HDFS文件到hive中

    上传文件到HDFS

    hive (default)> dfs -put /opt/module/datas/student.txt /user/hive;

    加载HDFS上数据

    hive (default)> load data inpath '/user/hive/student.txt' into table default.student;

    ③ 加载数据覆盖表中已有的数据

    上传文件到HDFS

    hive (default)> dfs -put /opt/module/datas/student.txt /user/hive;

    加载数据覆盖表中已有的数据

    hive (default)> load data inpath '/user/hive/student.txt' overwrite into table default.student;

 

2.通过查询语句向表中插入数据（Insert）

2.1 创建一张分区表

    hive (default)> create table student(id int, name string) partitioned by (month string) row format delimited fields terminated by '\t';

2.2 基本插入数据

    hive (default)> insert into table  student partition(month='201709') values(1,'wangwu');

2.3 基本模式插入（根据单张表查询结果）

    hive (default)> insert overwrite table student partition(month='201708') select id, name from student where month='201709';

2.4 多插入模式（根据多张表查询结果）

    hive (default)> from student

              insert overwrite table student partition(month='201707')

              select id, name where month='201709'

              insert overwrite table student partition(month='201706')

              select id, name where month='201709’;

 

3.查询语句中创建表并加载数据（as select）

    根据查询结果创建表（查询的结果会添加到新创建的表中）

    create table if not exists student3 as select id, name from student;

 

4.创建表时通过Location指定加载数据路径

4.1 创建表，并指定在hdfs上的位置

hive (default)> create table if not exists student5(
              id int, name string
              )
              row format delimited fields terminated by '\t'
              location '/user/hive/warehouse/student5';

4.2 上传数据到hdfs上

    hive (default)> dfs -put /opt/module/datas/student.txt /user/hive/warehouse/student5;

4.3 查询数据

    hive (default)> select * from student5;

 

5.import数据到指定Hive表中

    注意：先用export导出后，再将数据导入。

hive (default)> export table student to '/opt/module/datas/student_export/';
 hive (default)> import table student4 from '/opt/module/datas/student_export/';

    注意：import目标表必须为不存在的表。（补：数据迁移时候用到：import是包含元数据信息，load data不包含元数据信息，import导入的文件必须是经export的文件）。

 

 

数据导出

1.Insert导出

1.1 将查询的结果导出到本地

    hive (default)> insert overwrite local directory '/opt/module/datas/export/student’ select * from student;

1.2 将查询的结果格式化导出到本地

    hive(default)>insert overwrite local directory '/opt/module/datas/export/student1’ ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t'  select * from student;

1.3 将查询的结果导出到HDFS上(没有local)

    hive (default)> insert overwrite directory '/user/student2’ ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t' select * from student;

 

2.Hadoop命令导出到本地

    hive (default)> dfs -get /user/hive/warehouse/student/month=201709/000000_0 /opt/module/datas/export/student3.txt;

 

3.Hive Shell 命令导出

    基本语法：（hive -f/-e 执行语句或者脚本 > file）

    [luomk@hadoop102 hive]$ bin/hive -e 'select * from default.student;’ > /opt/module/datas/export/student4.txt;

 

4.Export导出到HDFS上

    (defahiveult)>export table default.student to '/user/hive/warehouse/export/student';

 

 

清空数据

hive (default)> truncate table student;

注意：Truncate只能删除管理表，不能删除外部表中数据