Unity Shader系列文章：Unity Shader目录-初级篇
Unity Shader系列文章：Unity Shader目录-中级篇
效果：
开启Cast Shadows正方体可以投射阴影，开启Receive Shadows平面可以接收阴影.jpg
开启光源的阴影效果.jpg
Mesh Renderer组件的Cast Shadows和Receive Shadows属性可以控制该物体是否投射和接收阴影.jpg
原理：
Unity中的阴影使用的是ShadowMap的技术。它会首先把摄像机的位置放在与光源重合的位置上，那么场景中该光源的阴影区域就是那些摄像机看不到的地方。
在前向渲染路径中，如果场景中最重要的平行光开启了阴影，Unity 就会为该光源计算它的阴影映射纹理(shadowmap)。这张阴影映射纹理本质上也是一张深度图， 它记录了从该光源的位置出发、能看到的场景中距离它最近的表面位置(深度信息)。
Unity使用一个额外的Pass来专门更新光源的阴影映射纹理，这个Pass就是LightMode标签被设置为ShadowCaster的Pass。这个Pass的渲染目标不是帧缓存，而是阴影映射纹理(或深度纹理)。Unity首先把摄像机放置到光源的位置上，然后调用该Pass, 通过对顶点变换后得到光源空间下的位置，并据此来输出深度信息到阴影映射纹理中。因此，当开启了光源的阴影效果后，底层渲染引擎首先会在当前渲染物体的Unity Shader中找到LightMode为ShadowCaster的Pass，如果没有，它就会在Fallback指定的Unity Shader中继续寻找，如果仍然没有找到，该物体就无法向其他物体投射阴影(但它仍然可以接收来自其他物体的阴影)。当找到了一个LightMode 为ShadowCaster的Pass后，Unity 会使用该Pass来更新光源的阴影映射纹理。
在传统的阴影映射纹理的实现中，我们会在正常渲染的Pass 中把顶点位置变换到光源空间下，以得到它在光源空间中的三维位置信息。然后，我们使用xy分量对阴影映射纹理进行采样，得到阴影映射纹理中该位置的深度信息。如果该深度值小于该顶点的深度值(通常由z分量得到)，那么说明该点位于阴影中。但Unity使用了不同于这种传统的阴影采样技术，即屏幕空间的阴影映射技术(Screenspace Shadow Map)。屏幕空间的阴影映射原本是延迟渲染中产生阴影的方法，所以并不是所有的平台Unity 都会使用这种技术。这是因为，屏幕空间的阴影映射需要显卡支持MRT,而有些移动平台不支持这种特性。
当使用了屏幕空间的阴影映射技术时，Unity 首先会通过调用LightMode为ShadowCaster的Pass来得到可投射阴影的光源的阴影映射纹理以及摄像机的深度纹理。然后，根据光源的阴影映射纹理和摄像机的深度纹理来得到屏幕空间的阴影图。如果摄像机的深度图中记录的表面深度大于转换到阴影映射纹理中的深度值，就说明该表面虽然是可见的，但是却处于该光源的阴影中。
通过这样的方式，阴影图就包含了屏幕空间中所有有阴影的区域。如果我们想要一A 个物体接收来自其他物体的阴影，只需要在Shader中对阴影图进行采样。由于阴影图是屏幕空间下的，因此，我们首先需要把表面坐标从模型空间变换到屏幕空间中，然后使用这个坐标对阴影图进行采样即可。
总结一下，一个物体接收来自其他物体的阴影，以及它向其他物体投射阴影是两个过程：
- 如果想要一个物体接收来自其他物体的阴影，就必须在Shader中对阴影映射纹理(包括屏幕空间的阴影图)进行采样，把采样结果和最后的光照结果相乘来产生阴影效果。
- 如果想要一个物体向其他物体投射阴影, 就必须把该物体加入到光源的阴影映射纹理的计算中，从而让其他物体在对阴影映射纹理采样时可以得到该物体的相关信息。在Unity中，这个过程是通过为该物体执行LightMode为ShadowCaster的Pass来实现的。如果使用了屏幕空间的投影映射技术，Unity 还会使用这个Pass产生一张摄像机的深度纹理。
Shader中计算阴影步骤：
1、在顶点着色器输出体中，声明一个宏SHADOW_COORDS用于对阴影纹理采样的坐标；
2、在顶点着色器中，使用宏TRANSFER_SHADOW计算声明的阴影纹理坐标；
3、在片元着色器中，使用宏SHADOW_ATTENUATION计算阴影值。
SHADOW_COORDS、TRANSFER_SHADOW和SHADOW_ATTENUATION是计算阴影时的"三剑客"。实际上通常情况下计算阴影时，直接使用宏UNITY_LIGHT_ATTENUATION进行计算阴影值，同时此宏还会同时计算光照衰减。
Shader代码：
// 前向渲染，阴影
Shader "Unlit/ForwardRenderingShadow"
{
Properties
{
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1) // 漫反射颜色
_Specular ("Specular", Color) = (1, 1, 1, 1) // 高光反射颜色
_Gloss ("Gloss", Range(8, 256)) = 20 // 高光区域大小
}
SubShader
{
Tags { "RenderType" = "Opaque" }
// Pass1
// Shadow Pass 将该物体加入到光源的阴影映射纹理的计算中。通常此Pass不需要写，
// 由于这个Pass功能通常是在多个Shader中通用，因此一般直接通过FallBack一个Unity内置Specular来完成，
// 即: FallBack "Specular"，因为Specular会继续FallBack回调内置的VertexLit
pass
{
Name "ShadowCaster"
Tags { "LightMode" = "ShadowCaster" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_shadowcaster
#include "UnityCG.cginc"
struct v2f
{
V2F_SHADOW_CASTER;
};
v2f vert(appdata_base v)
{
v2f o;
TRANSFER_SHADOW_CASTER_NORMALOFFSET(o);
return o;
}
float4 frag(v2f i): SV_Target
{
SHADOW_CASTER_FRAGMENT(i);
}
ENDCG
}
// Pass2
// Base Pass计算平行光、环境光
pass
{
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
// 应用传递给顶点着色器的数据
struct a2v
{
float4 vertex: POSITION; // 语义：顶点坐标
float3 normal: NORMAL; // 语义：法线
};
// 顶点着色器传递给片元着色器的数据
struct v2f
{
float4 pos: SV_POSITION; // 语义：裁剪空间的顶点坐标
float3 worldNormal: TEXCOORD0;
float3 worldPos: TEXCOORD1;
SHADOW_COORDS(2) // 内置宏：声明一个用于对阴影纹理采样的坐标 (这个宏参数需要是下一个可用的插值寄存器的索引值，这里是2)
};
v2f vert(a2v v)
{
v2f o;
// 将顶点坐标从模型空间变换到裁剪空间
// 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.pos = UnityObjectToClipPos(v.vertex);
// 将法线从模型空间变换到世界空间
// 等价于o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
// 将顶点坐标从模型空间变换到世界空间
o.worldPos = mul(unity_ObjectToWorld, v.vertex);
// 内置宏：用于计算声明的阴影纹理坐标
TRANSFER_SHADOW(o);
return o;
}
// 片元着色器
fixed4 frag(v2f i): SV_TARGET
{
fixed3 worldNormal = normalize(i.worldNormal);
// 世界空间光向量
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
// 计算漫反射颜色
// 兰伯特公式：Id = Ip * Kd * N * L
// IP：入射光的光颜色；
// Kd：漫反射颜色；
// N：单位法向量，L：单位光向量
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));
// 世界空间观察向量
// 等价于fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos)
fixed3 viewDir = UnityWorldSpaceViewDir(i.worldPos.xyz);
// 半角向量: h = (V + L)/(| V + L |)
fixed3 halfDir = normalize(worldLightDir + viewDir);
// 计算高光反射
// Blinn-Phong高光反射公式：
// Cspecular=(Clight * Mspecular) * max(0,n.h)^mgloss
// Clight：入射光颜色；
// Mspecular：高光反射颜色；
// n: 单位法向量；
// h: 半角向量：光线和视线夹角一半方向上的单位向量 h = (V + L)/(| V + L |)
// mgloss：反射系数；
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
// 环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
// 平行光无光照衰减
fixed atten = 1.0;
// 计算阴影值
fixed shadow = SHADOW_ATTENUATION(i);
return fixed4(ambient + (diffuse + specular) * atten * shadow, 1.0);
}
ENDCG
}
// Pass3
// Add Pass 计算额外的逐像素光源(点光源、聚光灯等), 每个pass对应1个光源
pass
{
Tags { "LightMode" = "ForwardAdd" }
// 开启混合
Blend One One
CGPROGRAM
// 若使用fullshadows，则Unity会为这些额外逐像素光源计算阴影
// #pragma multi_compile_fwdadd_fullshadows
#pragma multi_compile_fwdadd
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
// 应用传递给顶点着色器的数据
struct a2v
{
float4 vertex: POSITION; // 语义：顶点坐标
float3 normal: NORMAL; // 语义：法线
};
// 顶点着色器传递给片元着色器的数据
struct v2f
{
float4 pos: SV_POSITION; // 语义：裁剪空间的顶点坐标
float3 worldNormal: TEXCOORD0;
float3 worldPos: TEXCOORD1;
};
// 顶点着色器
v2f vert(a2v v)
{
v2f o;
// 将顶点坐标从模型空间变换到裁剪空间
// 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.pos = UnityObjectToClipPos(v.vertex);
// 将法线从模型空间变换到世界空间
// 等价于o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
// 将顶点坐标从模型空间变换到世界空间
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
return o;
}
// 片元着色器
fixed4 frag(v2f i): SV_TARGET
{
fixed3 worldNormal = normalize(i.worldNormal);
// 世界空间光向量
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
// 计算漫反射颜色
// 兰伯特公式：Id = Ip * Kd * N * L
// IP：入射光的光颜色；
// Kd：漫反射颜色；
// N：单位法向量，L：单位光向量
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));
// 世界空间观察向量
// 等价于fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos)
fixed3 viewDir = UnityWorldSpaceViewDir(i.worldPos);
// 半角向量: h = (V + L)/(| V + L |)
fixed3 halfDir = normalize(worldLightDir + viewDir);
// 计算高光反射
// Blinn-Phong高光反射公式：
// Cspecular=(Clight * Mspecular) * max(0,n.h)^mgloss
// Clight：入射光颜色；
// Mspecular：高光反射颜色；
// n: 单位法向量；
// h: 半角向量：光线和视线夹角一半方向上的单位向量 h = (V + L)/(| V + L |)
// mgloss：反射系数；
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
// 计算光照衰减 (一般都直接用Unity内置函数计算: UNITY_LIGHT_ATTENUATION，会在后续文章中用到)
#ifdef USING_DIRECTIONAL_LIGHT // 平行光
// 平行光，光照衰减不变
fixed atten = 1.0;
#else
#if defined(POINT) // 点光源
// 把顶点坐标从世界空间变换到点光源坐标空间中
// unity_WorldToLight由引擎代码计算后传递到shader中，这里包含了对点光源范围的计算，具体可参考Unity引擎源码。
// 经过unity_WorldToLight变换后，在点光源中心处lightCoord为(0, 0, 0)，在点光源的范围边缘处lightCoord模为1。
float3 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1)).xyz;
// 使用点到光源中心距离的平方dot(lightCoord, lightCoord)构成二维采样坐标(r,r)，对衰减纹理_LightTexture0采样。
// UNITY_ATTEN_CHANNEL是衰减值所在的纹理通道，可以在内置的HLSLSupport.cginc文件中查看。
// 一般PC和主机平台的话UNITY_ATTEN_CHANNEL是r通道，移动平台的话是a通道。
fixed atten = tex2D(_LightTexture0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL;
#elif defined(SPOT) // 聚光灯
// 把顶点坐标从世界空间变换到点光源坐标空间中
// unity_WorldToLight由引擎代码计算后传递到shader中，这里面包含了对聚光灯的范围、角度的计算，具体可参考Unity引擎源码。
// 经过unity_WorldToLight变换后，在聚光灯光源中心处或聚光灯范围外的lightCoord为(0, 0, 0)，在聚光灯光源的范围边缘处lightCoord模为1。
float4 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1));
// 与点光源不同，由于聚光灯有更多的角度等要求，因此为了得到衰减值，除了需要对衰减纹理采样外，还需要对聚光灯的范围、张角和方向进行判断。
// 此时衰减纹理存储到了_LightTextureB0中，这张纹理和点光源中的_LightTexture0是等价的。
// 聚光灯的_LightTexture0存储的不再是基于距离的衰减纹理，而是一张基于张角范围的衰减纹理。在张角中心，即坐标0.5处衰减值为1，而在两侧是接近0的。
fixed atten = (lightCoord.z > 0) * tex2D(_LightTexture0, lightCoord.xy / lightCoord.w + 0.5).w * tex2D(_LightTextureB0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL;
#else
fixed atten = 1.0;
#endif
#endif
// 尽管纹理采样方法可以减少计算衰减时的复杂度，有时也可以使用数学公式计算光照衰减：
// float distance = length(_WorldSpaceLightPos0.xyz - i.worldPos.xyz);
// float atten = 1.0 / distance;
return fixed4((diffuse + specular) * atten, 1.0);
}
ENDCG
}
}
}