VB.NET并行与分布式编程(6)-线程与内核同步[8]

2）我们可以用更好的方式使用.NET的委托和线程池

A）委托

 WaitCallback 委托,表示线程池线程要执行的回调方法。

 

WaitCallback 表示要在 ThreadPool 线程上执行的回调方法。 创建委托，方法是将回调方法传递给 WaitCallback 构造函数。 您的方法必须具有此处所显示的签名。

通过将 WaitCallback 委托传递给 ThreadPool.QueueUserWorkItem 来将任务排入队列以便执行。 您的回调方法将在某个线程池线程可用时执行。

如果要将信息传递给回调方法，请创建包含所需信息的对象，并在将任务排入队列以便执行时将它传递给 QueueUserWorkItem。 每次执行您的回调方法时，state 参数都包含此对象。

B)线程池

ThreadPool 类提供一个线程池，该线程池可用于执行任务、发送工作项、处理异步 I/O、代表其他线程等待以及处理计时器。

 许多应用程序创建的线程都要在休眠状态中消耗大量时间，以等待事件发生。 其他线程可能进入休眠状态，只被定期唤醒以轮询更改或更新状态信息。 线程池通过为应用程序提供一个由系统管理的辅助线程池，使您可以更为有效地使用线程。

 

 

线程池根据需要提供新的工作线程或 I/O 完成线程，直到其达到每个类别的最小值。当达到最小值时，线程池可以在该类别中创建更多线程或等待某些任务完成。从 .NET Framework 4 开始，线程池会创建和销毁工作线程以优化吞吐量，吞吐量定义为单位时间内完成的任务数。线程过少时可能无法更好地利用可用资源，但线程过多时又可能会加剧资源的争用情况。
注意当需求比较少时，线程池线程的实际数量可以低于这些最小值。
可使用GetMinThreads方法获得这些最小值。
警告您可以使用SetMinThreads方法增加线程的最小数量。但是，在不必要的情况下增加这些值，可能会导致性能问题。如果同时启动的任务过多，则所有任务的处理速度看起来都可能很慢。大多数情况下，线程池使用自己的分配线程的算法将能够更好地工作。
如果线程池重用某个线程，它不会清除线程本地存储区或由ThreadStaticAttribute特性标记的字段中的数据。因此，由一种方法放入线程本地存储区中的数据可以向由同一个线程池线程执行的其他任何方法公开。用于访问由ThreadStaticAttribute特性标记的字段的方法可能会遇到不同的数据，具体取决于执行此方法的线程池线程。

 

可以将与等待操作不相关的工作项排列到线程池。 若要请求由线程池中的一个线程来处理工作项，请调用 QueueUserWorkItem 方法。 此方法将对将被从线程池中选定的线程调用的方法或委托的引用用作参数。 一个工作项排入队列后就无法再取消它。

计时器队列中的计时器以及已注册的等待操作也使用线程池。 它们的回调函数也会排列到线程池。

每个进程都有一个线程池。 从 .NET Framework 4 版开始，进程的线程池的默认大小由虚拟地址空间的大小等多个因素决定。 进程可以调用 GetMaxThreads 方法以确定线程的数量。 使用 SetMaxThreads 方法可以更改线程池中的线程数。 每个线程使用默认的堆栈大小并按照默认的优先级运行。

c)代码如下：

 

 

 

Imports System
Imports System.Threading
Imports System.Diagnostics
Imports System.Diagnostics.ThreadState


