易语言实现链接mysql数据库，执行sql语句

 

.版本 2
.支持库 mysql

.程序集 窗口程序集_启动窗口

.子程序 _按钮1_被单击
.局部变量 ip, 文本型
.局部变量 端口, 整数型
.局部变量 用户, 文本型
.局部变量 密码, 文本型
.局部变量 数据库名, 文本型

ip ＝ 编辑框1.内容
端口 ＝ 到整数 (编辑框4.内容)
用户 ＝ 编辑框2.内容
密码 ＝ 编辑框3.内容
数据库名 ＝ 编辑框7.内容
句柄 ＝ 子_链接数据 (ip, 端口, 用户, 密码, 数据库名)
输出调试文本 (“句柄：” ＋ 到文本 (句柄))
按钮1.禁止 ＝ 真
按钮3.禁止 ＝ 假

.子程序 子_链接数据, 整数型
.参数 ip, 文本型
.参数 端口, 整数型
.参数 用户, 文本型
.参数 密码, 文本型
.参数 数据库名, 文本型
.局部变量 数据库句柄, 整数型


数据库句柄 ＝ 连接MySql (ip, 用户, 密码, 数据库名, 端口)
返回 (数据库句柄)

.子程序 _按钮2_被单击
.局部变量 SQL, 文本型
.局部变量 记录集句柄, 整数型
.局部变量 字段名, 文本型
.局部变量 循环计次, 整数型
.局部变量 字段值, 文本型
.局部变量 行数, 整数型

SQL ＝ 编辑框5.内容
编辑框6.加入文本 (“开始执行SQL。。。” ＋ #换行符)
输出调试文本 (“执行SQL:” ＋ SQL)
执行SQL语句 (句柄, SQL)
记录集句柄 ＝ 取记录集 (句柄)
输出调试文本 (“记录句柄集：” ＋ 到文本 (记录集句柄))
.计次循环首 (取字段总数 (记录集句柄), 循环计次)
    序号到字段名 (记录集句柄, 循环计次 － 1, 字段名)
    输出调试文本 (“字段名：” ＋ 字段名)
    编辑框6.加入文本 (字段名 ＋ “|”)
.计次循环尾 ()
编辑框6.加入文本 (#换行符)
行数 ＝ 取记录集行数 (记录集句柄)
.计次循环首 (行数, )
    .计次循环首 (取字段总数 (记录集句柄), 循环计次)
        序号到字段名 (记录集句柄, 循环计次 － 1, 字段名)
        读字段值 (记录集句柄, 字段名, 字段值)
        输出调试文本 (“字段值：” ＋ 字段值)
        编辑框6.加入文本 (字段值 ＋ “|”)
    .计次循环尾 ()
    编辑框6.加入文本 (#换行符)
    到下一行 (记录集句柄)
.计次循环尾 ()
释放记录集 (记录集句柄)


.子程序 _按钮3_被单击

断开MySql (句柄)
按钮1.禁止 ＝ 假
按钮3.禁止 ＝ 假