qml基础学习 模型视图(一)
文章目录
-
- 一、理解qml模型和视图
- 二、效果展示
- 三、源码分析
-
- 1、GridView增删
- 2、列表
- 3、卡牌效果
- 四、相关文章
一、理解qml模型和视图
qt的发展是迅速的，虽然在每一个release版本中或多或少都有bug，但是作为一个庞大的gui库，no，应该说是一个开发框架开说，qt已经算是做的相当好。qml部分是qt4.7的时候推出的，当时qml只是为了移动端而设计的开发语言，随着it行业的发展，桌面端也产生了一定的需求，这就使得qml也必须支持桌面端的开发。使用qml可以做出绚丽的界面，并把逻辑和界面展示分开，qml和C++就好比html和JavaScript。
qt中有大量的model/view类，视图类：QTableView、QListView和QTreeView，模型类：QAbstractTableModel、QAbstractListModel和QAbstractProxyModel，这三个模型类都是继承自QAbstractItemModel。对于qml语言来说，也有model和view，他们分别就是GridView、ListView和PathView，其中GridView和ListView在qt中都有对于的实现类，PathView是最难理解的view，也是最灵活的view，他可以做出各种各样比较绚丽的效果。
二、效果展示
这一节我们主要是说明qml中的视图类，如下效果图展示的那样，图1是用GridView实现，图2是用ListView实现，view的item项都是用代理进行绘制；图3是用PathView实现的一个效果图，类似于一个卡牌弹出弹入效果。
顺道提一嘴，qml文件都是可以使用qmlscene.exe来预览
三、源码分析
每一个示例中都有大量的注释，具体细节可以参看注释
1、GridView增删
如图1所示，这是一个GridView的简单示例，示例完成单击Add Item按钮实现新增项，点击项实现删除等功能。
import QtQuick 2.0
Rectangle {
width: 480;
height: 300;
//背景色渐变
gradient: Gradient {
GradientStop { position: 0.0; color: "#dbddde"; }
GradientStop { position: 1.0; color: "#5fc9f8"; }
}
//list模型默认9项
ListModel {
id: theModel
ListElement { number: 0; }
ListElement { number: 1; }
ListElement { number: 2; }
ListElement { number: 3; }
ListElement { number: 4; }
ListElement { number: 5; }
ListElement { number: 6; }
ListElement { number: 7; }
ListElement { number: 8; }
ListElement { number: 9; }
}
//Add Item按钮
Rectangle {
anchors.left: parent.left;
anchors.right: parent.right;
anchors.bottom: parent.bottom;
anchors.margins: 20;
height: 40;
color: "#53d769";
border.color: Qt.lighter(color, 1.1);
Text {
anchors.centerIn: parent;
text: "Add item!";
}
//点击时新增项 实现model的动态新增
MouseArea {
anchors.fill: parent;
onClicked: {
theModel.append({"number": ++parent.count});
}
}
property int count: 9;//
}
GridView {
anchors.fill: parent;
anchors.margins: 20;
anchors.bottomMargin: 80;
clip: true;
model: theModel;//绑定数据源
cellWidth: 45;//设置项大小
cellHeight: 45;
delegate: numberDelegate;//设置绘制代理
}
//自定义绘制代理
Component {
id: numberDelegate;
Rectangle {
id: wrapper;
width: 40;
height: 40;
//首先是一个渐变的矩形框
gradient: Gradient {
GradientStop { position: 0.0; color: "#f8306a"; }
GradientStop { position: 1.0; color: "#fb5b40"; }
}
//文本值是number的数值
Text {
anchors.centerIn: parent;
font.pixelSize: 10;
text: number;
}
//鼠标点击代理时，移除点击项
MouseArea {
anchors.fill: parent;
onClicked: {
if (!wrapper.GridView.delayRemove)//是否延迟移除
{
theModel.remove(index);
}
}
}
//GridView移除项 顺序动画
GridView.onRemove: SequentialAnimation {
//属性变化
PropertyAction {
target: wrapper;
property: "GridView.delayRemove";
value: true;
}
//数字动画
NumberAnimation {
target: wrapper;//目标对象
property: "scale";//执行动画的属性
to: 0;//结束值
duration: 250;//动画持续时长
easing.type: Easing.InOutQuad;//动画执行曲线
}
PropertyAction {
target: wrapper;
property: "GridView.delayRemove";
value: false;
}
}
//GridView新增项 顺序动画
GridView.onAdd: SequentialAnimation {
NumberAnimation {
target: wrapper;
property: "scale";
from: 0;//开始值
to: 1;
duration: 250;
easing.type: Easing.InOutQuad;
}
}
}
}
}
2、列表
如图2所示，是一个使用ListView实现的列表控件，点击列表控件中的项，可以实现最大化来展示列表的详细信息
import QtQuick 2.0
Item {
width: 300;
height: 480;
//渐变别景色
Rectangle {
anchors.fill: parent;
gradient: Gradient {
GradientStop { position: 0.0; color: "#4a4a4a"; }
GradientStop { position: 1.0; color: "#2b2b2b"; }
}
}
//主界面列表视图
ListView {
id: listView;
anchors.fill: parent;
delegate: detailsDelegate;//设置绘制代理
model: planets;//绑定数据源
}
ListModel {
id: planets;
ListElement {
name: "Mercury";
imageSource: "images/mercury.jpeg";
facts: "Mercury is the smallest planet in the Solar System. It is the closest planet to the sun. It makes one trip around the Sun once every 87.969 days." ;
}
ListElement {
name: "Venus";
imageSource: "images/venus.jpeg";
facts: "Venus is the second planet from the Sun. It is a terrestrial planet because it has a solid, rocky surface. The other terrestrial planets are Mercury, Earth and Mars. Astronomers have known Venus for thousands of years.";
}
ListElement {
name: "Earth";
imageSource: "images/earth.jpeg";
facts: "The Earth is the third planet from the Sun. It is one of the four terrestrial planets in our Solar System. This means most of its mass is solid. The other three are Mercury, Venus and Mars. The Earth is also called the Blue Planet, 'Planet Earth', and 'Terra'.";
}
ListElement {
name: "Mars";
imageSource: "images/mars.jpeg";
facts: "Mars is the fourth planet from the Sun in the Solar System. Mars is dry, rocky and cold. It is home to the largest volcano in the Solar System. Mars is named after the mythological Roman god of war because it is a red planet, which signifies the colour of blood.";
}
}
Component {
id: detailsDelegate;
Item {
id: wrapper;
width: listView.width;
height: 30;
//列表项文本
Rectangle {
anchors.left: parent.left;
anchors.right: parent.right;
anchors.top: parent.top;
height: 30;
color: "#333";
border.color: Qt.lighter(color, 1.2);
Text {
anchors.left: parent.left;
anchors.verticalCenter: parent.verticalCenter;
anchors.leftMargin: 4;
font.pixelSize: parent.height-4;
color: '#fff';
text: name;//ListElement中的name
}
}
//列表项图标
Rectangle {
id: image;
width: 26;
height: 26;
anchors.right: parent.right;
anchors.top: parent.top;
anchors.rightMargin: 2;
anchors.topMargin: 2;
color: "yellow";
Image {
anchors.fill: parent;
fillMode: Image.PreserveAspectFit;
source: imageSource;//ListElement中的imageSource
}
}
//鼠标点击列表项 进行状态前切换，
MouseArea {
anchors.fill: parent;
onClicked: parent.state = "expanded";//切换到展开状态
}
//详情页展开时，文本详细信息
Item {
id: factsView;
anchors.top: image.bottom;//位于放大后的图标底部
anchors.left: parent.left;
anchors.right: parent.right;
anchors.bottom: parent.bottom;
opacity: 0;//默认透明不显示 当点击代理项时该属性会慢慢变得可见
Rectangle {
anchors.fill: parent;
gradient: Gradient {
GradientStop { position: 0.0; color: "#fed958"; }
GradientStop { position: 1.0; color: "#fecc2f"; }
}
border.color: '#000000';
border.width: 2;
Text {
anchors.fill: parent;
anchors.margins: 5;
clip: true;//可剪切
wrapMode: Text.WordWrap;//文本支持换行
color: '#1f1f21';
font.pixelSize: 12;
text: facts;
}
}
}
//项最大化时 右上角关闭按钮
Rectangle {
id: closeButton;
anchors.right: parent.right;
anchors.top: parent.top;
anchors.rightMargin: 2;
anchors.topMargin: 2;
width: 26;
height: 26;
color: "#157efb";
border.color: Qt.lighter(color, 1.1);
opacity: 0;
MouseArea {
anchors.fill: parent;
onClicked: wrapper.state = "";//点击恢复到默认状态
}
}
//自定义代理状态
states: [
State {
name: "expanded";
//在点击列表项后 各项属相变化
//代理高度铺满视图高度
PropertyChanges { target: wrapper; height: listView.height; }
//列表项的图标放大
PropertyChanges {
target: image;
width: listView.width;
height: listView.width;
anchors.rightMargin: 0;
anchors.topMargin: 30//距离顶部30像素
}
//文本详细信息可见
PropertyChanges { target: factsView; opacity: 1; }
//关闭按钮可见
PropertyChanges { target: closeButton; opacity: 1; }
//列表项视图
PropertyChanges {
target: wrapper.ListView.view;
contentY: wrapper.y;
interactive: false
}
}
]
//项变化时 过程
transitions: [
Transition {
NumberAnimation {
duration: 200;
properties: "height,width,anchors.rightMargin,anchors.topMargin,opacity,contentY";
}
}
]
}
}
}
3、卡牌效果
示例代码可以直接放在qml文件中使用qmlscene.exe来预览
import QtQuick 2.6
Rectangle {
id: root;
width: 480;
height: 300;
PathView
{
anchors.fill: parent;
delegate: flipCardDelegate;
model: 100;
path: Path{
startX: root.width / 2;
startY: 0
PathAttribute { name: "itemAngle"; value: -45.0; }
PathAttribute { name: "itemScale"; value: 0.5; }
PathAttribute { name: "itemZ"; value: 0; }//属性值附加到代理上面
PathLine { x: root.width/2; y: root.height*0.4; }//路径元素定义
PathPercent { value: 0.48; }//控制两个元素之间的路径所占百分比
PathLine { x: root.width/2; y: root.height*0.5; }
PathAttribute { name: "itemAngle"; value: 0.0; }
PathAttribute { name: "itemScale"; value: 1.0; }
PathAttribute { name: "itemZ"; value: 100 }
PathLine { x: root.width/2; y: root.height*0.6; }
PathPercent { value: 0.52; }
PathLine { x: root.width/2; y: root.height; }
PathAttribute { name: "itemAngle"; value: 45.0; }
PathAttribute { name: "itemScale"; value: 0.5; }
PathAttribute { name: "itemZ"; value: 0; }
}
pathItemCount: 17;//可见元素数目
preferredHighlightBegin: 0.5;
preferredHighlightEnd: 0.5;
}
Component{
id: flipCardDelegate;
Rectangle{
id: wrapper;
width: 64;
height: 64;
antialiasing: true;//反锯齿
//代理背景色渐变
gradient: Gradient{
GradientStop { position: 0.0; color: "#2ed5fa"; }
GradientStop { position: 1.0; color: "#2467ec"; }
}
visible: PathView.onPath;//在PathView上的项可见，不在视图上的项不可见
scale: PathView.itemScale;//缩放
z: PathView.itemZ;//z值 数值大的在上面
property variant rotX: PathView.itemAngle;//属性别名 主要是因为要在底下这个旋转过程中使用
//动画过程旋转
transform: Rotation {
axis { x: 1; y: 1; z: 1; }//绕x轴旋转
angle: wrapper.rotX;//旋转角度
origin { x: 32; y: 32; }//旋转基点
}
Text{
anchors.horizontalCenter: parent.horizontalCenter;
anchors.verticalCenter: parent.verticalCenter;
text: index;
}
}
}
}
四、相关文章
qml基础学习(一) 基础概念
如果您觉得文章不错，不妨给个 打赏，写作不易，感谢各位的支持。您的支持是我最大的动力，谢谢！！！
 |
 |
很重要–转载声明
-
本站文章无特别说明，皆为原创，版权所有，转载时请用链接的方式，给出原文出处。同时写上原作者：朝十晚八 or Twowords
-
如要转载，请原文转载，如在转载时修改本文，请事先告知，谢绝在转载时通过修改本文达到有利于转载者的目的。