Caché Objects | 第二章 | 使用和重写属性方法

属性方法，这些方法是 Caché 在使用 OREF 处理对象属性时使用的实际方法。

一、属性方法简介

属性具有许多自动关联的方法。这些方法不是通过标准继承继承的。相反，它们使用特殊的属性行为机制为每个属性生成一系列方法。
每个属性从两个位置继承一组方法：

• %Property类，它提供某些内置行为，例如 Get()、Set() 和验证代码。
• 属性使用的数据类型类（如果适用）。其中许多方法都是方法生成器。

属性行为类是系统类。不能指定或修改属性行为。

例如，如果我们定义一个类人具有三个属性：

Class MyApp.Person Extends %Persistent
{
Property Name As %String;
Property Age As %Integer;
Property DOB As %Date;
}

编译的Person类具有为其每个属性自动生成的一组方法。这些方法继承自系统Property类以及与属性关联的数据类型类。这些生成方法的名称是属性名称，该名称与继承类中的方法名称连接在一起。例如，与 DOB 属性关联的一些方法包括：

Set x = person.DOBIsValid(person.DOB)
 Write person.DOBLogicalToDisplay(person.DOB)

其中 IsValid() 是属性类的方法，LogicalToDisplay() 是 %Date 数据类型类的方法。

二、文本属性的属性访问器

用于引用对象属性的 Caché 点语法是一组用于检索和设置值的访问器方法的接口。对于每个非计算属性，每当代码引用 oref. Prop（其中 oref 是一个对象，Prop 是一个属性），它的执行方式就像调用了系统提供的 PropGet() 或 PropSet() 方法一样。例如：

Set person.DOB = x
// 就像调用了以下方法一样：
Do person.DOBSet(x)

Write person.Name
// 就像调用了以下方法一样：
Write person.NameGet()

• 在大多数情况下，您看不到实际的 PropGet() 和 PropSet() 方法;对简单属性的访问直接在 Caché 虚拟机中实现，以实现最佳性能。
• 但是，您可以为特定属性提供 PropGet() 和 PropSet() 方法，只要该属性不是对象类型或多维属性即可。如果定义了这些方法，系统将在运行时自动调用它们。在自定义方法中，可以执行应用程序所需的任何特殊处理。
• 请注意，Studio 中新建属性向导的最后一个屏幕提供了用于创建自定义 Get() 方法和/或Set() 方法的选项。如果使用这些选项，Studio 会使用合适的签名来定义存根方法。
  

Property Age As %Integer;

Method AgeGet() As %Integer [ ServerOnly = 1 ]
{
	Quit ""
}

Method AgeSet(Arg As %Integer) As %Status [ ServerOnly = 1 ]
{
	Quit $$$OK
}

三、对象值属性的属性访问器

对于每个引用属性，都有 SetObject()（使用 OID 值）和 SetObjectId()（使用 ID 值）方法。例如：

Do car.OwnerSetObjectId(PersonId)

还有 GetObject（） 和 GetObjectId（） 方法，它们分别获取与引用属性关联的 OID 或 ID。综上所述，各种方法是：

• GetObject（） — 获取与属性关联的 OID。对于名为 prop 的属性，方法名称为 propGetObject（）。
• GetObjectId（） — 获取与属性关联的 ID。对于名为 prop 的属性，方法名称为 propGetObjectId（）。
• SetObject（） — 设置与属性关联的 OID。对于名为 prop 的属性，方法名称为 propSetObject（）。
• SetObjectId（） — 设置与属性关联的 ID。对于名为 prop 的属性，方法名称为 propSetObjectId（）。

四、重写属性 getter 方法

若要重写属性的 getter 方法，请修改包含该属性的类并添加方法，如下所示：

• 它必须具有名称 PropertyName Get，其中 PropertyName 是相应属性的名称。
• 它不需要任何参数。
• 其返回类型必须与属性的类型相同。
• 它必须返回属性的值。
• 若要引用此属性的值，此方法必须使用变量 i%PropertyName。此名称区分大小写。

