从1.5.0-beta1开始，android的gradle插件引入了com.android.build.api.transform.Transform
，可以点击 http://tools.android.com/tech-docs/new-build-system/transform-api 查看相关内容。Transform
每次都是将一个输入进行处理，然后将处理结果输出，而输出的结果将会作为另一个Transform
的输入，过程如下：
Transform 是 Android Gradle API ，允许第三方插件在class文件转为dex文件前操作编译完成的class文件，这个API的引入是为了简化class文件的自定义操作而无需对Task进行处理。在做代码插桩时，本质上是在merge{ProductFlavor}{BuildType}Assets Task之后，transformClassesWithDexFor{ProductFlavor}{BuildType} Transform 之前,插入一个transformClassesWith{YourTransformName}For{ProductFlavor}{BuildType} Transform，此Transform中完成对class文件的自定义操作（包括修改父类继承，方法中的super方法调用，方法参数替换等等，这个class交给你，理论上是可以改到怀疑人生）。
注意，输出地址不是由你任意指定的。而是根据输入的内容、作用范围等由TransformOutputProvider生成，需要通过一下方法获取获取输出路径：
TransformOutputProvider.getContentLocation
添加依赖
com.android.tools.build:gradle:2.3.3
可以自定义一个Transform子类，然后在Plugin实现类的apply方法中 调用如下代码注册Tranform到编译过程中
//注册Transform
def android = project.extensions.getByType(AppExtension);
android.registerTransform(this)
为省事直接将上一篇的Plugin实现类继承Transform，代码如下
public class PluginImpl extends Transform implements Plugin {
void apply(Project project) {
//注册Transform
def android = project.extensions.getByType(AppExtension);
android.registerTransform(this)
}
// 设置我们自定义的Transform对应的Task名称
// 类似：TransformClassesWithPreDexForXXX
@Override
String getName() {
return "myTestTransform"
}
// 指定输入的类型，通过这里的设定，可以指定我们要处理的文件类型
//这样确保其他类型的文件不会传入
@Override
Set getInputTypes() {
return TransformManager.CONTENT_CLASS
}
// 指定Transform的作用范围
@Override
Set getScopes() {
return TransformManager.SCOPE_FULL_PROJECT
}
@Override
boolean isIncremental() {
return false
}
@Override
void transform(Context context, Collection inputs, Collection referencedInputs, TransformOutputProvider outputProvider, boolean isIncremental) throws IOException, TransformException, InterruptedException {
println '==================MyPlugin transform start=================='
inputs.each { TransformInput transformInput ->
// Transform的inputs有两种类型，一种是目录，一种是jar包，要分开遍历
//对类型为“文件夹”的input进行遍历
transformInput.directoryInputs.each { DirectoryInput directoryInput ->
//文件夹里面包含的是我们手写的类以及R.class、BuildConfig.class以及R$XXX.class等
MyInject.injectDir(directoryInput.file.absolutePath,"com\\example\\use_plugin")
// 获取output目录
def dest = outputProvider.getContentLocation(directoryInput.name,
directoryInput.contentTypes, directoryInput.scopes,
Format.DIRECTORY)
// 将input的目录复制到output指定目录
FileUtils.copyDirectory(directoryInput.file, dest)
}
//对类型为jar文件的input进行遍历
transformInput.jarInputs.each { JarInput jarInput ->
//jar文件一般是第三方依赖库jar文件
// 重命名输出文件（同目录copyFile会冲突）
def jarName = jarInput.name
def md5Name = org.apache.commons.codec.digest.DigestUtils.md5Hex(jarInput.file.getAbsolutePath())
if(jarName.endsWith(".jar")) {
jarName = jarName.substring(0,jarName.length()-4)
}
//生成输出路径
def dest = outputProvider.getContentLocation(jarName+md5Name,
jarInput.contentTypes, jarInput.scopes, Format.JAR)
//将输入内容复制到输出
FileUtils.copyFile(jarInput.file, dest)
}
}
}
}
MyInject找出特定的类，利用Javassist（同样功能的修改class文件的框架还有asm，asm与Javassist对比，在这不做重点）修改class文件。
要使用 Javassit添加如下依赖
compile 'org.javassist:javassist:3.20.0-GA'
MyInject源码如下：
public class MyInject {
private static ClassPool pool = ClassPool.getDefault();
private static String injectStr = "System.out.println(\"inster before =======\" ) "
public static void injectDir(String path, String packageName) {
pool.appendClassPath(path)
File dir = new File(path)
if (dir.isDirectory()) {
dir.eachFileRecurse { File file ->
String filePath = file.absolutePath
//确保当前文件是class文件，并且不是系统自动生成的class文件
if (filePath.endsWith(".class")
&& !filePath.contains('R$')
&& !filePath.contains('R.class')
&& !filePath.contains("BuildConfig.class")) {
// 判断当前目录是否是在我们的应用包里面
int index = filePath.indexOf(packageName);
boolean isMyPackage = index != -1;
if (isMyPackage) {
int end = filePath.length() - 6 // .class = 6
String className = filePath.substring(index, end)
.replace('\\', '.').replace('/', '.')
//开始修改class文件
CtClass c = pool.getCtClass(className)
if (c.isFrozen()) {
c.defrost()
}
CtConstructor[] cts = c.getDeclaredConstructors()
if (cts == null || cts.length == 0) {
//手动创建一个构造函数
CtConstructor constructor = new CtConstructor(new CtClass[0], c)
constructor.insertBeforeBody(injectStr)
c.addConstructor(constructor)
} else {
//如果已经有构造函数，则添加一行打印代码
cts[0].insertBeforeBody(injectStr)
}
c.writeFile(path)
c.detach()
}
}
}
}
}
}
以上只是简单的修改已有class字节码文件，利用该技术可以实现无痕埋点等深层次更能