Apktool 工具反编译APK

工具下载：https://ibotpeaches.github.io/Apktool/install/

 

步骤一：下载工具jar包：apktool_2.x.x.jar；

步骤二：将待反编译的Apk放置相同目录；

步骤三：新建apktool.bat脚本文件放置相同目录；

步骤四：执行同目录下的start.bat脚本文件；（先修改脚本内的apk名称再执行）

 

start.bat脚本文件内容：

apktool d %~dp0app-debug.apk

 

apktool.bat脚本文件内容：

@echo off
setlocal
set BASENAME=apktool_
chcp 65001 2>nul >nul

rem Find the highest version .jar available in the same directory as the script
setlocal EnableDelayedExpansion
pushd "%~dp0"
if exist apktool.jar (
    set BASENAME=apktool
    goto skipversioned
)
set max=0
for /f "tokens=1* delims=-_.0" %%A in ('dir /b /a-d %BASENAME%*.jar') do if %%~B gtr !max! set max=%%~nB
:skipversioned
popd
setlocal DisableDelayedExpansion

rem Find out if the commandline is a parameterless .jar or directory, for fast unpack/repack
if "%~1"=="" goto load
if not "%~2"=="" goto load
set ATTR=%~a1
if "%ATTR:~0,1%"=="d" (
    rem Directory, rebuild
    set fastCommand=b
)
if "%ATTR:~0,1%"=="-" if "%~x1"==".apk" (
    rem APK file, unpack
    set fastCommand=d
)

:load
java -jar -Duser.language=en -Dfile.encoding=UTF8 "%~dp0%BASENAME%%max%.jar" %fastCommand% %*

rem Pause when ran non interactively
for /f "tokens=2" %%# in ("%cmdcmdline%") do if /i "%%#" equ "/c" pause