从零开始的代码重定位--一个小实例

从零开始的代码重定位--一个小实例

                                    ---参考朱有鹏ARM裸机编程

1、任务：

在SRAM中将代码从0xd0020010重定位到0xd0024000

如果创造这个环境？

把程序下载到0xd0020010，但是在链接脚本把其我们想让其链接到0xd0024000

代码实际运行在0xd0020010,但是被链接到0xd0024000从而为重定位奠定了基础。

实际上隐含的意思就是我们这个代码将来必须放在0xd0024000

如果不是在这个位置的话，就会出错，除非是位置无关码。

当你明白之后，重定位的作用就是：位置无关码在执行之前（在代码第一句）

当执行到位置有关码执行之前，必须将整个代码搬移到0xd0024000去执行，这就是重定位。

      

2、链接脚本的准备：

SECTIONS
{
	. = 0xd0024000;
	
	.text : {
		start.o
		* (.text)
	}
    		
	.data : {
		* (.data)
	}
	
	bss_start = .; 
	.bss : {
		* (.bss)
	}
	
	bss_end  = .;	
}

(1) . 点号代表当前地址，0xd0024000，就是我们本来下载地址是0xd0020010

但是我们这里把链接地址弄成0xd0024000.

(2).text段，就是代码段：在这么多代码段之前，我们优先链接start.o

(3).data段，就是数据段，没有什么顺序，就直接按顺序链接就可以了。

(4)把当前地址的值赋值给bss_start这个变量，要注意这个当前地址是等于=  0xd0024000+代码段和数据段代码和的

我们在链接脚本中调用的东西可以在start.s文件中引用，这样方便我们写代码，UBOOT里面也运用了很多这样的方法。

3、Makefile中的运用：

arm-linux-ld -Tlink.lds -o led.elf $^

使用链接脚本，把编译好的.o文件按照你想要的方式链接起来编写。

4、重定位代码分析和应用：DSP芯片也有很多应用：

(1)

adr:指令加载的是当前运行的指令，因为我们还没有执行到位置有关码，所以加载的地址是0xd0020010这个层面的地址。

ldr：可能我们有很多人会说，这个地址也应该是我们的运行地址，但是为什么它是我们的链接地址呢？

因为他使用了我们指针最重要的东西--C语言的指针，他指向另一个内存空间，里面写的内容就是我们在链接脚本中写的

0xd0024000这个内容。

(2)用汇编语言写一个while循环，把r0地址：也就是0xd0020010中的内容写到r1地址中（0xd0024000）中

实现了重定位，也就是说，代码拷贝到编程者想要的地方，现在程序中就有两份一样的代码了。

整个重定向的内容是不需要进行BSS段的拷贝，因为BSS段的内容都是一些初始化为0的全局变量。

(3)根据链接脚本提供的BSS段开始的地址，我们可以为重定位的该拷贝多少，也就是说在BSS段开始就是

我们重定位最后的地址，所以有效的利用这个地址，不进行拷贝。

(4)为什么我们最后需要清理BSS段的内容呢？

首先程序里面有两份重定位的内容，我们只需要进行一份的重定位就可以了，

因为有一份是程序帮我们弄好的，就是0xd0020010.

另一份需要我们自己对其进行处理,就是0xd0024000.

我们仍然使用ldr指令，跳转到链接地址中去执行清BSS段的指令。

(5)清理完BSS段之后就可以跳转到长跳转指令去执行我们需要的命令了。

ldr pc, =led_blink

#define WTCON		0xE2700000

#define SVC_STACK	0xd0037d80

.global _start					// 把_start链接属性改为外部，这样其他文件就可以看见_start了
_start:
	// 第1步：关看门狗（向WTCON的bit5写入0即可）
	ldr r0, =WTCON
	ldr r1, =0x0
	str r1, [r0]
	
	// 第2步：设置SVC栈
	ldr sp, =SVC_STACK
	
	// 第3步：开/关icache
	mrc p15,0,r0,c1,c0,0;			// 读出cp15的c1到r0中
	//bic r0, r0, #(1<<12)			// bit12 置0  关icache
	orr r0, r0, #(1<<12)			// bit12 置1  开icache
	mcr p15,0,r0,c1,c0,0;
	
	// 第4步：重定位
	// adr指令用于加载_start当前运行地址
	adr r0, _start  		// adr加载时就叫短加载		
	// ldr指令用于加载_start的链接地址:0xd0024000
	ldr r1, =_start // ldr加载时如果目标寄存器是pc就叫长跳转，如果目标寄存器是r1等就叫长加载	
	// bss段的起始地址
	ldr r2, =bss_start	// 就是我们重定位代码的结束地址，重定位只需重定位代码段和数据段即可
	cmp r0, r1			// 比较_start的运行时地址和链接地址是否相等
	beq clean_bss		// 如果相等说明不需要重定位，所以跳过copy_loop，直接到clean_bss
						// 如果不相等说明需要重定位，那么直接执行下面的copy_loop进行重定位
						// 重定位完成后继续执行clean_bss。

// 用汇编来实现的一个while循环
copy_loop:
	ldr r3, [r0], #4    // 源
	str r3, [r1], #4	// 目的   这两句代码就完成了4个字节内容的拷贝
	cmp r1, r2			// r1和r2都是用ldr加载的，都是链接地址，所以r1不断+4总能等于r2
	bne copy_loop

	// 清bss段，其实就是在链接地址处把bss段全部清零
clean_bss:
	ldr r0, =bss_start					
	ldr r1, =bss_end
	cmp r0, r1				// 如果r0等于r1，说明bss段为空，直接下去
	beq run_on_dram			// 清除bss完之后的地址
	mov r2, #0
clear_loop:
	str r2, [r0], #4		// 先将r2中的值放入r0所指向的内存地址（r0中的值作为内存地址），
	cmp r0, r1				// 然后r0 = r0 + 4
	bne clear_loop

run_on_dram:	
	// 长跳转到led_blink开始第二阶段
	ldr pc, =led_blink				// ldr指令实现长跳转
	
	// 从这里之后就可以开始调用C程序了
	//bl led_blink					// bl指令实现短跳转
	
// 汇编最后的这个死循环不能丢
	b .