规划模型的典型例题

规划模型的典型例题

(1) 平板装货问题

有七种规格的包装箱要装到两辆平板车上。包装箱的宽和高是一样的，但厚度t (厘米)和重量w (公斤)是不同的。下表给出了每种包装箱的厚度，重量以及数量。
每辆平板车有10.2米的地方可用来装包装箱(象面包片那样)， 载重为40吨。由于地区货运的限制，对C5,C6,C7类包装箱的总数有一个特别的限制：这三类包装箱所占空间(厚度)不能超过302.7厘米。
问题要求：设计一种装车方案，使剩余的空间最小。

• 首先找到已知的参量
  • 各类型的包装的厚度：$t_i(i=1\dots 7)$。
  • 各类型的包装的重量：$w_i(i=1\dots 7)$。
  • 各类型包装的件数：$n_i(i=1\dots 7)$。
  • 平板车的空间：$Space=1020cm$。
  • 平板车的载重：$Weight=40000kg$。
  • 三类包装箱所占的空间上限：$Limit=302.7$。
• 设出需要使用的变量：
  • 第一辆车上装载的各类型包装的数量：$x_i(i=1\dots 7)$
  • 第二辆车上装载的各类型包装的数量：$y_i(i=1\dots 7)$
• 明确问题的要求：
  $\min \{2\times Space-\sum _{i=1}^7{t}_i{x}_i-\sum _{i=1}^7{t}_i{y}_i\}$
• 列出各限定方程：
  • $x_i+y_i\le n_i(i=1\dots 7)$
  • $\sum _{i=1}^7{w}_i(x_i+y_i)\le 40000$
  • $\sum _{i=1}^7{t}_i{x}_i\le 1020$
  • $\sum _{i=1}^7{t}_i{y}_i\le 1020$
  • $\sum _{i=5}^7{t}_i(x_i+y_i)\le 302.7$
