解决火狐浏览器任务栏图标失效问题

老规矩，解决方法请见最下方内容。
正常情况下，火狐通过任务栏图标打开，对应的活跃窗口图标应该就在任务栏固定位置，如下图所示。

火狐使用中的任务栏正常状态

然而有时候我们会发现这个图标并没有处于活跃状态，而是在任务栏固定的图标区域之外，另有一个火狐图标（有时是原生的彩色图标），如下图所示。

火狐使用中的任务栏异常状态

解决方法如下：
将以下代码保存为“FirefoxIcoFix.bat”，然后双击运行。脚本自动请求管理员权限，弹出窗口选择确定即可。脚本执行完成后，将任务栏火狐图标取消固定，然后再重新固定图标到任务栏，即可解决问题。

@echo off
title 解决火狐任务栏双图标――鱼刺
mode con cols=50 lines=25
color 0a
:-------------------------------------
REM --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
:--------------------------------------
goto MENU
:menu
cls
echo.
echo 解决火狐任务栏双图标――鱼刺
echo =================================================
echo.
echo 执行操作成功后关闭浏览器重新固定到任务栏
echo.
echo 1，执行此操作
echo.
echo 2，还原操作
echo.
echo 3，退出
echo.
echo =================================================
echo.
echo 请输入选择项目的序号,按回车键确认：
set /p ID=
if "%id%"=="1" goto cmd1
if "%id%"=="2" goto cmd2
IF "%id%"=="3" exit
PAUSE

:cmd1
echo 删除TaskBarIDs项，该项已备份在当前目录 bak.reg
reg export HKLM\SOFTWARE\Wow6432Node\Mozilla\Firefox\TaskBarIDs bak1.reg
reg delete HKLM\SOFTWARE\Wow6432Node\Mozilla\Firefox\TaskBarIDs /f
reg export HKCU\SOFTWARE\Mozilla\Firefox\TaskBarIDs bak2.reg
reg delete HKCU\SOFTWARE\Mozilla\Firefox\TaskBarIDs /f
PAUSE
goto MENU

:cmd2
echo 还原注册表
reg import bak1.reg
reg import bak2.reg
PAUSE
goto MENU