多个独立的excel文件合并到一个excel文件的多个工作表Sheet中

上篇说到将excel中的一个工作表按照某列拆分成多个sheet工作表，那么如何将多个独立的excel文件合并到一个excel文件的多个工作表Sheet中呢，接下来就利用VBA工具来解决这个问题。
合并前:

合并后：

第一步：新建一个excel文件，点击“开发工具—>查看代码”命令，如图所示：

第二步：右击“WPS表格对象—>插入—>模块”命令，插入代码后点击“运行”即可。或者点击“运行—>运行子过程/用户窗体”菜单。如图所示：

具体代码如下：

Sub Books2Sheets()
    '定义对话框变量
    Dim fd As FileDialog
    Set fd = Application.FileDialog(msoFileDialogFilePicker)
    
    '新建一个工作簿
    Dim newwb As Workbook
    Set newwb = Workbooks.Add
    
    With fd
        If .Show = -1 Then
            '定义单个文件变量
            Dim vrtSelectedItem As Variant
            
            '定义循环变量
            Dim i As Integer
            i = 1
            
            '开始文件检索
            For Each vrtSelectedItem In .SelectedItems
                '打开被合并工作簿
                Dim tempwb As Workbook
                Set tempwb = Workbooks.Open(vrtSelectedItem)
                
                '复制工作表
                tempwb.Worksheets(1).Copy Before:=newwb.Worksheets(i)
                
                '把新工作簿的工作表名字改成被复制工作簿文件名，这儿应用于xls文件，即Excel97-2003的文件，如果是Excel2007，需要改成xlsx
                newwb.Worksheets(i).Name = VBA.Replace(tempwb.Name, ".xls", "")
                
                '关闭被合并工作簿
                tempwb.Close SaveChanges:=False
                
                i = i + 1
            Next vrtSelectedItem
        End If
    End With
    
    Set fd = Nothing
End Sub

第三步：系统会自动再新建一个excel文件，用来存放多个sheet工作表，同时会弹出对话框，选择要合并的独立excel文件，单击“打开”。

这样就把多个独立的excel文件合并到一个excel文件的sheet中了。