iOS-底层原理：alloc & init & new 源码分析

写在前面：本文并非原创，再此使用也仅为学习记录，以便后期复习，原文作者：Style_月月，地址：https://www.jianshu.com/p/b72018e88a97

一、学习底层原理，我们首先要找到Apple开源的代码库地址：

1、Apple 所有开源源码汇总地址，根据相应的版本查找对应的源码，以mac 10.15为例: macOS --> 10.15 --> 选择10.15 --> 搜索 objc
2、Apple 比较直接的源码下载地址，直接搜索想要下载的源码名称即可，例如objc：直接搜索 objc --> objc4/ --> 选择相应的objc的版本

二、源码分析

在分析alloc源码之前，先来看看一下3个变量 内存地址 和 指针地址区别：

内存地址与指针地址.png

分别输出3个对象的内容、内存地址、指针地址，下图是打印结果

image.png

结论：通过上图可以看出，3个对象指向的是同一个内存空间，所以其内容和内存地址是相同的，但是对象的指针地址是不同的
补充
%p -> &p1：是对象的指针地址
%p -> p1： 是对象指针指向的的内存地址

这就是本文需要探索的内容，alloc做了什么？init做了什么？

三、alloc 源码探索

alloc + init 整体源码的探索流程如下

alloc + init探索流程.png

• 【第一步】首先根据main函数中的YXPerson类的alloc方法进入alloc方法的源码实现（即源码分析开始），

//alloc源码分析-第一步
+ (id)alloc {
    return _objc_rootAlloc(self);
}

• 【第二步】跳转至_objc_rootAlloc的源码实现

// Base class implementation of +alloc. cls is not nil.
// Calls [cls allocWithZone:nil].
id
_objc_rootAlloc(Class cls)
{
    return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}

• 【第三步】跳转至callAlloc的源码实现

static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)// alloc 源码 第三步
{
#if __OBJC2__ //有可用的编译器优化
    /*
     参考链接：https://www.jianshu.com/p/536824702ab6
     */
    
    // checkNil 为false，!cls 也为false ，所以slowpath 为 false，假值判断不会走到if里面，即不会返回nil
    if (slowpath(checkNil && !cls)) return nil;
    
    //判断一个类是否有自定义的 +allocWithZone 实现，没有则走到if里面的实现
    if (fastpath(!cls->ISA()->hasCustomAWZ())) {
        return _objc_rootAllocWithZone(cls, nil);
    }
#endif

    // No shortcuts available. // 没有可用的编译器优化
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

如上所示，在calloc方法中，当我们无法确定实现走到哪步时，可以通过断点调试，判断执行走哪部分逻辑。这里是执行到_objc_rootAllocWithZone

• 【第四步】跳转至_objc_rootAllocWithZone的源码实现

id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)// alloc 源码 第四步
{
    // allocWithZone under __OBJC2__ ignores the zone parameter
    //zone 参数不再使用 类创建实例内存空间
    return _class_createInstanceFromZone(cls, 0, nil,
                                         OBJECT_CONSTRUCT_CALL_BADALLOC);
}

• 【第五步】跳转至_class_createInstanceFromZone的源码实现，这部分是alloc源码的核心操作，由下面的流程图及源码可知，该方法的实现主要分为三部分
• cls->instanceSize：计算需要开辟的内存空间大小
• calloc：申请内存，返回地址指针
• obj->initInstanceIsa：将 类 与isa关联

static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
                              int construct_flags = OBJECT_CONSTRUCT_NONE,
                              bool cxxConstruct = true,
                              size_t *outAllocatedSize = nil)// alloc 源码 第五步
{
    ASSERT(cls->isRealized()); //检查是否已经实现

    // Read class's info bits all at once for performance
    //一次性读取类的位信息以提高性能
    bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
    bool hasCxxDtor = cls->hasCxxDtor();
    bool fast = cls->canAllocNonpointer();
    size_t size;

    //计算需要开辟的内存大小，传入的extraBytes 为 0
    size = cls->instanceSize(extraBytes);
    if (outAllocatedSize) *outAllocatedSize = size;

    id obj;
    if (zone) {
        obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
    } else {
        //申请内存
        obj = (id)calloc(1, size);
    }
    if (slowpath(!obj)) {
        if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
            return _objc_callBadAllocHandler(cls);
        }
        return nil;
    }

    if (!zone && fast) {
        //将 cls类 与 obj指针（即isa） 关联
        obj->initInstanceIsa(cls, hasCxxDtor);
    } else {
        // Use raw pointer isa on the assumption that they might be
        // doing something weird with the zone or RR.
        obj->initIsa(cls);
    }

    if (fastpath(!hasCxxCtor)) {
        return obj;
    }

    construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
    return object_cxxConstructFromClass(obj, cls, construct_flags);
}

