idea通过数据库生成java实体类（lombok版）

使用原因：很多插件其实都提供了根据数据库生成实体类的功能，但是都不够简洁且不适合自己去自定义样式，而idea提供了能够自定义生成实体类的脚本，所以非常适合有代码洁癖的程序yuan们~
使用前提：需要lombok插件（这个插件的用途就是能让代码更简洁，减少多余的工作量，这里使用了它的@Data注解，它会为我们提供get set等方法），如果没有就需要适当修改下脚本，生成get set方法。
如何使用：
1. 连接数据库, 使用idea自带的插件Database

 

2. 点击表名，右键。Scripted Extensions   =>  Generate POJOs.groovy
3. 选择生成的实体类的位置

4. 自定义的实体类已生成，其中@Data为我们生成了基本的get set toString方法，@Id注解在tk.mybatis插件中需要使用到，@ApiModelProperty注解生成swagger文档

 

Generate POJOs.groovy 脚本解释（可自定义，稍微百度下语法就会了，也可以直接使用我这个）：
import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

/*
 * Available context bindings:
 *   SELECTION   Iterable
 *   PROJECT     project
 *   FILES       files helper
 */

packageName = "com.topex.admin.entity;"    // 此处指定包路径，也就对应实体类中的package com.topex.admin.entity;
typeMapping = [    // 此处指定对应的类型映射，如下：数据库中bigint对应生成java的Long，int|tinyint生成Integer...
        (~/(?i)bigint/)                      : "Long",
        (~/(?i)int|tinyint/)                 : "Integer",
        (~/(?i)float|double|decimal|real/): "java.math.BigDecimal",
        (~/(?i)date|datetime|timestamp/)       : "java.util.Date",
        (~/(?i)time/)                     : "java.sql.Time",
        (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
  SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
  def className = javaName(table.getName(), true)
  def fields = calcFields(table)
  new PrintWriter(new OutputStreamWriter(new FileOutputStream( new File(dir, className + ".java")), "utf-8")).withPrintWriter { out -> generate(out, className, fields) }
}

def generate(out, className, fields) {   // 从这里开始，拼实体类的具体逻辑代码
  out.println "package $packageName"
  out.println ""
  out.println ""
  out.println "import lombok.Data;"     // 因为我使用了lombok插件，使用到了Data注解，所以在引包时加了这一行
  out.println "import io.swagger.annotations.ApiModelProperty;"   // 同上，使用了swagger文档，所以引入到需要的注解
  out.println "import javax.persistence.Id;"  // tk.mybatis插件需用时需要@id注解，所以引入，不需要就去掉
  out.println ""
  out.println "@Data"
  out.println "public class $className {"
  out.println ""
  int i = 0
  fields.each() {   // 遍历字段，按下面的规则生成
    // 输出注释，这里唯一的是id特殊判断了一下，如果判断it.name == id, 则多添加一行@Id
    if (it.name == "id") {
      if (!isNotEmpty(it.commoent)) {
        out.println "\t/**"
        out.println "\t * 主键id"
        out.println "\t */"
        out.println "\t@ApiModelProperty(value = \"主键id\", position = ${i})"
      }
      out.println "\t@Id"
    }
    if (isNotEmpty(it.commoent)) {
      out.println "\t/**"
      out.println "\t * ${it.commoent}"
      out.println "\t */"
      out.println "\t@ApiModelProperty(value = \"${it.commoent}\", position = ${i})"
    }
    if (it.annos != "") out.println "  ${it.annos}"
    out.println "\tprivate ${it.type} ${it.name};"
    out.println ""
    i++
  }
  out.println ""
  out.println "}"
}

def calcFields(table) {
  DasUtil.getColumns(table).reduce([]) { fields, col ->
    def spec = Case.LOWER.apply(col.getDataType().getSpecification())
    def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
    fields += [[
                       name : javaName(col.getName(), false),
                       type : typeStr,
                       commoent: col.getComment(),
                       annos: ""]]
  }
}

def isNotEmpty(content) {
  return content != null && content.toString().trim().length() > 0
}

def javaName(str, capitalize) {
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
          .collect { Case.LOWER.apply(it).capitalize() }
          .join("")
          .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}
--------------------- 
作者：原野灬 
来源：CSDN 
原文：https://blog.csdn.net/lp2388163/article/details/86480480 
版权声明：本文为博主原创文章，转载请附上博文链接！