Unity Shader 逐像素半兰伯特漫反射光照（五）

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

逐像素半兰伯特漫反射光照效果：

逐像素半兰伯特漫反射光照.png

逐顶点兰伯特漫反射光照、逐像素兰伯特漫反射光照、逐像素半兰伯特漫反射光照效果：

逐顶点兰伯特漫反射光照、逐像素兰伯特漫反射光照、逐像素半兰伯特漫反射光照.png

半兰伯特漫反射公式：Id = Ip * Kd * (N * L * 0.5 + 0.5)
IP：入射光的光颜色；
Kd：漫反射系数 ( 0 ≤ Kd ≤ 1)；
N：单位法向量；
L：单位光向量；
原理：由于兰伯特光照模型计算出模型背面的颜色为负数，模型背面会变成黑色，
改进为将[-1, 1]映射到[0, 1]上，即乘以0.5，再加上0.5。

Shader代码：

// 逐像素光照：半兰伯特模型
Shader "Custom/Diffuse/HalfLambertDiffusePixel"
{
    Properties
    {
        // 漫反射光颜色
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
    }
    
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        LOD 100
        
        pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            
            fixed4 _Diffuse;
            
            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION;
                float3 normal: NORMAL;
            };
            
            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION;
                fixed3 worldNormal: TEXCOORD0;
            };
            
            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;
                
                // 将顶点坐标从模型空间变换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 将法线从模型空间变换到世界空间，然后归一化
                // 等价于o.worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                
                return o;
            }
            
            // 片元着色器函数
            fixed4 frag(v2f i): SV_TARGET
            {
                // 获得单位光向量
                float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 计算漫反射
                // 半兰伯特公式：Id = Ip * Kd * (N * L * 0.5 + 0.5)
                // IP：入射光的光颜色；
                // Kd：漫反射系数 ( 0 ≤ Kd ≤ 1)；
                // N：单位法向量，L：单位光向量
                // 原理：由于兰伯特光照模型计算出模型背面的颜色为负数，模型背面会变成黑色，
                // 改进为将[-1, 1]映射到[0, 1]上，即乘以0.5，再加上0.5
                float3 diffuse = _LightColor0.rgb * _Diffuse.rgb * (dot(i.worldNormal, worldLightDir) * 0.5 + 0.5);
                
                // 环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                fixed3 color = ambient + diffuse;
                return fixed4(color, 1);
            }
            
            ENDCG
            
        }
    }
}