[057][x86汇编语言]第16章 源码分析 过程[create_copy_cur_pdir]：复制 页目录表（core）到 页目录表（user）

学习笔记

《x86汇编语言：从实模式到保护模式》
https://www.jianshu.com/p/d481cb547e9f

方案的内容

每个任务都有自己的页目录表以及页表，
页目录表的前半部分对应着任务自己虚拟地址空间的前2GB（0~2G）
后半部分则映射到内核的页表（2~4G）；

- 当任务在自己独立的局部空间工作时，使用它自己的页表；
- 当任务请求系统服务时，用的则是内核的页表，访问的是内核的代码和数据；

本文只涉及页目录表相关。

• [1]、创建用户任务的页目录表（页目录表（user））;
• [2]、将内核页目录表（ 页目录表（core） ）中的内容复制过去；
• [3]、切换到用户任务的页目录表上去工作；

代码过程

• 源码文件 c16_core.asm
• 前面的数字代表语句在源码文件中的行号；

零、调用 过程 load_relocate_program

1067 call load_relocate_program

一、过程 load_relocate_program 的内部调用

830 ;创建用户任务的页目录
831 ;注意！页的分配和使用是由页位图决定的，可以不占用线性地址空间

; 调用过程 create_copy_cur_pdir 
832 call sys_routine_seg_sel:create_copy_cur_pdir

833 mov ebx,[es:esi+0x14] ;从TCB中获取TSS的线性地址
834 mov dword [es:ebx+28],eax ;填写TSS的CR3(PDBR)域

• 调用过程 create_copy_cur_pdir ，完成方案中的[1]以及[2]；
• 在过程 create_copy_cur_pdir返回之后，更新了用户任务的TSS的CR3域，从而完成了方案中的[3]

二、过程 create_copy_cur_pdir 的具体实现

create_copy_cur_pdir:                       ;创建新页目录，并复制当前页目录内容
                                            ;输入：无
                                            ;输出：EAX=新页目录的物理地址 
         push ds
         push es
         push esi
         push edi
         push ebx
         push ecx
         
         mov ebx,mem_0_4_gb_seg_sel
         mov ds,ebx
         mov es,ebx
         
         call allocate_a_4k_page            
         mov ebx,eax
         or ebx,0x00000007
         mov [0xfffffff8],ebx
         
         mov esi,0xfffff000                 ;ESI->当前页目录的线性地址
         mov edi,0xffffe000                 ;EDI->新页目录的线性地址
         mov ecx,1024                       ;ECX=要复制的目录项数
         cld
         repe movsd 
         
         pop ecx
         pop ebx
         pop edi
         pop esi
         pop es
         pop ds
         
         retf

1、通过call allocate_a_4k_page为用户任务申请了一个新的空闲的物理页，作为用户任务的页目录表，记为页目录表（user），即书上所称的新页目录表；

2、给页目录表（user）的物理地址填上页的属性：US=1（只有特权级为3的用户程序可以访问该页）、RW=1（页是可读可写的）、P=1（页位于物理内存中）

mov ebx,eax
or ebx,0x00000007

3、装填好页属性的页目录表（user）的物理地址怎么处理？放到页目录表（core）的倒数第二个表项里去，页目录表（core），就是内核程序的页目录表，即书上所称的当前页目录表（看完步骤4，一起看图解）

 mov [0xfffffff8],ebx

4、为什么页目录表（user）的线性地址是0x FFFF E000?

回顾 为什么 页目录表（core） 的线性地址是0x FFFF F000
https://www.jianshu.com/p/d6b534560669

• 

  为什么`页目录表（user）`的线性地址是`0x FFFF E000`.png

• 首先，由于步骤3，页目录(core)的倒数第二个表项，填入了刚分配的物理页的物理地址，而这个物理页正是分配给用户程序做页目录表用的；

• 现在是在内核程序里面，调用的过程，因此CR3寄存器的内容指向的正是内核程序的页目录表；

• 页目录表（core）的倒数第一项在很早的时候就已经被填好了自己的物理地址；

具体的时间点在源码文件`c16_core.asm`是这样的：

开启分页机制之后

(第969~973行) 在倒数第一项填入自己的物理地址
具体实现与图解 
可见 https://www.jianshu.com/p/c251257329fe

....
....
....

(1067行） call load_relocate_program 
回到本文上方看标题，就可以明白逻辑顺序
call load_relocate_program 
|---- call sys_routine_seg_sel:create_copy_cur_pdir          

• 由倒数第二个表项的偏移量应该是0xFF8就可以逆推出中10位是0x3FE，全部写成二进制的序列就是 0011 1111 1110，而根据线性地址的格式，也可以知道最开始的两个零，其实是自己的补零，那么中10位本质上就是 11 1111 1110，全部组合起来，就可以得到页目录表（user）的线性地址是0x FFFF E000；
• 因此，验证了书上的结论：

`页目录表（user）`的线性地址是`0x FFFF E000`
`页目录表（core）`的线性地址是`0x FFFF F000`

5、将内核页目录表中的内容复制过去

mov esi,0xfffff000                 ;ESI->当前页目录的线性地址
mov edi,0xffffe000                 ;EDI->新页目录的线性地址
mov ecx,1024                       ;ECX=要复制的目录项数
cld
repe movsd 

• 复制操作的汇编指令rep的语法就是这样的， 只要提供源地址、目的地址并且指定传送方向即可；

rep 相关具体语法参见 https://www.jianshu.com/p/1b17ad3ad51f

• 值得一提的是，因为现在的内核程序运行已经开启了分页机制，所以源地址和目的地址都要提供线性地址，我们需要把目录表（core）的内容全部复制给目录表（user），就需要知道两个东西的线性地址。