1. 目的
获取文件末次修改时间，可以进行一些的程序检查。
例如，.sas和.log的末次修改时间，两者比较可以判断出，程序更新后，是否重新Run过；例如，Source侧 (Production)的.log文件与QC侧 (Validation)的.log的末次修改时间，判断V侧程序是否在P侧程序之后Run过。
2. 涉及内容
前面两篇文章介绍了，通过SAS编程，如何获取某路径下的所有文件名称，以及如何如何获取某个文件的末次修改时间：
SAS编程：如何获取某路径下文件的名称？
SAS编程：如何获取某文件的修改时间？
这篇文章是两者内容的结合，先使用Dopen系列函数获取所有文件的名称（文件路径），再使用Fopen系列函数获取所有文件的修改时间。
文章中所涉及具体函数介绍，参考以下两篇文章：
SAS编程：Dopen系列函数介绍
SAS编程：Fopen系列函数介绍
我使用以下路径文件进行演示，路径中有4个.sas文件、4个.log文件，以及1个文件夹，共9个文件。
3. 获取所有文件的名称（文件路径）
使用Dopen函数打开指定路径，在当前SAS会话中，获取路径ID；使用Dnum函数获取该路径内的文件数目；使用Do语句循环以及Dread函数，获取路径下每一个文件的名称。
获取名称后，将文件夹路径与文件名称拼接，就获取到文件的对应路径。
**Dopen;
%let dirpath = E:\99_Test\Test\test1;
data _tmp1;
fileres=filename("dirpath","&dirpath.");
dirid=dopen("dirpath");
num = dnum(dirid);
length direct filename filepath $200;
if dirid > 0 and num > 0 then do;
do i = 1 to num;
direct = "&dirpath.";
filename = dread(dirid, i);
filepath = catx("\", direct,filename);
output;
end;
end;
keep direct filename filepath;
run;
运行结果如下：
4. 获取所有文件的修改时间
使用Fopen函数打开文件路径，在当前SAS会话中，获取文件ID；使用Finfo函数获取文件的修改时间。
不同SAS语言环境下，文件的属性名称不同。以末次修改时间为例：中文环境，“上次修改时间”；英文环境，“Last Modified”。
中文环境：
**Fopen -- Chinese;
data _tmp2;
set _tmp1;
*Get fileID;
fileres = filename("filepath", filepath);
fileid = fopen("filepath");
*Get Last Modified date;
if fileid > 0 then do;
length Last_modified $200;
Last_modified = finfo(fileid, "上次修改时间");
end;
*Close fileID;
fileid_c = fclose(fileid);
run;
结果如下：
英文环境：
**Fopen -- English;
data _tmp2;
set _tmp1;
*Get fileID;
fileres = filename("filepath", filepath);
fileid = fopen("filepath");
*Get Last Modified date;
if fileid > 0 then do;
length Last_modified $200;
Last_modified = finfo(fileid, "Last Modified");
end;
*Close fileID;
fileid_c = fclose(fileid);
run;
最后使用fclose函数注销当前SAS会话中文件ID的这一操作，在日常工作中比较常用，也是一个比较好的编程习惯。
例如，对于不需要输出到SAS Results页面的程序结果，可以在其前后添加：ods results off;, ods results on，即关闭后再打开。
例如，在日志中输出某个宏程序的运行代码，可以在其前后添加：options mprint;, options nomprint;, 即打开后再关闭。
读者可以自行测试下，上面代码去掉fclose函数处理后是什么输出结果。
总结
对于第4步，我尝试了好几种方法，当前处理是最简洁的。
之前文章SAS宏程序：批量获取文件的修改时间介绍了，SAS如何通过调用本机电脑CMD语句的返回结果，批量获取文件的修改时间。但在公司服务器系统测试发现，SAS无法访问CMD结果，我没去深究具体原因。
Python环境下，实现这一功能也不复杂，但要考虑是否允许在公司系统内进行，需要跟IT沟通。
感谢阅读， 欢迎关注！
若有疑问，欢迎评论交流！