SAS 程序冷知识——基线BLFL的制作

一、在data步中完成

proc sort data=LB_SDTM1;by SUBJID LBCAT LBTESTCD descending LBDTCN descending LBDTC;run;

data LB_QSDTM;

set LB_SDTM1;

by SUBJID LBCAT LBTESTCD descending LBDTCN;

if LBSTAT^='NOT DONE' then do;

    LBDYlg=lag(LBDY);

    SUBJIDlg=lag(SUBJID);

    LBCATlg=lag(LBCAT);

    LBTESTCDlg=lag(LBTESTCD);

end;

if . < LBDY <= 1 and (LBDYlg>1 or SUBJID ne SUBJIDlg or LBCAT ne LBCATlg or LBTESTCD ne LBTESTCDlg) and LBSTAT^='NOT DONE' then LBBLFL='Y';

run;

        首先是排序，排序一定是按照时间倒叙排列，因为基线的制作是要保证2个条件，一个是早于首次用药，这个很好判断。另一个是要在时间上距离首次用药最近，这个如果在正序的前提下很难得到，因为sas没法预判下一条（下一个时间点）是不是也在首次用药之前，这样就没法判断当前的观测是不是距离最近的了。

        一般在SDTM中DY变量会指示具体首次用药的日期差值，我们可以直接使用这个变量，如果条件不允许可以自己制作，无论是日期差还是时间差都是可以的。这里使用的是LBDY，因为如果日期相等，DY变量会＋1，所以是小于等于1作为判断是否早于给药时间的条件。而LBDYlg这个变量是上一条中的LBDY，LBDYlg > 1 是为了保证当前一条是距离给药时间最近的一条。因为我们时间是倒序的，所以上一条是下一个时间点，下一个时间点晚于给药时间，本条早于给药时间才能满足条件。

        LBDYlg>1 后面跟了一大串 SUBJID ne SUBJIDlg or LBCAT ne LBCATlg or LBTESTCD ne LBTESTCDlg 。这些条件是为了防止出现下面情况：本条的时间点是给药前，并且是当前参数下的最后一个时间点。此时本条应该被标记为基线，但如果没有这一大串代码，是无法实现标记基线的。具体原因如下：我们是希望以每 SUBJID LBCAT LBTESTCD（这个组合当然要根据需要调整） 的一个值得组合，作为一个单独的考察基线的分组。所以我们会按SUBJID LBCAT LBTESTCD排序，这样，如果本条和上一条相比，无论这三个变量中的哪一个发生变化，就说明本条已经是一个新的分组了。别忘记我们是按时间倒序排序的，换句话说此时当前分组的最晚的一条依然要早于给药时间。既然已经是最后一条，那麽就只能加上基线标记了（当然这是可以根据实际需要调整的）。

        同时，条件中还有一个 LBSTAT^='NOT DONE' 这个很显然，未作的行不能做为基线。但是需要解释的是为什么不能在最后的赋值LBBLFL的if语句中直接使用lag函数，而是要事先复制，以及赋值的时候为什么要加条件。

        以上的所有关于LBDYlg，SUBJIDlg，LBCATlg，LBTESTCDlg 的分析中，都隐含着一个前提，就是上一行必须不能是 LBSTAT='NOT DONE' 的。如何保证上一行肯定不是未做呢？这就涉及到 lag 函数的特点：严格来说 lag 函数并不是返回变量上一行的值，而是返回 lag 函数 上一次起作用时，那个变量的值。

        所以我们不能在最后的赋值LBBLFL的if语句中直接使用lag函数，因为每一行都会执行从 if 到 then 中间的部分，所以如果写成 ：

if . < LBDY <= 1 and (

lag (LBDY)>1 or 

SUBJID ne lag (SUBJID) or 

LBCAT ne lag (LBCAT) or 

LBTESTCD ne lag (LBTESTCD)

) and LBSTAT^='NOT DONE' then LBBLFL='Y';

则lag 函数返回的永远是上一行，而上一行是无法确保一定不是 LBSTAT='NOT DONE'  的。而如果我们在前面事先赋值，而且放在条件语句then的后面：

if LBSTAT^='NOT DONE' then do;

    LBDYlg=lag(LBDY);

    SUBJIDlg=lag(SUBJID);

    LBCATlg=lag(LBCAT);

    LBTESTCDlg=lag(LBTESTCD);

end;

则 lag 函数上一次起作用的值，永远是符合LBSTAT^='NOT DONE'的观测，因此它返回的一定是上一次LBSTAT^='NOT DONE' 的观测值，这样就可以完美跳过未做行。

        这也是为什么不使用first和last方法而使用lag来确定分组的原因，因为使用first或last，最终也是无法判断是否未做。最后这个语句还有一个好处，就是它可以嵌入到其他data步当中，只要事先排序，不需要使用by语句，所以不会收到merge是by语句的限制。

如果需要做基线后的话可以加上：

proc sort data=LB_SDTM1;by SUBJID LBCAT LBTESTCD descending LBDTCN descending LBDTC;run;

data LB_QSDTM;

set LB_SDTM1;

by SUBJID LBCAT LBTESTCD descending LBDTCN;

retain LBPOBLFL ;

if LBSTAT^='NOT DONE' then do;

    LBDYlg=lag(LBDY);

    SUBJIDlg=lag(SUBJID);

    LBCATlg=lag(LBCAT);

    LBTESTCDlg=lag(LBTESTCD);

end;

if . < LBDY <= 1 and (LBDYlg>1 or SUBJID ne SUBJIDlg or LBCAT ne LBCATlg or LBTESTCD ne LBTESTCDlg) and LBSTAT^='NOT DONE' then LBBLFL='Y';

if (SUBJID ne SUBJIDlg or LBCAT ne LBCATlg or LBTESTCD ne LBTESTCDlg) then LBPOBLFL='Y'; 

if  LBBLFL='Y' then LBPOBLFL='';

run;

当然，这样需要在后续的data步中，去掉未做行的标记。

二、SQL一步完成（待续）