Unity shader学习---渲染纹理

一.概念

渲染目标纹理：GPU允许把整个三围场景渲染到一个中间缓冲中
多重渲染目标：GPU允许把场景同时渲染到多个渲染目标纹理中，不再需要为每个渲染目标纹理单独渲染完整的场景。

Unity为渲染目标纹理定义了一个专门的纹理类型----渲染纹理。
Unity使用渲染纹理的方式通常有两种：
A.在 Project 下右键创建RenderTexture;
2.在屏幕后处理时使用GrabPass命令或者OnRenderImage函数来获取当前屏幕图像。（OnRenderImage 函数是我们实现屏幕特效的核心方法之一）

二. 镜子Mirror

原理：使用一个渲染纹理作为输入属性，并把该渲染纹理在水平方向上进行翻转后直接显示到物体上。
完整shader代码：

Shader "Unity Shaders Book/Chapter 10/Mirror" {
    Properties {
        _MainTex ("Main Tex", 2D) = "white" {}
    }
    SubShader {
        Tags { "RenderType"="Opaque" "Queue"="Geometry"}
        
        Pass {
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            
            sampler2D _MainTex;
            
            struct a2v {
                float4 vertex : POSITION;
                float3 texcoord : TEXCOORD0;
            };
            
            struct v2f {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
            };
            
            v2f vert(a2v v) {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                
                o.uv = v.texcoord;
                // Mirror needs to filp x
                o.uv.x = 1 - o.uv.x;
                
                return o;
            }
            
            fixed4 frag(v2f i) : SV_Target {
                return tex2D(_MainTex, i.uv);
            }
            
            ENDCG
        }
    } 
    FallBack Off
}

实现的效果如下：

镜子效果

三. Glass

原理： GrabPass 是一种特殊的 Pass ，它可以抓取屏幕中要将对象绘制到纹理中的内容，而且抓取到的纹理可以在其他 Pass 中使用。
它有两种使用方法：
A.GrabPass {}，这种方法抓取时，后续的 Pass 可以通过 _GrabTexture 来访问屏幕图像，要注意的是，对于为一个使用它的物体，Unity 都会为其单独进行一次抓取操作。这样每个物体都可以得到不同的屏幕图像，这取决于这个物体的渲染顺序及当前屏幕的缓冲颜色。这样会造成不小的性能消耗。
B.GrabPass { “TextureName” } ，指定一张纹理，抓取的屏幕图像会存储到这张纹理中，而后续的 Pass 可以访问这张纹理来访问屏幕图像。这种方法抓取屏幕时，Unity 只会在每一帧为第一个使用这张纹理的物体执行一次抓取屏幕的操作。所以，如果场景中有复数个物体使用了这张纹理，那么它们得到的屏幕图像其实是一样的，且为第一个使用这张纹理的物体得到的屏幕图像。

注意：GrabPass 通常用于渲染透明物体，需要将物体的渲染队列设置为透明队列，即"Queue"="Transparent"。
方法：先使用一张法线纹理修改模型的法线信息，然后使用反射通过一个cubemap模拟玻璃的反射，而在反射折射时，则使用了GrabPass获取玻璃后面的屏幕图像，并使用切线空间下的法线对屏幕纹理坐标偏移后，再对屏幕图像进行采样来模拟近似的折射效果。
完整shader代码如下：

Shader "Unity Shaders Book/Chapter 10/Glass Refraction" {
    Properties {
        _MainTex ("Main Tex", 2D) = "white" {}
        _BumpMap ("Normal Map", 2D) = "bump" {}
        _Cubemap ("Environment Cubemap", Cube) = "_Skybox" {}
        _Distortion ("Distortion", Range(0, 100)) = 10
        _RefractAmount ("Refract Amount", Range(0.0, 1.0)) = 1.0
    }
    SubShader {
        // We must be transparent, so other objects are drawn before this one.
        Tags { "Queue"="Transparent" "RenderType"="Opaque" }
        
        // This pass grabs the screen behind the object into a texture.
        // We can access the result in the next pass as _RefractionTex
        GrabPass { "_RefractionTex" }
        
        Pass {      
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"
            
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _BumpMap;
            float4 _BumpMap_ST;
            samplerCUBE _Cubemap;
            float _Distortion;
            fixed _RefractAmount;
            sampler2D _RefractionTex;
            float4 _RefractionTex_TexelSize;
            
            struct a2v {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 tangent : TANGENT; 
                float2 texcoord: TEXCOORD0;
            };
            
            struct v2f {
                float4 pos : SV_POSITION;
                float4 scrPos : TEXCOORD0;
                float4 uv : TEXCOORD1;
                float4 TtoW0 : TEXCOORD2;  
                float4 TtoW1 : TEXCOORD3;  
                float4 TtoW2 : TEXCOORD4; 
            };
            
            v2f vert (a2v v) {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                
                o.scrPos = ComputeGrabScreenPos(o.pos);
                
                o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);
                
                float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;  
                fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);  
                fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);  
                fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w; 
                
                o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);  
                o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);  
                o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);  
                
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target {       
                float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
                fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(worldPos));
                
                // Get the normal in tangent space
                fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));   
                
                // Compute the offset in tangent space
                float2 offset = bump.xy * _Distortion * _RefractionTex_TexelSize.xy;
                i.scrPos.xy = offset * i.scrPos.z + i.scrPos.xy;
                fixed3 refrCol = tex2D(_RefractionTex, i.scrPos.xy/i.scrPos.w).rgb;
                
                // Convert the normal to world space
                bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
                fixed3 reflDir = reflect(-worldViewDir, bump);
                fixed4 texColor = tex2D(_MainTex, i.uv.xy);
                fixed3 reflCol = texCUBE(_Cubemap, reflDir).rgb * texColor.rgb;
                
                fixed3 finalColor = reflCol * (1 - _RefractAmount) + refrCol * _RefractAmount;
                
                return fixed4(finalColor, 1);
            }
            
            ENDCG
        }
    }
    
    FallBack "Diffuse"
}

要点：_Distortion 表示光线折射时的扭曲程度，_RefractAmount 为 0 时，只含反射效果，_RefractAmount 为 1 时，只含折射效果；
指定一个纹理 _RefractionTex；
_RefractionTex_TexelSize 表示纹理的纹素大小，对屏幕图像采样时使用；
利用 Unity 内置函数 ComputeGrabScreenPos 得到对应抓取屏幕图像的采样坐标；

效果如下图：

_RefractAmount 为 0.75 的效果

四. 渲染纹理vs.GrabPass

GrabPass优点：实现简单
GrabPass缺点：效率低，且获取到的图像分辨率和显示屏幕一样，意味着高分辨率可能有严重的带宽影响。需要cpu直接读取后备缓冲（back buffer）的数据，破坏了CPU和GPU间的并行性，会更耗时。
渲染纹理优点：效率高，可以自定义渲染纹理大小，且可以控制相机的渲染层来减少二次渲染时的场景大小，且可通过相机自行开启关闭。
渲染纹理缺点：操作繁琐。