《如何提高彩票胜率》系列2:制作一个测试用开奖机__原创:简码编程

接上一篇的战略，从本篇开始，咱开始用数据和图表的方式来进行分析。

为了避免不必要的麻烦，咱们不接入任何彩票平台的真实开奖数据，而是自己写一个测试用的开奖机，用随机产生的开奖数据来验证各种提高胜率的思路。这个开奖机需要满足以下几点：

1、每隔一定的时间就开出一期。

2、可以在软件界面上直接看到当前的最新开奖结果。

3、可以用HTTP协议的方式供其它软件获取开奖数据进行分析。

程序需要用到定时器、HTTP服务端，PHP、Python、C#、C++、nodejs、JAVA等各种开发语言都可以实现这些功能，但电脑端桌面软件我还是首选国产编程语言Aardio，因为它简单易用。测试用的开奖机源码如下：

import win.ui;
/*DSG{{*/
var winform = win.form(text="测试用开奖机(作者:简码编程)";right=530;bottom=333)
winform.add(
buttonStart={cls="button";text="开始";left=146;top=287;right=215;bottom=316;z=2};
buttonStop={cls="button";text="停止";left=222;top=287;right=291;bottom=316;z=3};
editLog={cls="edit";left=16;top=10;right=518;bottom=273;edge=1;hscroll=1;multiline=1;vscroll=1;z=1}
)
/*}}*/

var 当天序号 = 0;
var 开奖期号 = "";
var 开奖号码 = "";
var 开奖时间 = "";

var timeHead = function(){
    var str = tostring(time(time.now(),"%Y-%m-%d %H:%M:%S"));
	return str; 
}

//定时器
import win.timer;
var timer = win.timer( winform );
timer.setInterval(3000)
timer.onTimer = function(hwnd,msg,id,tick){
    
    当天序号 = 当天序号+1;
    开奖期号 = tostring(time(time.now(),"%Y%m%d"))++string.format("%05d",当天序号)//前面补0,变成5位数编号
    
    var 万位 = string.random(1,"0123456789");
    var 千位 = string.random(1,"9876543210");
    var 百位 = string.random(1,"0123456789");
    var 十位 = string.random(1,"9876543210");
    var 个位 = string.random(1,"0123456789");
    开奖号码 = string.concat(万位,",",千位,",",百位,",",十位,",",个位)
    开奖时间 = timeHead();
    
	winform.editLog.print("开奖时间:"+开奖时间+" 开奖期号:"+开奖期号+" 开奖号码:"+开奖号码)
} 

//异步HTTP服务器
import wsock.tcp.asynHttpServer;
var srvHttp = wsock.tcp.asynHttpServer();
 
//指定IP，端口，运行HTTP服务端
srvHttp.start("127.0.0.1",80);
srvHttp.run( 
    function(response,request,session){
        //winform.editLog.print("HTTP协议访问：",request.url);
        response.contentType = "text/json"
        response.jsonPrettyPrint = true;
        reTable = {};
        reTable.开奖时间 = 开奖时间;
        reTable.开奖期号 = 开奖期号;
        reTable.开奖号码 = 开奖号码;
        response.write(reTable)
    } 	
);

winform.editLog.print("http服务端已启动:"+srvHttp.getUrl())

winform.buttonStart.oncommand = function(id,event){
    winform.editLog.print("开始")
	timer.enable();
}

winform.buttonStop.oncommand = function(id,event){
    winform.editLog.print("停止")
	timer.disable();
}

winform.show() 
win.loopMessage();

我们可以看到，这个程序是用定时器每隔三秒开出一期，每期的万位、千位、百位、十位、个位，都是从0至9这十个数字中随机选取一个，开奖后直接输出到软件界面的文本框，程序里还开了一个HTTP服务端，外部软件可以通过GET“http://127.0.0.1/”来获取到开奖的信息，在浏览器中直接打开此网址就可以看到它是JSON格式的文本

{
    "开奖号码":"2,1,1,6,1",
    "开奖时间":"2019-08-11 10:24:51",
    "开奖期号":"2019081101071"
}

这样我们就写好了一个测试用的开奖机，后面的提高胜率的思路都建立在这些随机的开奖数据上，请关注下一篇。

 

法律声明：本系列文章纯属研究提高胜率的思路和算法，不涉及具体彩种和任何彩票平台，一切均在合法合规的范围内进行，如有违规请联系作者反馈修正。本文为原创内容，作者保留所有权利，未经授权任何人不得转载、摘抄、引用、改编任何部分内容。授权转载请保留全文完整性和原文链接。