汇编入门---8255IO控制LED灯实验

汇编继续，献上8255 IO控制LED灯实验代码

（1）8255 A口输出控制流水灯，B口输入，B口最低位控制流水灯流向

;Made by X-Ray龙
;8255流水灯显示实验


IOY0         EQU   3000H          ;片选IOY0对应的端口始地址
MY8255_A     EQU   IOY0+00H*4     ;8255的A口地址
MY8255_B     EQU   IOY0+01H*4     ;8255的B口地址
MY8255_C     EQU   IOY0+02H*4     ;8255的C口地址
MY8255_MODE  EQU   IOY0+03H*4     ;8255的控制寄存器地址

STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

DATA SEGMENT 
LA      DB  ?                     ;定义数据变量
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA

START: MOV AX,DATA
       MOV DS,AX
       
       MOV DX,MY8255_MODE         ;初始化8255工作方式
       MOV AL,82H                 ;工作方式0，A口输出，B口输入
       OUT DX,AL

       MOV  LA,01H
LOOP1: 
       MOV  DX,MY8255_B       
       IN   AL,DX                 ;读B口的一字节数据内存放到AL中
       MOV  BL,AL
       TEST BL,00000001B          ;判断B口最低位0或1，是0则跳C1左循环，是1则跳C2右循环
       JZ   C1
       JMP  C2

       
C1:    MOV  AL,LA                 ;左循环，用变量LA来存放上一次移位后的数据
       CALL DALLY                 ;延时，方便人眼观察出灯的变化
       MOV  DX,MY8255_A
       OUT  DX,AL
       ROL  AL,1
       MOV  LA,AL
       JMP  C3
       
C2:    MOV  AL,LA                 ;右循环
       CALL DALLY
       MOV  DX,MY8255_A
       OUT  DX,AL
       ROR  AL,1
       MOV  LA,AL
       JMP  C3
       
C3:    MOV AH,1                   ;判断是否有按键按下
       INT 16H
       JZ  LOOP1                  ;无按键则跳回继续循环，有则退出

QUIT:  MOV AX,4C00H               ;结束程序退出
       INT 21H

DALLY PROC NEAR                   ;软件延时子程序
       PUSH CX
       PUSH AX
       MOV  CX,0FFFH
D1:    MOV  AX,0FFFFH
D2:    DEC  AX
       JNZ  D2
       LOOP D1
       POP  AX
       POP  CX
       RET
DALLY ENDP

CODE ENDS
     END START

      （2） A口输出控制LED,B口输入由开关控制高低电平，实现开关控制LED灯亮灭，同时把八位LED状态回显到屏幕

;Made by X-Ray龙
;8255基本输入输出实验


IOY0         EQU   3000H           ;片选IOY0对应的端口始地址
MY8255_A     EQU   IOY0+00H*4     ;8255的A口地址
MY8255_B     EQU   IOY0+01H*4     ;8255的B口地址
MY8255_C     EQU   IOY0+02H*4     ;8255的C口地址
MY8255_MODE  EQU   IOY0+03H*4     ;8255的控制寄存器地址

STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

CODE SEGMENT
        ASSUME CS:CODE

START: MOV DX,MY8255_MODE         ;初始化8255工作方式
       MOV AL,82H                 ;工作方式0，A口输出，B口输入
       OUT DX,AL

LOOP1: MOV DX,MY8255_B            ;读B口
       IN  AL,DX
       MOV DX,MY8255_A            ;写A口
       OUT DX,AL

       MOV CX,0008H
       MOV BL,10000000B
C1:    TEST AL,BL                 
       JZ   C2
       CALL SHOW1                 ;显示1
C2:    TEST AL,BL
       JNZ  C3
       CALL SHOW2                 ;显示0     
C3:    SHR BL,1
       LOOP C1
       
       CALL CHANGE                ;换行
       MOV AH,1                   ;判断是否有按键按下
       INT 16H
       JZ  LOOP1                  ;无按键则跳回继续循环，有则退出

QUIT:  MOV AX,4C00H               ;结束程序退出
       INT 21H
       
SHOW1  PROC NEAR
       PUSH AX
       MOV AH,02H
       MOV DL,31H
       INT 21H
       POP AX
       RET 
SHOW1  ENDP
       
SHOW2  PROC NEAR
       PUSH AX
       MOV AH,02H
       MOV DL,30H
       INT 21H 
       POP AX         
       RET 
SHOW2  ENDP   

CHANGE PROC NEAR 
       PUSH AX
       MOV  AH,02H
       MOV  DL,0AH
       INT  21H
       MOV  AH,02H
       MOV  DL,0DH
       INT  21H
       POP  AX   
       RET
CHANGE ENDP        

CODE ENDS
     END START