wwl33695

批处理 Set 命令详解

set,E文翻译过来就是“设置”的意思，相当于数学里的“令”。

如：set X=5，就是令X=5的意思。

set的通常用法示例：

1、set 显示环境变量：

如：在命令行下输入：

set 会显示当前所有的系统环境变量

set c 会显示所有的以c开头或C开头的变量（也即不区分大小写）；

set com 会显示所有的以com开头或COM开头的变量（不区分大小写）；

2、set 设置环境变量，用法示例：set 表达式，

如：set str=ok

就是将变量str的值设置成字符串“OK”

注意：set str=ok>

这个在批处理运行过程中会出错，系统会提示：“命令语法不正确。”

原因是，因为变量str 中的值“ok>”的字符">"为一特殊字符，会被系统当成定向符处理，所以会运行出错，那如果确实要设置这样的变量str，值为 "ok>"怎么办呢？解决办法有二：将特殊字符转义，转义方法在该特殊字符前加一个“^”，如：set str=ok^> (这种方法比较少用，因为没有多少应用价值)

常见的解决办法，在set后面将整个表达式用引号括起来，如：set "str=>"

3、带参数 /a的set 数值计算

set的/A参数就是让SET可以支持数学符号进行加减等一些数学运算! 支持的数学运算包含（优先权递减）:

() - 分组

! ~ - - 一元运算符

* / % - 算数运算符

+ - - 算数运算符

<< >> - 逻辑移位

& - 按位“与”

^ - 按位“异”

| - 按位“或”

= *= /= %= += -= - 赋值

&= ^= |= <<= >>=

, - 表达式分隔符

用法示例：set /a num=2*10,这样变量num的值将变为：20

复制代码代码如下:

set /a var=2 - 1 结果是多少呢?如果你看不到结果就echo %var%.....

set /a var=2 * 2 乘法运算

set /a var=2 / 2 除法运算

set /a var=(1+1) + (1+1) 结果等于4 看得懂吧!

set /a a=1+1,b=2+1,c=3+1 运行后会显示一个4,但我们用

echo %a% %b% %c%后看结果,会发现其他数学运算也有效果!,这就是"斗"号的

作用!

有时候我们需要直接在原变量进行加减操作就可以用这种语法

set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1

都是一样的结果。

对于"逻辑或取余操作符",我们需要把他们用双引号引起来,看例子

复制代码代码如下:

set /a var= 1 "&" 1 这样结果就显示出来了,其他逻辑或取余操作符用法

set /a var= 1 "+" 1 异运算

set /a var= 1 "%" 1 取模运算

set /a var= 2 "<<" 2 次方运算

set /a var= 4 ">>" 2 这个不太记得数学里的叫法....

这些符号也可以用&= ^= |= <<= >>= 这样的简单用法如

set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号

4、带参数 /p 的set 等待用户输入

windows 2000 和windows 是没有choice这个命令，choice的等待用户输入功能就要通过set /p来实现

演示如下：

复制代码代码如下:

@echo off

set /p str=请输入你想输入的字符：

echo 你输入的字符串为：%str%

pause>nul

set /p的特殊应用（set /p=<nul相当于输出字符并不带回车，利用这个性质，可以做出比较漂亮的动画），用法示例：

复制代码代码如下:

@echo off

for /l %%i in (1 1 70) do (

set /p=O<nul

for /l %%a in (1 1 50) do ver>nul

)

pause>nul

注：代码中用到了一句for /l %%a in (1 1 50) do ver>nul，它的目的是利用for循环运行某一命令来达到延时的目的。

5、利用set截取字符保存下面的代码为test.bat运行查看即可。

复制代码代码如下:

@echo off&color 1f&rem num=15 nums=30

mode con: cols=80 lines=35

set "var=1234567890"

set "num= "

set "nums= "

rem 第一屏舍弃

cls&echo 第一屏舍弃

echo\&echo %num% var=%var%&echo\

for /l %%i in (1 1 3) do call :dan %%i

echo\

for /l %%i in (0 1 1) do call :yi %%i

echo\

for /l %%i in (0 1 2) do call :_yi %%i

echo ~ 波浪号后面的数字：为正数表示舍弃变量的前位;

