unity 卡通风格渲染
unity 卡通风格的渲染主要分成两个步骤，第一个步骤是给模型描边，第二个步骤是实现卡通着色的高光效果。这两个步骤同时也是对应的两个不同的pass。
第一个步骤首先要剔除正面，然后对背面的轮廓线进行描边，为什么要对背面进行描边呢。当然是因为对正面进行描边的效果很鬼畜啦，删除代码中的Cull Front，会看到下图的效果，所以这时候应该能理解为什么要对背面进行描边了，描边的方法是把顶点往法线的方向扩张一段距离，但是这样的话，如果一些内凹的物体，偏移的时候很可能就直接跑到前面来了，形成的画面很糟糕，因此，这里把所有的z值先减去0.5，然后再进行偏移。
观察代码：
float4 pos = mul(UNITY_MATRIX_MV, v.vertex);
float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);
normal.z = -0.5;
pos = pos + float4(normalize(normal), 0) * _Outline;
o.pos = mul(UNITY_MATRIX_P, pos);
其中有趣的是，我们是在观察空间进行偏移的，而不是在投影空间，因为投影空间已经不是线性变换了，这样扩张会出现错误，我们可以尝试着在投影空间进行上述变化。
float4 pos = mul(UNITY_MATRIX_MVP, v.vertex);
float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);
normal.z = -0.5;
pos = pos + float4(normalize(normal), 0) * _Outline;
o.pos = pos;
会出现下图的效果，显然不是我们想要的。
第二个步骤就是高光部分，高光的书写不同于blinn-phong模型，
fixed3 specular = _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _Specul在这里插入代码片arScale - 1)) * step(0.0001, _SpecularScale);
乍一看还是挺复杂的，我们可以去掉一些无关紧要的部分，比如去掉* step(0.0001, _SpecularScale);这个是为了让_SpecularScale=0的时候直接去掉高光，如果直接删掉这部分的话，我们看到原图还是有部分高光，如下图所示，因为_SpecularScale是个浮点数，虽然看起来是0，但是实际上存储的时候就不一定是0了，这句话表示如果_SpecularScale<0.0001的时候就直接把它当做0
然后就是smoothstep函数，这个函数是起的平滑作用，如果值大于w则返回1，小于-w返回0，否则在其中平滑差值，spec + _SpecularScale - 1这个结果和w的数值关系如果没有经验还是很难掌握好的，不过，这个shader里面这样写能得到很好的效果，很多时候，经验所得的数值还是很重要的，需要多积累一下。
完整代码如下：
Shader "Unity Shaders Book/Chapter 14/Toon Shading" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_MainTex ("Main Tex", 2D) = "white" {}
_Ramp ("Ramp Texture", 2D) = "white" {}
_Outline ("Outline", Range(0, 1)) = 0.1
_OutlineColor ("Outline Color", Color) = (0, 0, 0, 1)
_Specular ("Specular", Color) = (1, 1, 1, 1)
_SpecularScale ("Specular Scale", Range(0, 0.1)) = 0.01
}
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry"}
Pass {
NAME "OUTLINE"
Cull Front
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
float _Outline;
fixed4 _OutlineColor;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
};
v2f vert (a2v v) {
v2f o;
float4 pos = mul(UNITY_MATRIX_MV, v.vertex);
float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);
normal.z = -0.5;
pos = pos + float4(normalize(normal), 0) * _Outline;
o.pos = mul(UNITY_MATRIX_P, pos);
return o;
}
float4 frag(v2f i) : SV_Target {
return float4(_OutlineColor.rgb, 1);
}
ENDCG
}
Pass {
Tags { "LightMode"="ForwardBase" }
Cull Back
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_fwdbase
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "AutoLight.cginc"
#include "UnityShaderVariables.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _Ramp;
fixed4 _Specular;
fixed _SpecularScale;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
float4 tangent : TANGENT;
};
struct v2f {
float4 pos : POSITION;
float2 uv : TEXCOORD0;
float3 worldNormal : TEXCOORD1;
float3 worldPos : TEXCOORD2;
SHADOW_COORDS(3)
};
v2f vert (a2v v) {
v2f o;
o.pos = mul( UNITY_MATRIX_MVP, v.vertex);
o.uv = TRANSFORM_TEX (v.texcoord, _MainTex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
TRANSFER_SHADOW(o);
return o;
}
float4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
fixed3 worldHalfDir = normalize(worldLightDir + worldViewDir);
fixed4 c = tex2D (_MainTex, i.uv);
fixed3 albedo = c.rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
fixed diff = dot(worldNormal, worldLightDir);
diff = (diff * 0.5 + 0.5) * atten;
fixed3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;
fixed spec = dot(worldNormal, worldHalfDir);
fixed w = fwidth(spec) * 2.0;
fixed3 specular = _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _SpecularScale - 1)) ;
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}