_class_createInstanceFromZone流程.png

四、内存字节对齐原则

Apple的分配内存是16字节对齐，在解释为什么需要16字节对齐之前，首先需要了解内存字节对齐的原则，主要有以下三点

• 数据成员对⻬规则：结构(struct)(或联合(union))的数据成员，第⼀个数据成员放在offset为0的地⽅，以后每个数据成员存储的起始位置要从该成员⼤⼩或者成员的⼦成员⼤⼩（只要该成员有⼦成员，⽐如说是数组，结构体等）的整数倍开始(⽐如int为４字节，则要从４的整数倍地址开始存储。 比如：当前开始的位置m = 9 接下来的数据成员n = 4，则n从12的位置开始。
• 结构体作为成员：如果⼀个结构⾥有某些结构体成员，则结构体成员要从其内部最⼤元素⼤⼩的整数倍地址开始存储，(struct a⾥存有struct b，b⾥有char，int ，double等元素，那b应该从8的整数倍开始存储)。
• 结构体的整体对齐规则:结构体的总⼤⼩，也就是sizeof的结果，必须是其内部最⼤成员的整数倍，不⾜的要补⻬。

为什么需要16字节对齐
需要字节对齐的原因，有以下几点：

• 通常内存是由一个个字节组成的，cpu在存取数据时，并不是以字节为单位存储，而是以块为单位存取，块的大小为内存存取力度。频繁存取字节未对齐的数据，会极大降低cpu的性能，所以可以通过减少存取次数来降低cpu的开销
• 16字节对齐，是由于在一个对象中，第一个属性isa占8字节，当然一个对象肯定还有其他属性，当无属性时，会预留8字节，即16字节对齐，如果不预留，相当于这个对象的isa和其他对象的isa紧挨着，容易造成访问混乱
• 16字节对齐后，可以加快CPU读取速度，同时使访问更安全，不会产生访问混乱的情况
  总结
• 通过对alloc源码的分析，可以得知alloc的主要目的就是开辟内存，而且开辟的内存需要使用16字节对齐算法，现在开辟的内存的大小基本上都是16`的整数倍
• 开辟内存的核心步骤有3步：计算 -- 申请 -- 关联

五、init 源码探索

alloc源码探索完了，接下来探索init源码，通过源码可知，inti的源码实现有以下两种
类方法 init

+ (id)init {
    return (id)self;
}

这里的init是一个构造方法 ，是通过工厂设计（工厂方法模式）,主要是用于给用户提供构造方法入口。这里能使用id强转的原因，主要还是因为内存字节对齐后，可以使用类型强转为你所需的类型
实例方法 init

• 通过以下代码进行探索实例方法 init

LGPerson *objc = [[LGPerson alloc] init];

• 通过main中的init跳转至init的源码实现

- (id)init {
    return _objc_rootInit(self);
}

• 跳转至_objc_rootInit的源码实现

id
_objc_rootInit(id obj)
{
    // In practice, it will be hard to rely on this function.
    // Many classes do not properly chain -init calls.
    return obj;
}

有上述代码可以，返回的是传入的self本身。

六、new源码探索

一般在开发中，初始化除了init，还可以使用new，两者本质上并没有什么区别，以下是objc中new的源码实现，通过源码可以得知，new函数中直接调用了callAlloc函数（即alloc中分析的函数），且调用了init函数，所以可以得出new其实就等价于[alloc init]的结论。

+ (id)new {
    return [callAlloc(self, false/*checkNil*/) init];
}

但是一般开发中并不建议使用new，主要是因为有时会重写init方法做一些自定义的操作，例如initWithXXX，会在这个方法中调用[super init]，用new初始化可能会无法走到自定义的initWithXXX部分。

总结

• 如果子类没有重写父类的init，new会调用父类的init方法
• 如果子类重写了父类的init，new会调用子类重写的init方法
• 如果使用alloc + 自定义的init，可以帮助我们自定义初始化操作，例如传入一些子类所需参数等，最终也会走到父类的init，相比new而言，扩展性更好，更灵活。