提示：

• 在给定属性的 getter 方法中，不要使用 ..PropertyName 语法来引用该属性的值。如果尝试这样做，则结果是 错误，该错误由一系列递归引用引起。但是，您可以使用 ..PropertyName 来引用其他属性，因为这样做不会导致任何递归。
• 变量 i%PropertyName 是一个实例变量。
• 不支持重写对象类型化属性或多维属性的访问器方法。
• 此外，由于方法名称的最大长度为 220 个字符，因此无法为长度为 218、219 或 220 个字符的属性创建访问器方法。

下面显示了一个示例，即名为 HasValue 的属性的 setter 方法，该属性的类型为 %Boolean：

Method HasValueGet() As %Boolean 
{
  If ((i%NodeType="element")||(i%NodeType="")) Quit 0
  Quit 1
}

五、重写 Property Setter 方法

若要重写属性的 setter 方法，请修改包含该属性的类并添加方法，如下所示：

• 它必须具有名称 PropertyName Set，其中 PropertyName 是相应属性的名称。
• 它采用一个参数，其中包含属性的值。
  具体而言，这是在设置属性时在 SET 命令中指定的值。
• 它必须返回 %Status 值。
  若要设置此属性的值，此方法必须设置变量 i%PropertyName。此名称区分大小写。

注意：

• 在给定属性的此 setter 方法中，请勿使用 ..PropertyName 语法来引用该属性的值。如果尝试这样做，则结果是 错误，该错误由一系列递归引用引起。但是，您可以使用 ..PropertyName 来引用其他属性，因为这样做不会导致任何递归。
• 变量 i%PropertyName 是一个实例变量
• 请注意，不支持重写对象类型化属性或多维属性的访问器方法。
• 此外，由于方法名称的最大长度为 220 个字符，因此无法为长度为 218、219 或 220 个字符的属性创建访问器方法。

Method DefaultXmlnsSet(value As %String) As %Status
{
    set i%DefaultXmlns = value
    If ..Namespaces'="" Set ..Namespaces.DefaultXmlns=value
    quit $$$OK
}

请注意，此示例使用 .. 引用同一对象的 Namespaces 属性。这种用法不是错误，因为它不会导致任何递归。

六、使用自定义访问器方法定义对象值属性

如前所述，不支持重写对象类型化属性的访问器方法。如果需要定义包含对象值的属性，并且需要定义自定义访问器方法，请使用 %CacheString类型定义该属性。这不是一个对象类，而是一个泛型类，允许重写此属性的访问器方法。使用该属性时，请将其设置为等于所需类的实例。

Class PropMethods.Demo Extends %Persistent
{

/// Timestamp for viewing Zip
Property LastTimeZipViewed As %TimeStamp;

/// Timestamp for changing Zip
Property LastTimeZipChanged As %TimeStamp;

/// When setting this property, set it equal to instance of Sample.USZipCode.
/// The type is %CacheString rather than Sample.USZipCode, so that it's possible 
/// to override ZipGet() and ZipSet().
Property Zip As %CacheString;

Method ZipGet() As %CacheString [ ServerOnly = 1 ]
{
    // get id, swizzle referenced object
    set id = i%Zip
    if (id '= "") {
        set zip = ##class(Sample.USZipCode).%OpenId(id)
        set ..LastTimeZipViewed = $zdt($zts)
    }
    else {
        set zip = ""
    }
    return zip
}

Method ZipSet(zip As %CacheString) As %Status [ ServerOnly = 1 ]
{
    // set i% for new zip
    if ($isobject(zip) && zip.%IsA("Sample.USZipCode")) {
        set id = zip.%Id()
        set i%Zip = id
        set ..LastTimeZipChanged = $zdt($zts)
    }
    else {
        set i%Zip = ""
    }
    quit $$$OK
}

}