今天，给大家介绍一个Microsoft365（原Office365）Excel新增函数--XLOOKUP函数。ps：还没用上Microsoft365的后台联系我，免费安装！
函数说明：
作用：
XLOOKUP 函数搜索区域或数组，然后返回对应于它找到的第一个匹配项的项。如果不存在匹配项，则 XLOOKUP 可以返回最接近 (匹配) 值。
语法：
XLOOKUP(lookup_value,lookup_array, return_array, [if_not_found], [match_mode], [search_mode])
参数：
lookup_value：必需，要查找的值
lookup_array：必需，要查找的数组或区域
return_array：必需，要返回的数组或区域
[if_not_found]：可选，如果找不到有效的匹配项，则返回此参数，忽略则显示#N/A错误。
[match_mode]：可选，指定匹配类型：
0 - 精确匹配。如果未找到，则返回 #N/A。这是默认选项。
-1 - 模糊匹配。如果没有找到，则返回下一个较小的项。
1 - 模糊匹配。如果没有找到，则返回下一个较大的项。
2 - 通配符匹配，其中 *, ? 和 ~ 有特殊含义。
[search_mode]：可选，指定要使用的查找方式：
1 - 从第一项开始执行搜索。这是默认选项。
-1 - 从最后一项开始执行反向搜索。
2 - 执行依赖于 lookup_array 按升序排序的二进制搜索。如果未排序，将返回无效结果。
-2 - 执行依赖于 lookup_array 按降序排序的二进制搜索。如果未排序，将返回无效结果。
用法示例：
1单条件精确查询
查找各个人的电话号码。
公式：=XLOOKUP(E2,A:A,C:C)
2屏蔽错误值
查找各个人的电话号码，找不到的就显示“找不到”。
公式：=XLOOKUP(E2,A:A,C:C,"找不到")
3单条件模糊查询
查找姓名包含“麻子”的特长。
公式：=XLOOKUP("*"&E2&"*",A:A,B:B,"找不到",2)
4区间查询
根据分数区间查询每个学生的等级。
公式：=XLOOKUP(C2,$F$2:$F$5,$G$2:$G$5,,-1)
5从后往前查
查找每个人最近一次的销售额。
公式：=XLOOKUP(E2,$B$2:$B$11,$C$2:$C$11,"找不到",0,-1)
6横向查找
查找张三的语文成绩。
公式：=XLOOKUP(F1,B1:D1,B2:D2)
7返回标题排列顺序一致的多列结果
返回标题排列顺序一致的多列结果
公式：=XLOOKUP(F2,A:A,B:D)
8返回标题排列不一致的多列结果
返回标题排列不一致的多列结果
公式：=XLOOKUP($F2,$A$2:$A$11,XLOOKUP(G$1,$B$1:$D$1,$B$2:$D$11))
9多条件查询
多条件查询
公式：=XLOOKUP(E2&F2,$A$2:$A$11&$B$2:$B$11,$C$2:$C$11)
10引用使用
求2021年3月到2021年7月的销售额总和。
公式：=SUM(XLOOKUP(E1,A2:A10,B2:B10):XLOOKUP(E2,A2:A10,B2:B10))
11向左查找
查找特长为Power Query的人的姓名。
公式：=XLOOKUP(D2,B:B,A:A)
写在最后：
作者只是抛砖引玉，更多更强大的功能等你来发现！
▼近期好文推荐▼
查找函数10个高阶用法
强大到没朋友的Excel函数--FILTER函数
Excel小技巧——批量新建文件夹
Excel中5个小技巧，看看你会几个？
连Excel打印都不会，怎么登上职场巅峰？
—END—