D5的PV3D日记—DAY1

D5的PV3D日记—DAY1

让我的DAE动起来

渲染3D场景的必备工具：

摄象机、舞台、物体、渲染器。

所以，必须要通过PV3D来实现这些东西。在PV3D 2.0中，已经不需要在定义一个Sprite来做3D的“容器”，取而代之的是Viewport3D对象：

复制内容到剪贴板

代码:

import org.papervision3d.view.Viewport3D;
......
public var pViewPort:Viewport3D;

......

public function init():void
{
        pViewPort = new Viewport3D();
        addChild(pViewPort);
        ......
}

接下来，我们可以去实现摄象机、舞台和渲染器：

复制内容到剪贴板

代码:

import org.papervision3d.cameras.Camera3D;
import org.papervision3d.render.BasicRenderEngine;
import org.papervision3d.scenes.Scene3D;
......
public function init():void
{
        ......
        scene = new Scene3D();  //实现3D场景
        camera = new Camera3D(); // 实现3D摄象机
        camera.z = -5;       
                       
        renderer = new BasicRenderEngine(); //实现渲染引擎
        ......
}

这些内容都有了之后，就可以渲染场景啦，渲染的命令非常简单：

复制内容到剪贴板

代码:

renderer.renderScene(scene,camera,pViewPort);

整理一下~本段的代码如下：

复制内容到剪贴板

代码:

packge
{
        import org.papervision3d.cameras.Camera3D;
        import org.papervision3d.render.BasicRenderEngine;
        import org.papervision3d.scenes.Scene3D;
        import org.papervision3d.view.Viewport3D;

        public class Hello3D extends Sprite
        {
                public var scene:Scene3D;
                public var camera:Camera3D;
                public var pViewPort:Viewport3D;
                public var renderer:BasicRenderEngine;

                public function Hello3D()
                {
                        build3D();
                }
               
                private function build3D():void
                {
                        pViewPort = new Viewport3D();
                        addChild(pViewPort);
                       
                        scene = new Scene3D();
                        camera = new Camera3D();
                        camera.z = -5;       
                       
                        renderer = new BasicRenderEngine();
                }

        }

}

但是这样舞台上是什么都没有的，所以就算渲染也渲染不出什么东西来，嘿嘿。我们需要一个主角来进行渲染。开启SWFIT3D 5.0，随便拖一个正方体出来，然后保存为PV3D的格式，即可在保存目录中找到*.dae文件。把它拿到刚才编写的代码这边来用一下吧。

要导入并渲染dae文件，我们首先要声明DAE对象，并告诉他DAE文件的路径：

复制内容到剪贴板

代码:

import org.papervision3d.objects.parsers.DAE;
.......
        public var daeFile:DAE;
        daeFile = new DAE();
        daeFile.load("box.dae");
......

接下来，我们要把这个DAE对象加到场景中去

复制内容到剪贴板

代码:

scene.addChild(daeFile);

再测试影片，还是什么都没有吗？奇怪吧？我也在这里耽误了很久。原来PV3D是不会自动给DAE加材质的，所以，渲染出来的实际是一个透明的东西。我们下面来给这个CUBE加个简单的材质

复制内容到剪贴板

代码:

        import org.papervision3d.materials.ColorMaterial;
        import org.papervision3d.materials.utils.MaterialsList;
......
        public var cm:ColorMaterial;
......
        cm = new ColorMaterial(0xcccccc, .85, true);
                       
        daeFile = new DAE();
        daeFile.load("box.dae",new MaterialsList({all:cm}));

最终的代码看起来应该是这样的：

复制内容到剪贴板

代码:

package
{
        import flash.display.Sprite;
        import flash.events.Event;
        // 包含PV3D相关的东东
        import org.papervision3d.cameras.Camera3D;
        import org.papervision3d.materials.ColorMaterial;
        import org.papervision3d.materials.utils.MaterialsList;
        import org.papervision3d.objects.parsers.DAE;
        import org.papervision3d.render.BasicRenderEngine;
        import org.papervision3d.scenes.Scene3D;
        import org.papervision3d.view.Viewport3D;
       
        public class Hello3D extends Sprite
        {
                public var scene:Scene3D;                        // 场景
                public var camera:Camera3D;                        // 摄象机
                public var daeFile:DAE;                        // DAE
                public var pViewPort:Viewport3D;                // 视点
                public var renderer:BasicRenderEngine;                // 渲染引擎
                public var cm:ColorMaterial;                        // 材质
               
                public function Hello3D()
                {
                        build3D();
                        buildObject();
                }
               
                private function build3D():void
                {
                        pViewPort = new Viewport3D();        // 声明视点
                        addChild(pViewPort);
                       
                        scene = new Scene3D();                // 声明场景
                        camera = new Camera3D();                // 声明摄影机
                        camera.z = -5;                        // 焦距。。我的理解，自己调整来的，呵呵
                       
                        renderer = new BasicRenderEngine();        // 渲染引擎
                }
               
                private function buildObject():void
                {
                        cm = new ColorMaterial(0xcccccc, .85, true);                // 材质
                       
                        daeFile = new DAE();
                        daeFile.load("box.dae",new MaterialsList({all:cm}));        // 加载模型
                       
                        scene.addChild(daeFile);                                // 放进舞台
                       
                        this.addEventListener(Event.ENTER_FRAME,loop_rander);        // 触发动作
                }
               
                public function loop_rander(e:Event):void
                {
                        daeFile.rotationZ+=2;
                        daeFile.rotationY+=2;
                        daeFile.rotationX+=2;
                        renderer.renderScene(scene,camera,pViewPort);        // 将DAE旋转，并渲染
                }
        }
}

附件中有代码下载，包含DAE文件，不过不包含PV3D，开发环境为FLEX3

PV3D 2.0的打包可以到论坛3D专区下载。地址 www.d5power.com

转自： http://www.d5power.com/thread-43-1-1.html