trigger的使用

看本篇之前可以相应阅读以下Trigger相关文章：

1. https://developer.salesforce.com/page/Trigger_Frameworks_and_Apex_Trigger_Best_Practices
2. http://chrisaldridge.com/triggers/lightweight-apex-trigger-framework/
3. http://www.sfdc99.com/2015/01/19/the-one-trigger-per-object-design-pattern/

以前以为salesforce中Trigger应用特别简单，所以没有列出来单独讲解，总结问题以后，发现还是很有必要将Trigger单独写出来一篇，让新手更好的了解Trigger。

一.Trigger介绍

Trigger在salesforce记录更改以前或者以后自动执行，可以执行以下几种情况：insert，update，delete，merge,upsert,undelete，一个trigger可以同时处理200条records,所以后面所讲的new和old变量的返回类型为List类型。
有两种类型的trigger：

• Before trigger通常用于在他们被保存在数据库以前更新或者校验数据;
• After trigger通常用于保存后访问系统的字段（Id等）.

trigger设计的思想为'One Trigger per Object',这种设计的好处详情查看上方第三个链接。所以一个Trigger可以同时设定很多种自动执行的触发器情况。eg：

    trigger GoodsTrigger on Goods__c (before delete, before update) {}

声明一个trigger针对Goods__c这个Object，当执行delete，update操作以前执行此trigger。
　　trigger可以有以下的执行类别：before insert,before update,before delete,after insert,after update,after delete,after undelete.
　　注意：trigger代码块中不能包含static关键字。
　　Trigger类中封装了很多的上下文的变量，这些变量在开发中经常用到。

• isExecuting:当前Apex代码的上下文环境为trigger环境，而不是VF等则返回true，否则返回false;
• isInsert:当前操作是否为正在执行添加操作，是返回true，否则返回false;
• isUpdate:当前操作是否为正在执行修改操作，是返回true，否则返回false;
• isDelete:当前操作是否为正在执行删除操作，是返回true，否则返回false;
• isBefore:当前操作是否为在save以前操作，是返回true，否则返回false;
• isAfter:当前操作是否为在save以后操作，是返回true，否则返回false;
• isUndelete:当前操作是否为在回收箱中回复数据以后操作，是返回true，否则返回false;
• new:返回sObject的记录的最新的数据的列表;
• newMap:返回一个ID映射到最新的数据列表的Map集合;
• old:返回sObject的记录修改以前的数据的列表;
• oldMap:返回一个ID映射到修改以前的数据列表的Map集合;
• size:在触发器中调用的数据总数，包括new和old。

这里主要描述一下new,newMap,old以及oldMap，因为他们有使用限制。

• new只适用于执行insert和update的trigger操作时并且类型为before的时候，才可以使用new返回列表;
• newMap只适用于before update,after insert以及after update的trigger操作时，才可以使用newMap返回map集合;
• old以及oldMap只适用于update和delete操作时，才可以使用old以及oldMap。

二.Trigger的使用

目前本人使用trigger主要有两种方式：第一种为直接使用trigger，在trigger内部块中写业务逻辑;第二种为通过Handler对trigger进行封装。以下是两种方式的介绍.
　　1. 直接在trigger内部块中写代码。代码描述为（在before和after trigger时输出debug信息）：

     trigger GoodsTrigger on Goods__c (before delete, before update) { 
        if(trigger.isBefore) {
          System.debug('=======before trigger========');
        } else {
          System.debug('=======after trigger========');
        }
    }

2. 通过Handler方式.通过Handler方式可以将每个Object创建其自身的Handler，将trigger业务逻辑写在自身的Handler里面，并通过Factory实例化，达到更好的可扩展性以及可读性，操作步骤如下所示：

• 创建TriggerHandler父类

    public abstract class TriggerHandler {   
      /* Trigger中，在运行时封装了new,newMap,old,oldMap变量
      * 其中，new和old返回类型为ListnewMap和oldMap返回类型为Map
      */        
      protected MapoldMap{get;set;}       
      protected MapnewMap{get;set;}       
      protected ListlistNew{get;set;}        
      protected ListlistOld{get;set;}
      /*
      *  封装trigger应该注意以下几点：
      * 1.trigger.new只能用在insert和update时，且trigger必须是before;
      * 2.trigger.old只能用在update和delete时;
      * 3.trigger.newMap只能用在before update,after insert和after update时;
      * 4.trigger.oldMap只能用在update和delete时.
      */
      public interface MyTrigger {
        void beforeInsert(SObject currentObject);
        void beforeUpdate(SObject oldSobject, SObject currentObject);
        void beforeDelete(SObject currentObject);
        void afterInsert(SObject currentObject);
        void afterUpdate(SObject oldSobject, SObject currentObject);
        void afterDelete(SObject currentObject);
        Boolean skipExecution();
      }
    }
  

