舔一舔红宝石炼就得仙丹

最近看博客被安利一颗仙丹elixir.

# 打开iterm输入，读作 [ɪˈlɪksɚ]
say elixir

elixir基于erlang vm，语法近似ruby。
号称兼具二者的优点：高性能、并发稳定，语法不再像erlang一样反人类，可以元编程。
另外这课丹，没有OO，有FP。
我copy了一份ElixirSchool放在我的主机上

在elixir的基础知识里面，只有模式匹配 (Pattern Matching) ，比较难理解。
因为elixir使用=，这个通常在其他语言中用来赋值的符号，用于模式匹配。

iex(1)> x = 1
1
iex(2)> 1 = x
1
iex(3)> 2 = x
** (MatchError) no match of right hand side value: 1

iex(3)> x = 2
2
iex(4)> 2 = x
2
iex(5)> 1 = x
** (MatchError) no match of right hand side value: 2

1 = x放在其他语言是铁定出错的，你不能让1等于其他值。

但是在elixir里面，1 = x表示的却和数学上的一样。
x = 1当然1 = x，而2 = x不成立。
当x = 2时，有2 = x却不会有1 = x

有时候却又要像正则表达式的匹配一样理解，

iex(1)> {:ok, value} = {:ok, "Successful!"}
{:ok, "Successful!"}
iex(2)> value
"Successful!"
iex(3)> {:ok, value} = {:error, "Error!"}
** (MatchError) no match of right hand side value: {:error, "Error!"}
iex(3)> value
"Successful!"

:ok匹配了:ok所以value取得了"Successful!"
:ok不能匹配了:error，所以value保持原值。

一个用猜数字的游戏，大家看看，基本比较好理解。

defmodule Guess do
  # 模块注释
  @moduledoc """
  猜数字游戏
  游戏设定一个数字
  用户输入一个数字，
  提示用户输入与设定数字的大小关系
  同一个数字最多才7次，超过7次，提示用户开始新的游戏
  猜对数字，提示用户在玩一局
  """

  # 定义模块属性
  @max_time 7
  @number_range 1..100

  # 函数注释
  @doc """
  开始一个游戏
  """
  def begin do
    start(init_number())
  end

  # defp定义私有函数
  defp init_number do
    Enum.random(@number_range)
  end

  # 设置默认参数
  defp start(number, time \\ @max_time)

  # 匹配所有number但time=0的情况
  defp start(_, 0) do
    one_more_time()
  end

  defp start(number, time) do
    case guess_a_number() do
      ^number ->
        IO.puts "少年，猜对了!"
        one_more_time()
      # 使用哨兵检查匹配的数字
      x when x > number ->
        try_again("大了点", number, time - 1)
      # 缺省选项，排除了=和>,只有<匹配
      _ ->
        try_again("还不够", number, time - 1)
    end
  end

  defp guess_a_number do
    try do
      # pipe 管道，将输入传给第一个函数，并把输出作为后续方法的输入
      "猜猜看呀:"
      |> IO.gets
      |> String.trim
      |> String.to_integer
    rescue
      # 输入无法转换为数字时，忽略error，递归提示重新输入
      _ ->
        IO.puts "请输入数字，敲黑板！"
        guess_a_number()
    end
  end

  defp one_more_time do
    case IO.gets "大爷，再来一局吧？[y/N]" do
      "y\n" ->
        begin()
      _ ->
        "大爷，下次再来！"
    end
  end

  defp try_again(message, number, time) do
    IO.puts message
    start(number, time)
  end
end

Guess.begin()