激活 Win10 企业版

创建文件 active.bat

@echo off&setlocal EnableDelayedExpansion&color 3e
title KMS_Activation for Windows 10

echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo    自动检查 Win10 的版本，导入相应的 KMS 密钥    
echo       然后连接指定的 KMS 服务器激活 Win10       
echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo.&echo.

:: 如果激活失败，可能是因为连不到KMS服务器了，你仅需修改下面的KMS服务器地址

::KMS_Sev=kms.landiannews.com
::set KMS_Sev=kms.xspace.in
::set KMS_Sev=zh.us.to
set KMS_Sev=kms.shuax.com
::set KMS_Sev=skms.ddns.net

::======================= 以下内容无需更改 ======================
call :verchk
call :adminchk

set Core=TX9XD-98N7V-6WMQ6-BX7FG-H8Q99
set CoreCountrySpecific=PVMJN-6DFY6-9CCP6-7BKTT-D3WVR
set CoreN=3KHY7-WNT83-DGQKR-F7HPR-844BM
set CoreSingleLanguage=7HNRX-D7KGG-3K4RQ-4WPJ4-YTDFH
set Professional=W269N-WFGWX-YVC9B-4J6C9-T83GX
set ProfessionalN=MH37W-N47XK-V7XM9-C7227-GCQG9
set Enterprise=NPPR9-FWDCX-D2C8J-H872K-2YT43
set EnterpriseN=DPH2V-TTNVB-4X9Q3-TJR4H-KHJW4
set Education=NW6C2-QMPVW-D7KKK-3GKT6-VCFB2
set EducationN=2WH4N-8QGBV-H22JP-CT43Q-MDWWJ
set EnterpriseS=WNMTR-4C88C-JK8YV-HQ7T2-76DF9
set EnterpriseSN=2F77B-TNFGY-69QQF-B8YKP-D69TJ

for /f "tokens=3 delims= " %%i in ('reg QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "EditionID"') do set EditionID=%%i

if defined %EditionID% (
    cscript //Nologo %windir%\system32\slmgr.vbs /ipk !%EditionID%!
    cscript //Nologo %windir%\system32\slmgr.vbs /skms %KMS_Sev%
    cscript //Nologo %windir%\system32\slmgr.vbs /ato
) else (
    echo.&echo Not found DEFINED Key: "%EditionID%".
    echo.
)
pause
exit

:verchk
ver | find "10.0." >nul 2>nul && (goto :EOF)
echo.&echo The current OS is NOT Windows 10.
echo.&pause
exit

:adminchk
reg query "HKU\S-1-5-19" >nul 2>nul || (
cls&echo.&echo 请右键以管理员身份运行.
echo.&echo Press any key to exit.
echo.&pause>nul
exit)
goto :EOF

右键选择“以管理员身份运行”。

激活失败的处理

如果你在联网激活时提示激活失败，多半是由于连接不到KMS服务器了。这时，可以通过修改上面的激活程序来解决。

::KMS_Sev=kms.landiannews.com
::set KMS_Sev=kms.xspace.in
::set KMS_Sev=zh.us.to
set KMS_Sev=kms.shuax.com
::set KMS_Sev=skms.ddns.net

定位到上面设置 KMS 服务器地址的代码块（其中 :: 表示当前行已被注释掉，去掉 :: 解除注释）。在上面 5 句中一个接一个的测试，总有一句会成功。