为 dnode 方法加 hook

Node.JS 模块驱动的方法学和标准化的 Stream 很适合创建 “微服务”(Microservices) 的系统架构 《What are some best architecture practices when designing a nodejs system?》。

James Halliday(Substack) 4年前有写了一系列的模块来帮助构建基于“微服务”(虽然那个时候这个名词还不流行)的系统架构。其中服务间调用的核心模块就是 dnode。dnode 已经很久没更新了，原因是代码和功能（很小的功能集）已经非常稳定。

Vanilar Version

一个简单的 dnode 例子如下：

dnode = require 'dnode'
net = require 'net'
grappling = require 'grappling-hook'

log = console.log.bind console
error = console.error.bind console

apis =
    transform: (s, cb) ->
        log '--original func calls'
        cb null, s.replace(/[aeiou]{2,}/, 'oo').toUpperCase()

server = net.createServer (c) ->
    d = dnode apis
    c.pipe(d).pipe c

server.listen 5004

d = dnode()
d.on 'remote', (remote) ->
    remote.transform 'beep', (err, s) ->
        if err?
            error 'Errors', err
        else
            log 'beep => ' + s
        d.end()

c = net.connect 5004
c.pipe(d).pipe c

这段代码很简短，执行结果是：

--original func calls
beep => BOOP

其功能为 Server 自动向 Client 发布了 apis 这个 rpc 接口，Client 可以在 d.on 'remote' 事件中获得这个接口，然后调用 Server 提供的 transform 方法。

我在这里不会详细介绍 dnode，你可以去它的 Github Repos. 学习。如果想了解协议细节，我这有个中文版。

Hooked Version

我的需求是，要在 dnode Server 的 API 上，添加 Hook，这样我可以在每个 API 方法的运行前后，根据需要插入特定的 pre 或者 post 逻辑。这样的“注入”需求在后台开发中很常见。

Javascript 的Hook 库很多，我这里用的是 grappling-hook。用它的原因一方面是因为其功能比较丰富，另一方面是前一段研究 keystone.js，对这块比较熟悉。
Hook 一个对象方法的例子如下：

grappling = require 'grappling-hook'
instance = grappling.create()
instance.addHooks {
    transform: (s, cb) ->
        cb null, s.replace(/[aeiou]{2,}/, 'oo').toUpperCase()
}
instance.pre 'transform', (s, done) ->
    log 'before transform'
    done()
.post 'transform', (s, done) ->
    log 'after transform!'
    done()
instance.transform 'beep', (err,  res)-> console.log 'result', res

grappling-hook 的详细用法请自行读文档。
上面这段程序的输出结果是：

before transform
BOOP
after transform!

看起来可以工作了。
不过这里有一个问题，就是如果你把 instance 直接传递给 dnode (例如:d = dnode instance)是有问题的。因为 instance 除了有 transform 之外包含大量的辅助方法。这些东西可多会被 dnode 作为接口定义传递给 Client，这不是我们要的，因此要清理，例子代码如下：

...
apis =
    transform: (s, cb) ->
        log '--original func calls'
        cb null, s.replace(/[aeiou]{2,}/, 'oo').toUpperCase()

wrap = (apis) ->
    instance = grappling.create()
    instance.addHooks apis

    hooked = {}
    hooked[k] = instance[k] for k of apis
    { instance, hooked }

{instance, hooked} = wrap apis

# Equip middlewares
# Callback func MUST have same numbers of arguments as the origin
instance.pre 'transform', (s, done) ->
    log 'before transform'
    done()
.post 'transform', (s, done) ->
    log 'after transform!'
    done()
...

wrap 函数返回一个“干净的” hooked 过的 API 定义对象，这是可以被作为接口定义传递给 Client 的。同时，你可以通过 wrap 返回的另一个 instance 对象来慢慢添加你的 pre、post 方法。而且，这些你可以对同一个方法添加不止一个 pre、post hooks。

任务完成。如果想直接看可执行程序，源代码在这里：https://github.com/jacobbubu/dnodeHook 。