[007][x86汇编语言]各个数位的显示 条件转移指令（搭配cmp）Bochs命令：n 、u 、info eflags

学习笔记

《x86汇编语言：从实模式到保护模式》
https://www.jianshu.com/p/d481cb547e9f

c06_mbr.asm

         ;代码清单6-1
         ;文件名：c06_mbr.asm
         ;文件说明：硬盘主引导扇区代码
         ;创建日期：2011-4-12 22:12 
      
         jmp near start
         
  mytext db 'L',0x07,'a',0x07,'b',0x07,'e',0x07,'l',0x07,' ',0x07,'o',0x07,\
            'f',0x07,'f',0x07,'s',0x07,'e',0x07,'t',0x07,':',0x07
  number db 0,0,0,0,0
  
  start:
         mov ax,0x07c0                  ;设置数据段基地址 
         mov ds,ax
         
         mov ax,0xb800                 ;设置附加段基地址 
         mov es,ax
         
         cld
         mov si,mytext                 
         mov di,0
         mov cx,(number-mytext)/2      ;实际上等于 13
         rep movsw
     
         ;得到标号所代表的偏移地址
         mov ax,number
         
         ;计算各个数位
         mov bx,ax
         mov cx,5                      ;循环次数 
         mov si,10                     ;除数 
  digit: 
         xor dx,dx
         div si
         mov [bx],dl                   ;保存数位
         inc bx 
         loop digit
         
         ;显示各个数位
         mov bx,number 
         mov si,4                      
   show:
         mov al,[bx+si]
         add al,0x30
         mov ah,0x04
         mov [es:di],ax
         add di,2
         dec si
         jns show
         
         mov word [es:di],0x0744

         jmp near $

  times 510-($-$$) db 0
                   db 0x55,0xaa

运行测试

c06_mbr.asm

代码说明

• 逻辑地址0x0000:0x7c00

对应的物理地址是 0x07c00
该地址又是段0x07c0的起始地址
等价的逻辑地址是 0x07c0:0x0000
------------------------------------------
mov ax,0x07c0                  ;设置数据段基地址 
mov ds,ax

• 批量复制

源数据 ds:si
目的地址 es:di

按字节传递 movsb
按字传递 movsw

正向传递 cld 低地址到高地址 DF = 0
反向传递 std 高地址到低地址 DF = 1

指令前缀 rep （repeat） ：CX不为零则重复

批量复制
--------------------------------
   cld
         mov si,mytext                 
         mov di,0
         mov cx,(number-mytext)/2      ;实际上等于 13
         rep movsw
--------------------------------

• Intel 8086 ： [BX] [SI] [DI] [BP]

BX （Base Address Register）基址寄存器
SI （Source Index）源索引寄存器
DI  (Destination Index）目标索引寄存器

[bx+si]
[bx+di]
[bp+si]
[bp+di]


AX （Accumulator）累加器
CX（Counter）计数器
DX（ Data）数据寄存器

• inc 指令

inc al
inc byte [bx]
inc word [label_a]

• div 指令

dividnd dw 0x3f0  ;被除数
divisor db 0x3f  ; 除数
...

mov ax,[dividnd]
div byte [divisor]

• cbw（convert byte to word）、cwd （convert word to double word）

《x86汇编语言：从实模式到保护模式》 cbw cwd

《x86汇编语言：从实模式到保护模式》 第84页

• 无符号数与有符号数 范围

无符号数
8位      0~255
16位 0~65535
32位 0~4294967295

有符号数
8位      -128~-1 0~127
16位 -32768~-1 0~32767

• 无符号数除法 div 、有符号数除法 idiv

《x86汇编语言：从实模式到保护模式》有符号数除法 idiv

《x86汇编语言：从实模式到保护模式》 第86页

• 现有指令对标志位的影响

《x86汇编语言：从实模式到保护模式》 现有指令对标志位的影响

《x86汇编语言：从实模式到保护模式》 第90页

• jns show 条件转移指令

如果未设置符号位SF，则转移到标号 show 所在的位置处执行；
有符号位 SF（sign flag）

《x86汇编语言：从实模式到保护模式》 jns show 条件转移指令

当显示完最后一个数位后，SI的内容是零，执行dec si指令后，由于产生了借位，实际的运算结果是0xffff（SI只能容纳16个比特），因其最高位是“1”，故处理器将标志位SF置为“1”，表明当前SI中的结果可以理解为一个负数（-1）。于是，指向jns show时，条件不满足，接着执行后面指令。
《x86汇编语言：从实模式到保护模式》 第88页

• 各种比较结果和相应的条件转移指令

《x86汇编语言：从实模式到保护模式》条件转移指令

《x86汇编语言：从实模式到保护模式》 第90页

《x86汇编语言：从实模式到保护模式》 表6-1 各种比较结果和相应的条件转移指令

《x86汇编语言：从实模式到保护模式》 第91页

《x86汇编语言：从实模式到保护模式》 表6-1 各种比较结果和相应的条件转移指令（续表）

《x86汇编语言：从实模式到保护模式》 第92页

• $ 与 $$

 jmp near $
等价于
infi: jmp near infi

$ 是当前行的汇编地址
-------------------------------------

$$ 是NASM汇编器提供的另一个标记，代表当前汇编节(段）的起始汇编地址
--------------------------------------
 times 510-($-$$) db 0
                   db 0x55,0xaa
主引导扇区512个字节，要求最后两个字节分别是 0x55,0xaa，多余部分用零填充

Bochs 调试

• 调试命令

n 命令 越过循环体
可以越过rep 、loop循环

u 命令 反汇编：根据机器指令生成可读的汇编语言指令
u/2 指定反汇编的条数为2

info eflags 查看标志寄存器：小写说明标志位0、大写为1

info eflags 查看标志寄存器：小写说明标志位0、大写为1

检测点6.5 使用反汇编命令定位到第53行jmp near $.png

• 调试过程记录

Next at t=0
(0) [0x0000fffffff0] f000:fff0 (unk. ctxt): jmpf 0xf000:e05b          ; ea5be000f0
 s
Next at t=1
(0) [0x0000000fe05b] f000:e05b (unk. ctxt): xor ax, ax                ; 31c0
 b 0x7c00
 c

...

 s
Next at t=17404890
(0) [0x000000007c60] 0000:7c60 (unk. ctxt): jns .-16 (0x00007c52)     ; 79f0
 u/3
00007c60: (                    ): jns .-16                  ; 79f0
00007c62: (                    ): mov word ptr es:[di], 0x0744 ; 26c7054407
00007c67: (                    ): jmp .-3                   ; e9fdff
 b 0x7c67
 c
(0) Breakpoint 2, 0x0000000000007c67 in ?? ()
Next at t=17404920
(0) [0x000000007c67] 0000:7c67 (unk. ctxt): jmp .-3 (0x00007c67)      ; e9fdff

参考

• [050][汇编语言]flag标志寄存器

https://www.jianshu.com/p/f694df2da5b4

• [052][汇编语言]检测点11.2（有符号数运算判断溢出OF的具体做法）

https://www.jianshu.com/p/bf51348d18d4