通过异类查询(OpenDataSource - OLEDB引擎驱动)把外部数据(Excel,TXT)导入到SqlServer及job代理执行出错的处理

无论用sqlcmd或者通过C#逻辑处理，或者还是直接在SqlServer里执行操作，个人总结大概不过可归总为这两种方式：
1，SSIS；
2，OLEDB驱动引擎。

SSIS实在也好用，现在这里先不去讨论。其中大多数人用的都是第二种方法，下面，本人也以第二种方法在SqlServer里导入excel和txt格式文件的具体实例来说明怎样在项目里灵活通过OLEDB导入数据！

一，必要的环境说明

本实例用sql语句在SqlServer里面完成对数据的导入操作。
在本实例开始之前,可能需要先安装AccessDatabase引擎包
(本人机器64位，安装的是32位的office组件，所以需要另外安装office驱动引擎包（此引擎包作用在于使得office系统文件与office应用程序之间进行数据传输） - 此步骤中需要先卸载32位office组件，否则会提示驱动安装不成功)
本人所用引擎包下载地址如下：
http://www.microsoft.com/zh-cn/download/details.aspx?id=13255
安装完成后,具体配置可以这里配,建议如非必要,默认就好。

二，代码准备 - 建数据库及存储过程

建数据库这里不多说，建立与导入数据相匹配的数据库而已。
而为了项目拓展及方便使用管理,需要创建存储过程,目的是为了批量导入外部数据。
因为本例以excel和txt分别来做实例说明，所以，需要新建两个存储过程 - "sp_ReadXLSSource"和"sp_ReadSource"。代码分别如下：
存储过程：sp_ReadXLSSource

