把Windows Recovery Environment安装到硬盘上

Technorati 标签: Windows, Reconvery Environment

把Windows Recovery Environment安装到硬盘上
Win7安装盘就是一个现成的WinRE
首先，从Vista的安装盘中复制2个文件到D:\盘根目录，这两个文件分别是：
\Boot\boot.sdi     ...3.02MB
\Source\boot.wim ...138MB
然后把boot.wim改名为winre.wim。
就是说象下面这样把2文件放D：盘的根目录：
D:\boot.sdi
D:\winre.wim
然后复制下列代码到记事本，另存为*.bat，做成一个批处理文件，右键管理员运行。
    @echo off
    REM
    REM {ad6c7bc8-fa0f-11da-8ddf-0013200354d8}
    REM
    set RAMDISK_OPTIONS={ad6c7bc8-fa0f-11da-8ddf-0013200354d8}
    REM
    REM {572bcd56-ffa7-11d9-aae0-0007e994107d}, GUID for the WinPE boot entry
    REM
    set WINPE_GUID={572bcd56-ffa7-11d9-aae0-0007e994107d}
    REM
    REM Set Timeout
    REM
    bcdedit.exe -timeout 5
    REM
    REM Create Ramdisk device options for the boot.sdi file
    REM
    bcdedit.exe -create %RAMDISK_OPTIONS% -d "Ramdisk Device Options" -device
    bcdedit.exe -set %RAMDISK_OPTIONS% ramdisksdidevice partition=D:
    bcdedit.exe -set %RAMDISK_OPTIONS% ramdisksdipath \boot.sdi
    REM
    REM Create WinRE boot entry
    REM
    bcdedit.exe -create %WINPE_GUID% -d "Windows RE 系统修复" -application OSLOADER
    bcdedit.exe -set %WINPE_GUID% device ramdisk=[D:]\winre.wim,%RAMDISK_OPTIONS%
    bcdedit.exe -set %WINPE_GUID% path \windows\system32\boot\winload.exe
    bcdedit.exe -set %WINPE_GUID% osdevice ramdisk=[D:]\winre.wim,%RAMDISK_OPTIONS%
    bcdedit.exe -set %WINPE_GUID% systemroot \windows
    bcdedit.exe -set %WINPE_GUID% detecthal yes
    bcdedit.exe -set %WINPE_GUID% nx optin
    bcdedit.exe -set %WINPE_GUID% winpe yes
    bcdedit.exe -displayorder %WINPE_GUID% /addlast
    echo Windows Recovery Environment安装完毕。
    pause

完毕。
（注意：Boot.wim建议用零售版光盘中提取，OEM版修改过可能无法通用。）
至于这两个文件为什么要放在D盘，是因为如果把WinRE放C盘将无法在WinRE环境下用Windows Complete PC恢复C:盘。;
剩下的事情就是把这2个文件+上只读隐藏系统属性，眼不见为净。;
还要注意的是这2个文件千万别用NTFS压缩。如果要卸载的话可以：
bcdedit.exe -displayorder {572bcd56-ffa7-11d9-aae0-0007e994107d} /remove
（当然用VistaBootPRO删掉WinRE菜单也一样），然后直接删掉boot.sdi和winre.wim就可以。
要修改菜单显示时间：计算机--属性---高级系统属性--启动和故障恢复--设置里面修改。
如果要把那2个文件放其他盘的话请自己修改批处理文件：
bcdedit.exe -set %RAMDISK_OPTIONS% ramdisksdidevice partition=D:
bcdedit.exe -set %WINPE_GUID% device ramdisk=[D:]\winre.wim,%RAMDISK_OPTIONS%
bcdedit.exe -set %WINPE_GUID% osdevice ramdisk=[D:]\winre.wim,%RAMDISK_OPTIONS%
上面3行中的D:改成相应盘符。
由于是通过RAMdisk方式载入WinRE镜像，所以winRE环境下可以格式化C:甚至WinRE文件所在盘。
对于在WinPE下用Ghost32进行备份还原的来说，可以放心把WinPE放C：盘，备份恢复C盘都没问题，这就是Ramedisk方式引导的优势。
对于没有DVD刻录机的来说，也可以在WinRE下格式化C：盘全新安装Vista单系统，先把安装文件释放到硬盘上，然后在WinRE下的命令行下运行安装程序。
其实WinRE也就是WinPE。
考虑到尽量简单，没有加入到Vista的F8菜单，而是做成双启动。如果直接加入Vista的F8菜单有个问题，WinRE放哪个盘，Vista的备份就会把它当系统盘必须一起备份。如果要加入F8菜单，可以最后加入这2条。
bcdedit.exe -set {default} recoverysequence %WINPE_GUID%
bcdedit.exe -set {default} recoveryenabled yes

如果是英文版的用户，引导菜单如果无法正常显示汉字的话，自己可以自定义这一行引号中的内容：
   bcdedit.exe -create %WINPE_GUID% -d "Windows RE 系统修复" -application OSLOADER