Unity Shader 前向渲染光照衰减和阴影

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

前向渲染，光照衰减和阴影.jpg

// 前向渲染，光照衰减和阴影
Shader "Unlit/ForwardRenderingAttenAndShadow"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1) // 漫反射颜色
        _Specular ("Specular", Color) = (1, 1, 1, 1) // 高光反射颜色
        _Gloss ("Gloss", Range(8, 256)) = 20 // 高光区域大小
    }

    SubShader
    {
        Tags { "RenderType" = "Opaque" }

        // Base Pass计算平行光、环境光
        pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma multi_compile_fwdbase

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 语义：顶点坐标
                float3 normal: NORMAL; // 语义：法线
            };

            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION; // 语义：裁剪空间的顶点坐标
                float3 worldNormal: TEXCOORD0;
                float3 worldPos: TEXCOORD1;
                SHADOW_COORDS(2) // 内置宏：声明一个用于对阴影纹理采样的坐标 (这个宏参数需要是下一个可用的插值寄存器的索引值，这里是2)
            };

            v2f vert(a2v v)
            {
                v2f o;
                // 将顶点坐标从模型空间变换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);

                // 将法线从模型空间变换到世界空间
                // 等价于o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                // 将顶点坐标从模型空间变换到世界空间
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);

                // 内置宏：用于计算声明的阴影纹理坐标
                TRANSFER_SHADOW(o);

                return o;
            }

            // 片元着色器
            fixed4 frag(v2f i): SV_TARGET
            {
                fixed3 worldNormal = normalize(i.worldNormal);

                // 世界空间光向量
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                // 计算漫反射颜色
                // 兰伯特公式：Id = Ip * Kd * N * L
                // IP：入射光的光颜色；
                // Kd：漫反射颜色；
                // N：单位法向量，L：单位光向量
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));

                // 世界空间观察向量
                // 等价于fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos)
                fixed3 viewDir = UnityWorldSpaceViewDir(i.worldPos.xyz);
                // 半角向量: h = (V + L)/(| V + L |)
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                // 计算高光反射
                // Blinn-Phong高光反射公式：
                // Cspecular=(Clight * Mspecular) * max(0,n.h)^mgloss
                // Clight：入射光颜色；
                // Mspecular：高光反射颜色；
                // n: 单位法向量；
                // h: 半角向量：光线和视线夹角一半方向上的单位向量 h = (V + L)/(| V + L |)
                // mgloss：反射系数；
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);

                // 环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                // 计算阴影值和光照衰减
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

                return fixed4(ambient + (diffuse + specular) * atten, 1.0);
            }
            
            ENDCG
            
        }

        // Add Pass 计算额外的逐像素光源(点光源、聚光灯等), 每个pass对应1个光源
        pass
        {
            Tags { "LightMode" = "ForwardAdd" }

            // 开启混合
            Blend One One
            
            CGPROGRAM
            
            // 若使用下面定义，则Unity会为这些额外逐像素光源计算阴影
            // #pragma multi_compile_fwdadd_fullshadows
            #pragma multi_compile_fwdadd

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 语义：顶点坐标
                float3 normal: NORMAL; // 语义：法线
            };

            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION; // 语义：裁剪空间的顶点坐标
                float3 worldNormal: TEXCOORD0;
                float3 worldPos: TEXCOORD1;
                SHADOW_COORDS(2) // 内置宏：声明一个用于对阴影纹理采样的坐标 (这个宏参数需要是下一个可用的插值寄存器的索引值，这里是2)
            };

            // 顶点着色器
            v2f vert(a2v v)
            {
                v2f o;

                // 将顶点坐标从模型空间变换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);

                // 将法线从模型空间变换到世界空间
                // 等价于o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                // 将顶点坐标从模型空间变换到世界空间
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

                // 内置宏：用于计算声明的阴影纹理坐标
                TRANSFER_SHADOW(o);

                return o;
            }

            // 片元着色器
            fixed4 frag(v2f i): SV_TARGET
            {
                fixed3 worldNormal = normalize(i.worldNormal);

                // 世界空间光向量
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                // 计算漫反射颜色
                // 兰伯特公式：Id = Ip * Kd * N * L
                // IP：入射光的光颜色；
                // Kd：漫反射颜色；
                // N：单位法向量，L：单位光向量
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));

                // 世界空间观察向量
                // 等价于fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos)
                fixed3 viewDir = UnityWorldSpaceViewDir(i.worldPos);
                // 半角向量: h = (V + L)/(| V + L |)
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                // 计算高光反射
                // Blinn-Phong高光反射公式：
                // Cspecular=(Clight * Mspecular) * max(0,n.h)^mgloss
                // Clight：入射光颜色；
                // Mspecular：高光反射颜色；
                // n: 单位法向量；
                // h: 半角向量：光线和视线夹角一半方向上的单位向量 h = (V + L)/(| V + L |)
                // mgloss：反射系数；
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);

                // 计算阴影值和光照衰减
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

                return fixed4((diffuse + specular) * atten, 1.0);
            }
            
            ENDCG
            
        }
    }

    FallBack "Specular"
}