echo , 逗号后面的数字为正数表示取变量的舍弃以后的前几位;

echo , 逗号后面为负数表示舍弃变量的后几位

echo\&echo\&pause&color 1e

rem 第二屏取

cls&echo 第二屏取

echo\&echo %num% var=%var%&echo\

for /l %%i in (-1 -1 -3) do call :dan %%i

echo\

for /l %%i in (-4 -1 -6) do call :er %%i

echo\

call :_er -8

echo ~ 波浪号后面直接跟负数表示取变量的后几位

echo , 逗号后面的数字为正数表示取变量的舍弃以后的前几位;

echo , 逗号后面为负数表示舍弃变量的后几位

echo\&echo\&pause&color 1f

rem 第三屏替换删除

cls&echo 第三屏替换删除

set "var=abc:\123\ef:g\123\456"hij"789"klm\"

echo\&echo %num%var=%var%

echo\

call :san

echo = 号左边为要替换掉的字符, 右边为需替换来的字符

echo = 号左边要替换掉的字符前面加个*号,代表第一次出现的字符及其前面的所有字符

echo\

echo ========= 演示完毕 ========= 按任意键退出 ==========

pause>nul

exit

:dan

set shu=%1

if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍弃&set ji=前

if "%shu:~0,1%"=="-" set shu=%shu:~1%

set str1=%%var:~%1%%%num%

set str2=%aa%var的%ji%%shu%位%nums%

call set str3=%%var:~%1%%%num%

call echo %%str1:~0,15%% %%str2:~0,30%% %%str3:~0,15%%

goto :eof

:yi

set shu=%1

if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍弃&set ji=前

for /l %%i in (1 1 3) do (

set str1=%%var:~%1,%%i%%%num%

set str2=%aa%var的%ji%%shu%位之后取%%i位%nums%

call set str3=%%var:~%1,%%i%%%num%

call echo %%str1:~0,15%% %%str2:~0,26%% %%str3:~0,15%%

if %%i==3 echo\

)

goto :eof

:_yi

for /l %%i in (-1 -1 -3) do (

set str1=%%var:~%1,%%i%%%num%

set str2=舍弃var的前%1位和%%i位%nums%

call set str3=%%var:~%1,%%i%%%num%

call echo %%str1:~0,15%% %%str2:~0,28%% %%str3:~0,15%%

if %%i==-3 echo\

)

goto :eof

:er

set sss=%1

set sss=%sss:~1%

for /l %%i in (1 1 3) do (

set str1=%%var:~%1,%%i%%%num%

set str2=从var的倒数%sss%位开始取%%i位%nums%

call set str3=%%var:~%1,%%i%%%num%

call echo %%str1:~0,15%% %%str2:~0,24%% %%str3:~0,15%%

if %%i==3 echo\

)

goto :eof

:_er

set sss=%1

set sss=%sss:~1%

for /l %%i in (-1 -1 -3) do (

set str1=%%var:~%1,%%i%%%num%

set str2=从var的倒数%sss%位开始并舍弃最后%%i位%nums%

call set str3=%%var:~%1,%%i%%%num%

call echo %%str1:~0,15%% %%str2:~0,20%% %%str3:~0,15%%

if %%i==-3 echo\

)

goto :eof

:san

set str1=%%var:"=%%%num%

set str2=删除var中的所有^"号%num%

set str3=%var:"=%%nums%

call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%

set str1=%%var:\=%%%num%

set str2=删除var中的所有\号%num%

set str3=%var:\=%%nums%

call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%

set str1=%%var::=%%%num%

set str2=删除var中的所有:号%num%

set str3=%var::=%%nums%

call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%

echo\

set str1=%%var:"=好%%%num%

set str2=替换var中的所有^"号为好字%num%

set str3=%var:"=好%%nums%

call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%

set str1=%%var:\=好%%%num%

set str2=替换var中的所有\号为好字%num%

set str3=%var:\=好%%nums%

call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%

set str1=%%var::=好%%%num%

set str2=替换var中的所有:号为好字%num%

set str3=%var::=好%%nums%

call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%

echo\

set str1=%%var:*"=%%%num%

set str3=%var:*"=%%nums%

echo 删除var中的第一次出现的^"号及其前面的所有字符