易语言教程数据库写和添加记录

本课 示范了写（）、加记录（）、加空记录（）三个命令的使用方法。

视频链接：

511遇见易语言教程数据库

添加记录
（1）手动添加
（2）代码添加
使用代码添加和修改记录，主要有以下几个命令：
“加空记录（）”，可以在当前数据库记录的尾部添加一条空记录。
“加记录（）”，在添加空记录时，可以同时提供欲添加的数据。
“写（）”，可以将数据写入当前数据库中的当前记录处的指定字段内。

教程源码：

.版本 2

.程序集 窗口程序集_启动窗口

.子程序 _按钮1_被单击
.局部变量 字段表, 字段信息, , "4"

字段表 [1].名称 ＝ “姓名”
字段表 [2].名称 ＝ “语文”
字段表 [3].名称 ＝ “数学”
字段表 [4].名称 ＝ “英语”
连续赋值 (#文本型, 字段表 [1].类型, 字段表 [2].类型, 字段表 [3].类型, 字段表 [4].类型)

.如果 (创建 (“成绩”, 字段表) ＝ 假)
    信息框 (“创建数据库失败！！”, 0, , )
    返回 ()
.否则
    信息框 (“创建数据库成功！！”, 0, , )
.如果结束


.子程序 _按钮2_被单击
.局部变量 姓名, 文本型
.局部变量 语文, 文本型
.局部变量 数学, 文本型
.局部变量 英语, 文本型
.局部变量 i, 整数型

.判断开始 (编辑框1.内容 ≠ “” 且 编辑框2.内容 ≠ “” 且 编辑框3.内容 ≠ “” 且 编辑框4.内容 ≠ “”)
    姓名 ＝ 删首尾空 (编辑框1.内容)
    语文 ＝ 删首尾空 (编辑框2.内容)
    数学 ＝ 删首尾空 (编辑框3.内容)
    英语 ＝ 删首尾空 (编辑框4.内容)

.默认
    信息框 (“请输入相应字段的数据”, 0, , )
    返回 ()
.判断结束

.如果 (是否已打开 (取运行目录 () ＋ “\成绩.edb”) ＝ 假)
    打开 (取运行目录 () ＋ “\成绩.edb”, , , , , , )

.否则

.如果结束

' 写入记录

加记录 (姓名, 语文, 数学, 英语)

' 加空记录 ()
.' 计次循环首 (4, i)
    ' 写 (i, 多项选择 (i, 姓名, 语文, 数学, 英语))
.' 计次循环尾 ()

信息框 (“数据添加成功！！”, 0, , )
编辑框1.内容 ＝ “”
编辑框2.内容 ＝ “”
编辑框3.内容 ＝ “”
编辑框4.内容 ＝ “”
编辑框1.获取焦点 ()

.子程序 _编辑框1_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #回车键)
    编辑框2.获取焦点 ()
.如果真结束


.子程序 _编辑框2_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #回车键)
    编辑框3.获取焦点 ()
.如果真结束


.子程序 _编辑框3_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #回车键)
    编辑框4.获取焦点 ()
.如果真结束


.子程序 _编辑框4_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #回车键)
    _按钮2_被单击 ()
.如果真结束


.子程序 __启动窗口_将被销毁

关闭 ()

源码：511遇见易语言教程

           511遇见易语言教程视频链接

           511遇见易语言教程-数据库-写和添加记录