MiniJava的语法

MiniJava语言参考。引用自 Modern Compiler Implementation in Java, Second Edition，Appendix A, Page 484-486。

下面是MiniJava语法的EBNF。粗体蓝色的表示terminals，斜体的是non-terminals。星号（*）表示出现0或多次。

引用

Program → MainClass ClassDecl*
MainClass → class id { public static void main(String[ ] id) { Statement* } }
ClassDecl → class id { VarDecl* MethodDecl* }
_________ → class id extends id { VarDecl* MethodDecl* }
VarDecl → Type id ;
MethodDecl → public Type id ( FormalList ) { VarDecl* Statement* return Exp; }
FormalList → Type id FormalRest*
_________ →
FormalRest → , Type id
Type → int[]
____ → boolean
____ → int
____ → id
Statement → { Statement* }
_________ → if ( Exp ) Statement else Statement
_________ → while ( Exp ) Statement
_________ → System.out.println(Exp);
_________ → id = Exp;
_________ → id[Exp] = Exp;
Exp → Exp op Exp
___ → Exp [Exp]
___ → Exp .length
___ → Exp . id (ExpList)
___ → INTEGER_LITERAL
___ → true
___ → false
___ → id
___ → this
___ → new int[Exp]
___ → new id( )
___ → !Exp
___ → (Exp)
ExpList → Exp ExpRest*
_______ →
ExpRest → , Exp

（注释： op表示二元运算符，可以是： && < + - *的任意一个；
.length只能作用于 int[]类型的变量上。）

本来是想找找比较简单的实例，看看别人是如何实现类（class）的作用域的。然而这MiniJava真作 弊，居然强制要求变量声明在方法声明之前，于是我遇到的问题在一定程度上给避开了。Hmm……我再想想看怎么办好……