• 创建相关对象的Handler，继承TriggerHandler并实现其MyTrigger接口,并实现相关方法。
  public class GoodsHandler extends TriggerHandler implements TriggerHandler.MyTrigger {
  public GoodsHandler() {
  // TODO Construcion
  }
  public void beforeInsert(SObject currentObject) {
  // TODO beforeInsert
  }
  public void afterInsert(SObject currentObject) {
  // TODO afterInsert
  }
  public void beforeUpdate(SObject oldSobject, SObject currentObject) {
  // TODO beforeUpdate
  }
  public void beforeDelete(SObject currentObject) {
  //TODO beforeDelete
  }
  public void afterUpdate(SObject oldSobject, SObject currentObject) {
  }
  public void afterDelete(SObject currentObject) {
  }
  public Boolean skipExecution() {
  return false;
  }
  }

• 创建TriggerFactory，此方法用于实例化Trigger的Handler并执行相应的before或者after操作，其中MyException为自定义异常类。
  public classMyExceptionextendsException {
  }

    public class TriggerFactory {
      /*
       * 实例化Handler,如果不跳过executeTrigger情况下，自动执行Trigger
      */
      public static void instanceHandler(Schema.SObjectType objectToken) {
        TriggerHandler.MyTrigger myTriggerHandler = getTriggerByObjectToken(objectToken);
        if(myTriggerHandler == null) {
          throw new MyException('无此object token的trigger');
        }
        if(!myTriggerHandler.skipExecution()) {
          executeTrigger(myTriggerHandler);
        }
      }
      /*
       * 执行trigger应该注意以下几点：
       * 1.trigger.new只能用在insert和update时，且trigger必须是before;
       * 2.trigger.old只能用在update和delete时;
       * 3.trigger.newMap只能用在before update,after insert和after update时;
       * 4.trigger.oldMap只能用在update和delete时.
      */
      public static void executeTrigger(TriggerHandler.MyTrigger myTriggerHandler) {
        //trigger分成isBefore以及isAfter
        if(Trigger.isBefore) {
          if(Trigger.isInsert) {
            for (SObject currentObject : Trigger.new) {
              myTriggerHandler.beforeInsert(currentObject);
            }
          }else if(Trigger.isUpdate) {
            for (SObject oldObject : Trigger.old) {
              myTriggerHandler.beforeUpdate(oldObject, Trigger.newMap.get(oldObject.Id));
            }
          }else if(Trigger.isDelete) {
            for (SObject currentObject : Trigger.old) {
              myTriggerHandler.beforeDelete(currentObject);
            }
          }
        } else {//isAfter
          if (Trigger.isInsert) {
            for (SObject currentObject : Trigger.new) {
              myTriggerHandler.afterInsert(currentObject);
            }
          } else if (Trigger.isUpdate) {
            for (SObject oldObject : Trigger.old) {
              myTriggerHandler.afterUpdate(oldObject, Trigger.newMap.get(oldObject.Id));
            }
          } else if (Trigger.isDelete){
            for (SObject currentObject : Trigger.old) {
              myTriggerHandler.afterDelete(currentObject);
            }
          }
        }
      }
      /*
      * 此方法用于返回具体某个object的trigger，如果添加一个object的trigger，在此方法添加相
      * 应的匹配处理，同时此object的Handler必须继承TriggerHandler以及实现TriggerHandler.
      * MyTrigger每个Object的Object Token不同，所以使用Token作为参数更加便捷
      * */
      public static TriggerHandler.MyTrigger getTriggerByObjectToken(Schema.SObjectType objectToken) {
        if(objectToken == Goods__c.sObjectType) {
          return new GoodsHandler();
        }
        // TODO  有其他Object需要使用trigger可以继承TriggerHandler实现其中MyTrigger然后在此处配置
        return null;
      }
    }
  

• 相应Object的trigger调用Factory的实例化方法
  trigger GoodsTrigger on Goods__c (before delete, before update) {
  TriggerFactory.instanceHandler(Goods__c.sObjectType);
  }

当Goods__c字段进行delete或者update操作时，save以前，会自动触发GoodsTrigger,GoodsTrigger会执行TriggerFactory的instanceHandler方法，此方法会调用执行instanceHandler以及executeTrigger函数，从而最终将Goods__c表trigger业务逻辑由GoodsHandler类处理。
　　 ** 总结 **：如果业务相对简单，可以采用第一种方式，开发效率高；如果业务相对复杂，第二种方式可以在相应的Handler模块更加明了的书写业务逻辑，方便后期维护以及有更好的可读性，有相关需求的童鞋可以copy代码，并修改其中TriggerFactory的getTriggerByObjectToken方法便可直接使用。