• 下面给出Lingo的求解代码：

    model: !程序由model开始，由end结束;
    sets:  !sets开始设置变量，endsets结束变量设置;
    num/1..7/:t,w,n,x,y; !定义5个数组分别为t,w,n,x,y
    endsets
    data:  !数据设置由data开始，由enddata结束;
    t=48.7,52.0,61.3,72.0,48.7,52.0,64.0;
    w=2000,3000,1000,500,4000,2000,1000;
    n=8,7,9,6,6,4,8;
    enddata
    min=(1020-@sum(num:t*x))+(1020-@sum(num:t*y));!说明需要优化的为min;
    !以下是进行条件限制的量
    @sum(num:t*x)<=1020;
    @sum(num:t*y)<=1020;
    @sum(num:w*x)<=40000;
    @sum(num:w*y)<=40000;
    @for(num(i):x(i)+y(i)<=n(i));
    @sum(num(i)|i#ge#5#and#i#le#7:(x(i)+y(i))*t(i))<=302.7;
    @for(num:@gin(x));
    @for(num:@gin(y));
    end

 

(2) 选修课策略问题

某学校规定，运筹学专业的学生毕业时必须至少学习过两门数学课、三门运筹学课和两门计算机课。这些课程的编号、名称、学分、所属类别和先修课要求如下表所示。
问题：
1.毕业时学生最少可以学习这些课程中哪些课程?
2.如果某个学生既希望选修课程的数量少，又希望所获得的学分多，他可以选修哪些课程？

• 找到已知参量：
  • 各个课程$x_i(i=1\dots 9)$进行$0,1$参量的设定，选择为$1$，未选择为$0$。
  • 各课程的学分$scor{e}_i(i=1\dots 9)$。

问题1

• 明确问题的要求：
  • $min\sum _{i=1}^9{x}_i$(保证课程的学习数量最少)
• 列出各限定方程：
  • 首先保证满足数学两门，运筹学三门，计算机两门。
    • $\sum _{i=1}^5{x}_i\ge 2$
    • $x_3+x_5+x_6+x_8+x_9\ge 3$
    • $x_4+x_6+x_7+x_9\ge 2$
  • 再保证先修课的要求。⭐️这里采取的方法是：如果$x_a$是$x_b$的先修课，则$x_a\ge x_b$。
    • $x_3\le x_1$
    • $x_3\le x_2$
    • $x_4\le x_7$
    • $x_5\le x_1$
    • $x_5\le x_2$
    • $x_6\le x_7$
    • $x_8\le x_5$
    • $x_9\le x_1$
    • $x_9\le x_2$
• 下面给出Lingo的求解方程：

  model:
  sets:
  num/1..9/:x;
  endsets
  min=@sum(num(i):x(i));
  x(3)<=x(1);
  x(3)<=x(2);
  x(4)<=x(7);
  x(5)<=x(1);
  x(5)<=x(2);
  x(6)<=x(7);
  x(8)<=x(5);
  x(9)<=x(1);
  x(9)<=x(2);
  @sum(num(i)|i#ge#1#and#i#le#5:x(i))>=2;
  x(3)+x(5)+x(6)+x(8)+x(9)>=3;
  x(4)+x(6)+x(7)+x(9)>=2;
  @for(num:@bin(x));
  end

可以知道优化的结果为6，也就是最少上6门课。

问题2

• 明确问题的要求：
  • $\max \{\sum _{i=1}^{9}scor{e}_i\ast x_i\}$。
• 增加的条件：
  • $\sum _{i=1}^9{x}_i=6$，保证选课的数量最少。
• 下面给出Lingo的代码

  model:
  sets:
  num/1..9/:x,score;
  endsets
  data:
  score=5,4,4,3,4,3,2,2,3;
  enddata
  max=@sum(num(i):score(i)*x(i));
  @sum(num(i):x(i))=6;
  x(3)<=x(1);
  x(3)<=x(2);
  x(4)<=x(7);
  x(5)<=x(1);
  x(5)<=x(2);
  x(6)<=x(7);
  x(8)<=x(5);
  x(9)<=x(1);
  x(9)<=x(2);
  @sum(num(i)|i#ge#1#and#i#le#5:x(i))>=2;
  x(3)+x(5)+x(6)+x(8)+x(9)>=3;
  x(4)+x(6)+x(7)+x(9)>=2;
  @for(num:@bin(x));
  end

 

(3) 最优组队问题

某车间要参加单位举办的技术操作比赛，比赛设有5个单项和一个全能项目（同时参加5个单项）,14人参加。
如果比赛规定：
(1)每个车间可派14人参加比赛，每人至少参赛一项；
(2)参加比赛的队员中必须有3人参加全能比赛，其余队员参加单项比赛，且参加每个单项比赛的队员数不得超过6人（不包括全能队员）；
(3)参加全能的队员不能参加单项；
(4)参加单项比赛的队员至多可以参加3个单项；
(5)参加单项比赛的队员得分是其参加项目得分之和，参加全能比赛的队员得分是其参加项目得分和的4/5，车间的得分是车间所有参赛队员得分之和。
问如何安排参加比赛最好？

• 找到已知各参量
  • 参加单项的队员：$x_{ij}(i=1\dots 14,j=1\dots 5)$。(参加记为1，未参加记为0)。
  • 参加全能的队员：$y_i(i=1\dots 14)$。(这里保证参加过全能的队员不再出现在参加过单项的队员中，并且参加记为1，未参加记为0)。
  • 队员各比赛的期望得分为$scor{e}_{ij}(i=1\dots 14,j=1\dots 5)$。
• 明确问题的要求
  明显最好的参赛结果就是尽可能的得到一个较高的分数。
  $\max \{\sum _{i=1}^{14}\sum _{j=1}^5{x}_{ij}\times scor{e}_{ij}+\frac{4}{5}\sum _{i=1}^{14}{y}_i(\sum _{j=1}^{5}scor{e}_{ij})\}$
• 列出各限定方程
  • $y_i+\sum _{j=1}^5{x}_{ij}\ge 1(i=1\dots 14)$(保证每个人至少参加一项比赛)。
  • $\sum _{i=1}^{14}{y}_i=3$（保证参加全能比赛的人数必须为3人)。
  • $\sum _{j=1}^{14}{x}_{ij}\le 6(i=1\dots 5)$(保证每一个单项比赛参加的人数都不超过6人)。
  • $\sum _{i=1}^5{x}_{ij}\le 3(j=1\dots 14)$(保证每个参加单项比赛的人最多参加3项)。