工具/使用脚本修改windows本地IP地址

概述

在进行局域网内网络通信的程序调试时，通过要设置固定的IP地址，但如此一来通常就会影响到Internet上网功能，因此可能会有这样的需求，切换网卡设置为静态IP地址或DHCP动态IP地址，挺麻烦的确实…
另外，有时候为了绕过公司的内网过滤，通过连接非内网的无线或热点连接来访问一些必要的网站，我们可能需要禁用连接内网的网卡，然后再适时打开…

脚本内容

新建文本文件，添加如下脚本代码。

@echo off
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
 
@echo off
:start
echo 1(静态IP)
echo 2(动态IP)
echo 3(禁用网卡)
echo 4(启用网卡)
set /P var="请选择你的设置:"
if %var%==1 goto ip1
if %var%==2 goto ip2
if %var%==3 goto x_disable 
if %var%==4 goto x_enable

:ip1
cls
netsh interface ip set address "以太网" static 10.60.66.20 255.255.255.0 10.60.66.254
ipconfig /flushdns
echo ** 切换静态IP **
echo ------------------------------------------
pause
exit

:ip2
cls
netsh interface ip set address "以太网" dhcp
netsh interface ip set dns "以太网" dhcp
ipconfig /flushdns
echo ** 切换动态IP **
echo ------------------------------------------
pause
exit

:x_disable
cls
netsh interface set interface "以太网" disabled
ipconfig /flushdns
echo ** 禁用网卡设置成功 **
echo ------------------------------------------
pause
exit

:x_enable
cls
netsh interface set interface "以太网" enabled
ipconfig /flushdns
echo ** 启用网卡设置成功 **
echo ------------------------------------------
pause
exit

基本说明

其中：“以太网” 是网卡的名称，可更改网络适配器界面 (控制面板\所有控制面板项\网络连接) 进行设置，它可以是"以太网"、“以太网 2”、“WLAN 2”…等，注意，人家名称里有空格的话，你也不要落下。

保存和运行

保存后，修改文件名称后缀为.bat格式（如change_ip.bat），最后双击运行即可。
若果在运行过程中，出现乱码，可以使用NotPad++ 或 EditPlus 修改文件编码格式，从UTF8到ANSI编码。（以NotPad++为例，其修改方法为：菜单栏_编码 -> 转为ANSI编码）