Genero Excel Upload

  这个是利用客户端调用COM将本地Excel数据上传到系统的实例，结合上一篇文章的叙述，这个就不多讲了，这种方法麻烦一点，但是灵活性还是不错的。直接看代码吧，都给注释清除了。

MAIN
  DEFINE path STRING   #定义文件路径


  LET path = "C:/Users/EmpID/Desktop/test"
  
  CALL excel_upload(path) #上传指定路劲的EXCEL数据到数组
END MAIN


FUNCTION excel_upload(p_path)
  DEFINE p_path STRING
  DEFINE i,j,r_app,r_wb,r_row INT


  DEFINE datain DYNAMIC ARRAY OF RECORD  #定义动态数组保存EXCEL数据
    col1 CHAR(10),
    col2 CHAR(20),
    col3 CHAR(30)
  END RECORD
  
  CALL ui.interface.frontCall('WinCOM','CreateInstance',['Excel.Application'],[r_app])  #创建excel实例 
  CALL CheckError(r_app, __LINE__)
  CALL ui.interface.frontCall('WinCOM','CallMethod',[r_app,'WorkBooks.Open',p_path],[r_wb]) #打开workbook
  CALL CheckError(r_wb, __LINE__)
  CALL ui.interface.frontCall('WinCOM','GetProperty',[r_app,'ActiveSheet.UsedRange.Rows.Count'],[r_row])  #得到excel数据条目
  CALL CheckError(r_row, __LINE__)


  IF r_row > 1 THEN   #第一行栏位名不要，第二行开始
    FOR i = 2 TO r_row
      CALL ui.interface.frontCall('WinCOM','GetProperty',[r_app,'ActiveSheet.Cells('||i||',1).Value'],[datain[i-1].col1]) #从sheet写第一列数据到数组
      CALL ui.interface.frontCall('WinCOM','GetProperty',[r_app,'ActiveSheet.Cells('||i||',2).Value'],[datain[i-1].col2]) #从sheet写第二列数据到数组
      CALL ui.interface.frontCall('WinCOM','GetProperty',[r_app,'ActiveSheet.Cells('||i||',3).Value'],[datain[i-1].col3]) #从sheet写第三列数据到数组
    END FOR
  END IF


  #记得关闭打开的实例，释放内存
  CALL ui.interface.frontCall('WinCOM','CallMethod',[r_app,'Quit'],[r_wb])  
  CALL ui.interface.frontCall('WinCOM','ReleaseInstance',[r_app],[r_wb])  


  LET j = 1
  FOR j = 1 TO (r_row - 1)    #显示一下
    DISPLAY datain[j].*     
  END FOR
END FUNCTION


FUNCTION checkerror(result, lin)  #抓取错误信息
  DEFINE result,lin INT
  DEFINE mess STRING


  IF result = -1 THEN
    DISPLAY "COM ERROR AT LINE: ", lin
    CALL ui.interface.frontCall('WinCOM',"GetError",[],[mess])
    DISPLAY mess
    EXIT PROGRAM -1
  END IF
END FUNCTION


运行结果如下：