三、开关控件
TlincoSwitch
用过
Delphi1
(好古老的东东呀!)的人相信都记得这个开关控件
,不知道当初
Borland
为什么把这么一个在开发普通应用程序中应用不到的工控控件放到
Delphi
中,而且在
Delphi2
及其以后的版本中再也没有见过它的身影。让我们怀着怀旧的心情把这位“开国元老”请出来吧!
1、
建立位图资源文件:
用
Image Editor
建立一个
Res
文件,并在文件中分别建立下面两个位图
,并分别命名为
SWITCHON
、
SWITCHOFF
。保存此
Res
到控件单元所在目录下。
2
、写控件代码。
unit LincoSwitch;
interface
uses
SysUtils, Classes, Controls, Graphics, Windows;
type
TLincoSwitch = class(TCustomControl)
private
FIsOn: Boolean;
FPicOn: Graphics.TBitmap;
FPicOff: Graphics.TBitmap;
procedure FSetIsOn(AValue: Boolean);
protected
procedure Click;override;
procedure Paint;override;
public
constructor Create(AOwner: TComponent);override;
destructor Destroy;override;
published
property IsOn: Boolean read FIsOn write FSetIsOn;
property OnClick;
property OnKeyDown;
property OnKeyPress;
property OnKeyUp;
property OnCanResize;
property OnDblClick;
property OnMouseDown;
property OnMouseMove;
property OnMouseUp;
property OnMouseWheel;
property OnResize;
end;
procedure Register;
implementation
{$R *.res}
procedure LoadBitmapFromRes(ABitmapId: string; ABitmap: Graphics.TBitmap);
begin
ABitmap.LoadFromResourceName(hInstance, ABitmapId);//
从资源文件中读取位图
end;
constructor TLincoSwitch.Create(AOwner: TComponent);
begin
inherited Create(AOwner);
FPicOn := Graphics.TBitmap.Create;
FPicOff := Graphics.TBitmap.Create;
LoadBitmapFromRes('SWITCHON', FPicOn);
LoadBitmapFromRes('SWITCHOFF', FPicOff);
Invalidate;
end;
destructor TLincoSwitch.Destroy;
begin
FPicOn.Free;
FPicOff.Free;
inherited;
end;
procedure TLincoSwitch.Click;
begin
IsOn := not IsOn;//
改变按钮的状态
Invalidate;
inherited;
end;
procedure TLincoSwitch.Paint;
begin
//
画开关图案
if IsOn then
StretchBlt(Canvas.Handle, 0, 0, self.Width, self.Height, FPicOn.Canvas.Handle,
0, 0, FPicOn.Width, FPicOn.Height,SRCCOPY)
else
StretchBlt(Canvas.Handle, 0, 0, self.Width, self.Height, FPicOff.Canvas.Handle,
0, 0, FPicOff.Width, FPicOff.Height,SRCCOPY);
end;
procedure TLincoSwitch.FSetIsOn(AValue: Boolean);
begin
FIson := AValue;
Invalidate;
end;
procedure Register;
begin
RegisterComponents('Linco', [TLincoSwitch]);
end;
end.
3
、代码分析
(
1
)、因为我们要在控件表面上将按钮的图案画出来,所以我们选择
TcustomControl
做为父类控件,因为它有个
Canvas
属性,我们可以利用
Canvas
在控件表面作图。不选用
Tcontrol
的原因是因为它有很多我们不需要的属性。
(
2
)、
ABitmap.LoadFromResourceName(hInstance, ABitmapId);
是从资源文件中读取
Id
为
AbitmapId
的位图,关于资源文件的使用请参考其他相关资料。注意代码中的“
{$R *.res}
”,它的作用是将资源文件编译到程序文件中,如果没有这个预编译条件,程序将会出现错误。
(
3
)、
StretchBlt
是将位图画到画板上,使用方法请参考
MSDN
。
(
4
)、我们为控件增加了
IsOn
属性。这个布尔属性用来表示开关的状态(开
/
关)。
从
property IsOn: Boolean read FIsOn write FSetIsOn;
我们可以看出这个属性是个可读可写的属性。当读这个属性时会将
FisOn
的值返回给调用者,而写属性时则会调用
FsetIsOn
方法,并将赋给属性的值做为参数传递给
FsetIsOn
。在
FsetIsOn
方法中,有如下实现代码:
FIson := AValue;
Invalidate;
首先将
Fison
设置为参数传递来的值,然后调用
Invalidate;
要求重画控件,以告诉用户控件的状态已经改变,这一点是使用写字段无法做到的。
(
5
)
FPicOn: Graphics.TBitmap;
FPicOff: Graphics.TBitmap;
是声明两个
.Tbitmap
类型变量以保存控件的开关两种状态的图案。
(
6
)
procedure Click;override;
procedure Paint;override;
分别是覆盖父类中相应的调度方法。当控件被鼠标单击时,
Click
方法会被调用,我们将在
Click
中改变控件的开关状态;
Paint
方法则在用户调用
Invalidate
方法或控件发生重画时调用,我们一般在这个方法绘制控件的图案。
(
7
)、
TcustomControl
中又很多事件处理句柄。比如
OnClick
、
OnKeyDown
等,但是它把他们声明成了
Protected
保护级别,所以我们在
Object Inspector
中看不到他们,如果我们要他们可以在
Object Inspector
中被用户编辑的话,只要在
Published
中重新声明他们即可,不用写他们的读写方法,只要使用:
Property
属性名;
这样的方法就可以。比如这个例子中的:
Property Onclick;
思考题:
1、
做一个有特效的按钮控件,当鼠标按下时按钮是一个红色边框的空心圆,当鼠标松开时按钮是一个淡绿色边框的空心圆。
2、
对于父类控件中为
protected
的属性,如果想将它在子类控件中公布,应该怎么做?请思考
Delphi
为什么要将一些属性设为
protected
级别?