小米的兩道面試題

偶然間看到據說是小米的面試題，拿來用coffeescript玩一下

題目一

// 题目要求！
function repeat (func, times, wait) {}
// 这个函数能返回一个新函数，比如这样用
// var repeatedFun = repeat(alert, 10, 5000)
// 调用这个 repeatedFun ("hellworld")会alert十次 helloworld, 每次间隔5秒

Nodejs的環境，預設是沒有alert的，因此我們稍稍改一下題目

• 修改後的題目一

function repeat(func,times,wait) {
// do something
}

// 調用時
alert = function () { console.log("alert") };
action = repeat(alert,10,5000);
action() // 印出alert十次，每次間隔5秒

以下，用coffeescript來實作，純粹好玩

使用setInterval

repeat = (func,times,wait)-> () ->
    func()
    executedTimes = 1
    setInterval ->
        return unless executedTimes < times
        func()
        executedTimes += 1
    , wait

使用setTimeout

repeat = (func,times,wait)-> () ->
    f = (i)-> setTimeout func, i*wait
    f(i) for i in [0... times]

這其實是有點偷懶...直接spawn多個setTimeout獨立執行，不能保證時序。反正就玩玩。這版本行數少了一些，其實極端一點甚至可以寫成一行(不推薦)

repeat = (func,times,wait) -> () -> ( (i) -> setTimeout func, i*wait)(i) for i in [0... times]

不過setTimeout每次都要把function寫在前面有點醜，給他換個名字

delay = (ms, fn) -> setTimeout fn, ms

iced-coffeescript版本

repeat = (func,times,wait)-> () ->
    loop = (completion) -> delay wait, ->
        func()
        completion(true)
    await loop(defer done) for i in [0...times]

這方法是比較有可讀性的，我們把要執行的行為：delay幾秒、func都用loop包起來，並結束時給一個completioncallback，之後就可以輕鬆用await去控制流程。await讓整個程式的流程更清楚，同時又不會堵塞線程，真是個好物! 其實這並不是什麼高深的語法，最後也是compile成100% javascript寫的"Outside-In"控制流，只是寫起來更優雅而已。至於defer done在這個題目並不重要，他只是把callback回來的true存在done參數裡而已。

題目二

這一題真的很有趣！

var result1 = stringconcat("a", "b") //result1 = "a+b"
var stringconcatWithPrefix = stringconcat.prefix("helloworld");
var result2 = stringconcatWithPrefix("a", "b") //result2 = "hellworld+a+b"

這題一開始我還以為出錯了...怎麼如此簡單，沒想到挺有意思的。重點在於stringconcat.prefix必須儲存helloworld字串於閉包中，並回傳一個函式。想了快半小時，直接上解答

stringconcat = (s1,s2) ->  s1 + "+" + s2
stringconcat.prefix = (s0)-> 
    that = this
    return (s1,s2) -> 
        return s0 + "+" + that(s1,s2)

再稍微整理一下，由於coffee script會自動return函式最後一行表達式，所以這邊我們可以省略掉return，並且用=>來省略that。

stringconcat.prefix = (s0)-> 
    (s1,s2) => 
        s0 + "+" + this(s1,s2)

然後最後再化簡一下

stringconcat.prefix = (s0)-> (s1,s2) => s0 + "+" + this(s1,s2)

一樣，一行搞定！原文有用Array.prototype去實作，也是很有趣的做法。建議大家看看。