Module Module1

    <MTAThread()> _
    Sub Main()





        '完成任务的线程号
        Dim finishedid As Integer
        '定义WaitCallback 委托
        Dim mywaitcallback(4) As WaitCallback

        '定义线程传参的对象数组
        Dim calculateifno(4) As CalculateIfno




        '分别给每个线程创建AutoResetEvent对象
        Dim threadevent(4) As AutoResetEvent

        Console.WriteLine(Now.ToLongTimeString & "线程对象创建完毕,开始执行线程")

        '设置线程执行前相关参数，并执行线程，将参数对象传入线程
        For i = 0 To threadevent.GetUpperBound(0)
            '设置参数对象
            threadevent(i) = New AutoResetEvent(False)
            calculateifno(i) = New CalculateIfno
            calculateifno(i).threadevent = threadevent(i)
            calculateifno(i).result = 0
            calculateifno(i).threadname = i & "号线程"
            '在线程池中加入线程，将参数对象传入线程执行
            mywaitcallback(i) = New WaitCallback(AddressOf mythreadrun)
            ThreadPool.QueueUserWorkItem(mywaitcallback(i), calculateifno(i))
        Next

        '等待其中一个线程完成累加,然后将其它未完成任务的线程终止 
        finishedid = WaitHandle.WaitAny(threadevent)
        '线程执行完毕   
        Console.WriteLine(Now.ToLongTimeString & "    " & finishedid & "号线程完成任务，计算完毕!" & Environment.NewLine & "计算结果为：" & calculateifno(finishedid).result)

    End Sub
    Public Class CalculateIfno
        Private _threadevent As AutoResetEvent
        Private _result As Long
        Private _threadname As String
        Public Property threadevent As AutoResetEvent
            Get
                Return _threadevent
            End Get
            Set(ByVal value As AutoResetEvent)
                _threadevent = value
            End Set
        End Property
        Public Property result As Long
            Get
                Return _result
            End Get
            Set(ByVal value As Long)
                _result = value
            End Set
        End Property
        Public Property threadname As String
            Get
                Return _threadname
            End Get
            Set(ByVal value As String)
                _threadname = value
            End Set
        End Property
    End Class
    Public Sub mythreadrun(ByVal calculateifno As Object)
        Dim mynum As Integer
        Dim jg As Long = 0
        Try
            For mynum = 1 To 1000
                jg += mynum
                Thread.Sleep(5)
            Next
            Console.WriteLine(CType(calculateifno, CalculateIfno).threadname & "  " & Now.ToLongTimeString & "线程运行完毕!")
        Catch
            Console.WriteLine(CType(calculateifno, CalculateIfno).threadname & "  " & Now.ToLongTimeString & "线程异常终止!")
            '终止线程
            Thread.CurrentThread.Abort()
        Finally
            CType(calculateifno, CalculateIfno).threadevent.Set()
            CType(calculateifno, CalculateIfno).result = jg
        End Try
    End Sub
End Module

 D)分析

1.参数类中增加了threadname ，存放线程名称，因为

调用 QueueUserWorkItem 方法。 此方法将对将被从线程池中选定的线程调用的方法或委托的引用用作参数。 一个工作项排入队列后就无法再取消它。并且没有提供直接指定线程池被调用的线程的名字的办法

 

    Public Class CalculateIfno
        Private _threadevent As AutoResetEvent
        Private _result As Long
        Private _threadname As String
        Public Property threadevent As AutoResetEvent
            Get
                Return _threadevent
            End Get
            Set(ByVal value As AutoResetEvent)
                _threadevent = value
            End Set
        End Property
        Public Property result As Long
            Get
                Return _result
            End Get
            Set(ByVal value As Long)
                _result = value
            End Set
        End Property
        Public Property threadname As String
            Get
                Return _threadname
            End Get
            Set(ByVal value As String)
                _threadname = value
            End Set
        End Property
    End Class

2.QueueUserWorkItem方法

QueueUserWorkItem(WaitCallback)将方法排入队列以便执行。此方法在有线程池线程变得可用时执行。QueueUserWorkItem(WaitCallback, Object)将方法排入队列以便执行，并指定包含该方法所用数据的对象。此方法在有线程池线程变得可用时执行。

calculateifno(i)这个参数类对象被传入队列

        '设置线程执行前相关参数，并执行线程，将参数对象传入线程
        For i = 0 To threadevent.GetUpperBound(0)
            '设置参数对象
            threadevent(i) = New AutoResetEvent(False)
            calculateifno(i) = New CalculateIfno
            calculateifno(i).threadevent = threadevent(i)
            calculateifno(i).result = 0
            calculateifno(i).threadname = i & "号线程"
            '在线程池中加入线程，将参数对象传入线程执行
            mywaitcallback(i) = New WaitCallback(AddressOf mythreadrun)
            ThreadPool.QueueUserWorkItem(mywaitcallback(i), calculateifno(i))
        Next