Oracle之PL/SQL学习笔记之异常

Oracle之PL/SQL学习笔记之异常

1. 认识异常

1.1 什么是异常

   PL/SQL运行过程中可能会出现错误，这些错误有的来自程序本身，也有的来自开发人员自定义的数据，而所有的这些错误我们称之为异常(编译时的错误不能称为异常)

1.2 处理异常的语法

  PL/SQL块有三部分  声明部分，执行部分，例外部分(异常部分)异常通常都是发生在执行体部分，处理部分在PL/SQL块的最下方。其语法格式如下:

exception 
    when exception1 [or exception2] then --异常列表
      statement1...                      --异常处理
    when exception3 [or exception4] then --异常列表
      statement2...
    [when others then]
       statement3 ... --异常处理结束

1.3 异常的分类

• 预定义异常

• 非预定义异常

• 用户自定义异常

其中，预定义和非预定义异常都与Oracle中的错误有关，当出现错误时会自动触发，而自定义异常与Oracle的错误没有关系，

它是人为的为某种特殊情况定义的异常，也不会自动触发，需要显示的操作来触发。

2. 预定义异常

  Oracle为每个错误提供一个错误号，而捕获异常则需要异常有名称。Oracle提供了一些已经定义好名称的常用异常，这就是预定义异常。

  下面是一些常用的预定义异常：

异常	错误	何时出现
ACCESS_INTO_NULL	ORA-06530	试图访问未初始化对象的时候出现
CASE_NOT_FOUND	ORA-06592	如果定义了一个没有ELSE子句的CASE语句，而且没有CASE语句满足运行时条件时出现该异常
COLLECTION_IS_NULL	ORA-06531	当程序去访问一个没有进行初始化的NESTED TABLE或者是VARRAY的时候，会出现该异常
CURSOR_ALREADY_OPEN	ORA-06511	游标已经被OPEN，如果再次尝试打开该游标的时候，会出现该异常
DUP_VAL_ON_INDEX	ORA-00001	如果插入一列被唯一索引约束的重复值的时候，就会引发该异常（该值被INDEX认定为冲突的）
INVALID_CURSOR	ORA-01001	不允许的游标操作，比如关闭一个已经被关闭的游标，就会引发
INVALID_NUMBER	ORA-01722	给数字值赋非数字值的时候，该异常就会发生，这个异常也会发生在批读取时候LIMIT子句返回非正数的时候
LOGIN_DENIED	ORA-01017	程序中，使用错误的用户名和密码登录的时候，就会抛出这个异常
NO_DATA_FOUND	ORA_06548	在使用SELECT INTO 结构，并且语句返回NULL值的时候；访问嵌套表中已经删除的表或者是访问INDEX BY表（联合数组）中的未初始化元素就会出现该异常
NOT_LOGGED_ON	ORA-01012	当程序发出数据库调用，但是没有连接的时候（通常，在实际与会话断开连接之后）
PROGRAM_ERROR	ORA-06501	当Oracle还未正式捕获的错误发生时常会发生，这是因为数据库大量的Object功能而发生
ROWTYPE_MISMATCH	ORA-06504	如果游标结构不适合PL/SQL游标变量或者是实际的游标参数不同于游标形参的时候发生该异常
SELF_IS_NULL	ORA-30625	调用一个对象类型非静态成员方法（其中没有初始化对象类型实例）的时候发生该异常
STORAGE_ERROR	ORA-06500	当内存不够分配SGA的足够配额或者是被破坏的时候，引发该异常
SUBSCRIPT_BEYOND_COUNT	ORA-06533	当分配给NESTED TABLE或者VARRAY的空间小于使用的下标的时候，发生该异常（类似于java的ArrayIndexOutOfBoundsException）
SUBSCRIPT_OUTSIDE_LIMIT	ORA-06532	使用非法的索引值来访问NESTED TABLE或者VARRAY的时候引发
SYS_INVALID_ROWID	ORA-01410	将无效的字符串转化为ROWID的时候引发
TIMEOUT_ON_RESOURCE	ORA-00051	当数据库不能安全锁定资源的时候引发
TOO_MANY_ROWS	ORA-01422	常见错误，在使用SELECT INTO 并且查询返回多个行时引发。如果子查询返回多行，而比较运算符为相等的时候也会引发该异常。
USERENV_COMMITSCN_ERROR	ORA-01725	只可使用函数USERENV('COMMITSCN')作为INSERT语句的VALUES子句中的顶级表达式或者作为UPDATE语句的SET子句中的右操作数
VALUE_ERROR	ORA-06502	将一个变量赋给另一个不能容纳该变量的变量时引发
ZERO_DIVIDE	ORA-01476	将某个数字除以0的时候，会发生该异常

 案例1： NO_DATA_FOUND

declare 
 c_empno number:=1000;--一个不存在的员工编号
 v_name emp.ename%type;--员工姓名
begin
  select ename into v_name from emp where empno=c_empno;
  exception 
    when no_data_found then 
      dbms_output.put_line('不存在雇员编号为：'||c_empno||'的雇员');
end;

案例2： TOO_MANY_ROWS

declare 
 c_deptno number:=10;--一个不存在的员工编号
 v_name emp.ename%type;--员工姓名
begin
  select ename into v_name from emp where deptno=c_deptno;
  exception 
    when too_many_rows then 
      dbms_output.put_line('期望返回一条记录，实际返回多条记录');
end;

3. 非预定义异常

  Oracle中的异常更多都是非预定义异常。也就是说，它们只有错误编号和相关的错误描述，而没有名称的异常是不能被捕获的。

为了解决这个问题，Oracle允许开发人员为这样的异常添加一个名称，使得它们能够被异常处理模块捕获到。

 为一个非预定义异常定义名称需要如下两步：

1. 声明一个异常名称

2. 把这个名称与异常编号相互关联

Oracle处理预定义与非预定义异常并没有区别。

案例:

declare 
   my_2291_exp exception;
   pragma exception_init(my_2291_exp,-02291);
begin
   insert into emp values(1001,'King','no job',7788,sysdate,1000,0,50);
   exception
     when my_2291_exp then 
       dbms_output.put_line('违反了完整性约束，没有部门编号为50的部门');
end;

 4. 用户自定义异常

 如果开发当中遇到与实际业务相关的错误，例如产品数量不允许为负数，生成日期必须在保质期之前等，

这些和业务相关的问题并不能算系统错误，也不能使用预定义和非预定义异常来捕获它们。如果想要用一场的方式处理这些问题，

那么这样的异常需要开发人员自己编写，而且在调用的时候也需要显示的触发。

案例:  emp表的入职时间不能大于当前日期

declare 
   my_hiredate_exp exception;
   v_hiredate emp.hiredate%type;
begin
  select hiredate into v_hiredate from emp where rownum<=1;
  if v_hiredate> sysdate then 
    raise my_hiredate_exp;--显示触发自定义异常
  end if;
  exception 
    when my_hiredate_exp then 
      dbms_output.put_line('入职时间不能大于当前日期');
end;

  自定义异常编程需要如下几步:

1.  自定义一个exception类型变量

2. 用户根据业务需要来主动触发异常  raise exception变量名;

3. exception 异常捕获部分

直接在程序中跑出自定义异常

create or replace procedure change_sal(vempno number) 
is 
begin
update emp set sal=sal*1.1 where empno=vempno;
raise_application_error(-20001,'更新雇员工资失败,员工编号为:'||vempno);
end;

注意: raise_application_error(error_number_in number,error_msg_in)中 error_number_in 取值为-20000 - -20999

   error_msg_in 只能小于2k超出2k将截取2k