2017.07.14【NOIP提高组】模拟赛B组 最大公约数 题解

原题：

http://172.16.0.132/senior/#contest/show/2058/0

题目描述：

小菜的妹妹小诗就要读小学了！正所谓计算机要从娃娃抓起，小菜决定在幼儿园最后一段轻松的时间里教妹妹编程。
小菜刚教完gcd即最大公约数以后，一知半解的妹妹写了如下一段代码：
sum:=0;
for i:=1 to n-1 do
for j:=i+1 to n do sum:=sum+gcd(i,j)
显然这个程序的效率是很低的，小明打算写一个更强的程序，在求出sum的同时比妹妹跑的更快。

输入：

第一行一个整数t，即表示有t组数据
接下来t行，每行一个整数n

输出：

t行，每行一个整数，表示n所对应的sum值

样例输入：

2
10
100

样例输出：

67
13015

分析：

以下分析借鉴于HownoneHe博客
首先假设我们要求i=1~n的gcd(n,i)的和
我们可以先假设gcd(n,i)=k,则gcd(n/k,i/k)=1
即假设gcd(n/k,x)=1 则gcd(n,x∗k)=k
gcd(n,x∗k)=k k的取值是确定的，即n的所有因子，
所以满足gcd(n/k,x)=1中x的个数乘以k即为所有满足gcd(n,i)=k的和。
因此就转化为∑φ(n/k)∗k

题目与这一假设很接近，只是将求i=1_{n的gcd(n,i)变成求i=1}(j=1~n)的gcd(i,j)
首先 我们可以设一个求和数组sum，他满足
sum(n)=sum(n−1)+gcd(1,n)+gcd(2,n)+...+gcd(n−1,n)
设 数组f[i]表示j=1~i的gcd(j,i)值，则
f(n)=gcd(1,n)+gcd(2,n)+...+gcd(n−1,n)=∑i∗φ(n/i)I是n的因子
我们可以先线性求phi，并保存
在预处理出sum和f数组，那么对于每个n，ans=sum[n]

实现：

var
        t,i,j,n,tot:longint;
        pri,p:array[0..1000001]of longint;
        f,sum:array[0..1000001]of int64;
        bz:array[0..1000001]of boolean;
procedure phi(m:longint);
var
        x:longint;
begin
        p[1]:=1;
        for i:=2 to m do
        begin
                if not bz[i] then
                begin
                        p[i]:=i-1;
                        inc(pri[0]);
                        pri[pri[0]]:=i;
                end;
                for j:=1 to pri[0] do
                begin
                        x:=pri[j];
                        if x*i>m then break;
                        bz[i*x]:=true;
                        if i mod x=0 then
                        begin
                                p[i*x]:=p[i]*x;
                                break;
                        end
                        else p[i*x]:=p[i]*p[x];
                end;
        end;
end;
begin
        readln(t);
        phi(1000000);
        for i:=1 to 1000000 do
        begin
                j:=2*i;
                while j<=1000000 do
                begin
                        f[j]:=f[j]+i*p[j div i];
                        j:=j+i;
                end;
        end;
        sum[1]:=0;
        for i:=2 to 1000000 do sum[i]:=sum[i-1]+f[i];
        while t>0 do
        begin
                readln(n);
                writeln(sum[n]);
                dec(t);
        end;
end.