USE [CUSTOMS]
GO
/****** Object:  StoredProcedure [dbo].[sp_ReadXLSSource]    Script Date: 11/21/2014 3:01:39 PM ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER PROCEDURE [dbo].[sp_ReadXLSSource]
@trgPath varchar(255),
@trgTable varchar(255),
@xlsFile varchar(255),
@xlsSheet varchar(255),
@xlsFields varchar(8000)
AS
declare @mySql varchar(8000)
declare @myIntermediate varchar(8000)
declare @Firstfield varchar(100)
declare @FirstfieldValue varchar(100)

--Lookup lastfield
set @Firstfield = dbo.fnGetFirstField(@xlsFields)
set @FirstfieldValue = RTRIM(LTRIM(SUBSTRING(@Firstfield,2,CHARINDEX(']',@Firstfield,0)-2)))
--PRINT @FirstfieldValue

--Drop table if exists
set @myIntermediate = 'IF EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N''[dbo].[' + @trgTable + ']'') AND type in (N''U''))'
set @mySql = @myIntermediate + ' DROP TABLE ' + @trgTable
exec(@mySql)
--PRINT @mySql

--Load Table
set @mySql = 'SELECT ' + @xlsFields + ' INTO ' + @trgTable + ' FROM OPENROWSET(''Microsoft.ACE.OLEDB.12.0'',  
''Excel 12.0;DATABASE=' + @trgPath + '\' + @xlsFile + ';IMEX=1'',  ''Select * from ' + @xlsSheet + ''')'
+ 'WHERE NOT ' + @Firstfield + ' IS NULL'
--PRINT @mySql
exec(@mySql)

存储过程：sp_ReadSource

USE [WOOX_CQM]
GO
/****** Object:  StoredProcedure [dbo].[sp_ReadSource]    Script Date: 11/21/2014 2:54:33 PM ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER PROCEDURE [dbo].[sp_ReadSource]
@trgPath varchar(255),
@trgTable varchar(255),
@trgFields varchar(8000)
AS
declare @mySql varchar(8000)
declare @myIntermediate varchar(8000)
declare @Firstfield varchar(100)
declare @FirstfieldValue varchar(100)

--Lookup lastfield
set @Firstfield = dbo.fnGetFirstField(@trgFields)
set @FirstfieldValue = RTRIM(LTRIM(SUBSTRING(@Firstfield,2,CHARINDEX(']',@Firstfield,0)-2)))
--PRINT @FirstfieldValue

--Drop table if exists
set @myIntermediate = 'IF EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N''[dbo].[' + @trgTable + ']'') AND type in (N''U''))'
set @mySql = @myIntermediate + ' DROP TABLE ' + @trgTable
exec(@mySql)
--PRINT @mySql

--Load Table
set @mySql = 'SELECT ' + @trgFields + ' INTO ' + @trgTable + ' ' +
'FROM OpenDataSource (''Microsoft.ACE.OLEDB.12.0'',
''Data Source="' + @trgPath + '";Extended properties=Text'')...' 
+ @trgTable + '#txt ' 
+ 'WHERE NOT ' + @Firstfield + ' IS NULL AND ' + @Firstfield + ' <> ' + '''' + @FirstfieldValue + ''''
--PRINT @mySql
exec(@mySql)

三，文件准备,导入源及Schema.ini配置文件

对于excel文件来说,相对txt格式，实在简单很多，关键不过以下这段代码

TRUNCATE TABLE WOOX_INFORMATICA..VBPA;
INSERT INTO WOOX_INFORMATICA..VBPA select * FROM OPENROWSET('Microsoft.ACE.OLEDB.12.0', 'Excel 12.0;Database=C:\InitialData\db_data.xlsx;HDR=YES', 'SELECT * FROM [VBPA$]')
--(适用于office2007及以上版本，2003用Jet - "Microsoft.Jet.OLEDB.4.0")

其它需要注意的不过就是保证excel内的数据格式是统一的文本格式，这里只简单给出事例图，不做详细说明。


对于txt格式文件，本人所用格式如下。

//标示部分为标题；
ok，下面是关键，我们需要配置导入txt格式数据的配置文件Schema.ini！如果导入不成功或者出错，大都是这一步骤错了
（ps：此配置文件要和导入源放在同一个文件夹下，另外，文件夹目录最好别太长或者包含有空格之类的，这些自己注意！）
其中Schema.ini里规范格式如下。

[SAP_TVSTZ.txt]
FORMAT=Delimited(|)
ColNameHeader=True
MaxScanRows=0
CharacterSet=Unicode
TextDelimiter=`
Col1=SKIP1 TEXT
Col2=SKIP2 TEXT
COL3=VSBED TEXT
COL4=LADGR char(100)
COL5=WERKS TEXT
COL6=LGORT TEXT
COL7=VSTEL TEXT

这里需要标明的是：域值内，第一行表示数据源文件名；第二行至第六行是必要的设置和说明，每个人按需修改；第七行以下必须按照Col从1索引开始递增，右边是显示的列名及格式。具体有兴趣的同学可以自己试着操作下，看下差异。

四，执行及检查

执行代码如下

USE WOOX_CQM

EXECUTE sp_ActivateDistributedQueries
----------------------------- SAP Tables -----------------------------
DECLARE @LoadPath varchar(2000)
SET @LoadPath = 'C:\InitialData\SAPdata'

--import Excel--
EXECUTE sp_ReadXLSSource 
@LoadPath, 
'SAP_TCURF', 'SAP_TCURF.xls', '[Sheet1$]',
'[KURST],[FCURR],[TCURR],[GDATU], [FFACT],[TFACT],[FromDate],[ToDate]'

--import txt--
EXECUTE sp_ReadSource 
@LoadPath, 
'SAP_TVSTZ', 
'[VSBED],[LADGR],[WERKS],[LGORT],[VSTEL]'

可用以下代码先行测试导入数据是否有差距，同学们记得更改本人所用的hardcored。

select * 
FROM OpenDataSource ('Microsoft.ACE.OLEDB.12.0',
'Data Source="C:\InitialData\SAPdata";Extended properties=Text')...SAP_TW06S#txt

ok，大概代码就是这样，如果有什么不懂或者有不同意见的，可用留言讨论！

五，通过SQL Server Agent Job 计划执行的出错处理

在用Job代理计划执行的时候，提示出错


此时的解决办法是打开Windows Services ，找到对应的服务实例，然后右键打开属性，选择登录选项，把登录用户更改为本地机器账号，保存重启，然后就可以的了。