12.《汇编语言》-王爽第三版学习笔记 内中断

1. 中断

CPU 不再接着（刚执行完的指令）向下执行，而是转去处理这个特殊信息。

2. 8086CPU 产生中断的4种情况

（1）出发错误 比如 div指令产生的除法溢出 中断类型码：0
（2）单步执行 中断类型码：1
（3）执行 into 指令 中断类型码：4
（4）执行 int 指令 该指令的格式位 int n ，指令中的n为立即数，是提供给 CPU的 中断类型码

3. 中断向量表

• CPU 通过中断向量表找到中断程序的入口地址。
• 8086CPU 中 中断向量表就必须存放在 0000:0000 ～ 0000:03FF 中。
• 中断向量表中 一个表项存放一个中断向量，包括段地址 和 偏移地址。占两个字，高地址字存放段地址 低地址字存放偏移地址。

4. 8086CPU 收到中断信息后，引发的中断过程

（1）从中断信息中，取得中断类型码 取得中断类型码 N
（2）标志寄存器的值入栈（因为在中断过程中要改变标志寄存器的值，所以先将其值保存在栈中） pushf
（3）设置标志寄存器的第8为 TF 和 第9为 IF 的值为 0 TF=0 IF=0
（4）CS 的内容入栈 push cs
（5）IP 的内容入栈 push ip
（6）从内存地址为 中断类型码 4 和 中断类型码4+2 的两个字单元中读取中断处理程序的入口地址设置 IP 和 CS。 (ip)=(N4), (cs)=(N4+2)**

4. 中断处理程序 和 iret 指令

• 中断处理的常规步骤
  （1）保存用到的寄存器
  （2）处理中断
  （3）恢复用到的寄存器
  （4）用 iret 指令返回

• iret指令执行的操作是：
  pop IP
  pop CS
  popf
  在中断过程中 寄存器入栈的顺序是 标志寄存器 cs ip
  iret的出栈顺序是 ip cs 标志寄存器 正好一一对应。

5. 编写 0 号中断处理程序，在除法溢出发生时，在屏幕中间显式字符串 “divide error！！”，然后返回到 dos

assume cs:codesg

codesg segment

    start: ;do0 安装程序
           mov ax,cs     ;设置 ds:si 指向源地址
           mov ds,ax
           mov si,offset do0

           mov ax,0     ;设置 es:di 指向目的地址   
           mov es,ax
           mov di,200h

           mov cx,offset do0end - offset do0   ;设置 cx 传输长度

           cld   ;设置 传输方向为正
           rep movsb

           ;设置中断向量表
           mov ax,0
           mov es,ax
           mov word ptr es:[0*4],200h
           mov word ptr es:[0*4+2],0

           mov ax,1000h
           mov bh,1
           div bh

           mov ax,4c00h
           int 21h

      do0: jmp short do0start
           db "divide error!!"

 do0start: ;显示字符串"divide error!!"
           mov ax,cs
           mov ds,ax
           mov si,202h    ;设置 ds:si 指向字符串

           mov ax,0b800h
           mov es,ax
           mov di,12*160+36*2 ;设置 es:di 指向显存空间的中间位置

           mov cx,14
        s: mov al,[si]
           mov es:[di],al
           mov byte ptr es:[di+1],2
           inc si
           add di,2
           loop s

           mov ax,4c00h
           int 21h

   do0end: nop

codesg ends

end start