Erlang 日期和时间处理、时间戳转换

获取当前时间

erlang:now()得到的是从1970年1月1日零时起，到现在经过的时间，结果为{MegaSecs, Secs, MicroSecs}。有个问题要注意，还有另外一个函数可以实现同样的功能：os:timestamp()

那么erlang:now()和os:timestamp()的区别是什么？

erlang的解释如下：

erlang:now()

If you do not need the return value to be unique and monotonically increasing, use os:timestamp/0 instead to avoid some overhead.

os:timestamp()

The difference is that this function returns what the operating system thinks (a.k.a. the wall clock time) without any attempts at time correction. The result of two different calls to this function is not guaranteed to be different.

大致的意思是：os:timestamp()获取到的时间更接近于操作系统时间，erlang:now()每次获取都会生成唯一的时间，看来erlang:now()在实现上对时间多做了一个校正，相对os:timestamp()有点失真，同时也会有多余的开销。但是erlang:now()每次都生成唯一的值，有时候对我们来说也是一大利好的

获取当前时间戳

timestamp() ->
    {M, S, _} = os:timestamp(),
    M * 1000000 + S.

获取当前时间

% 本地时间
local_time() ->
    calendar:local_time().

% 世界时间
world_time() ->
    calendar:universal_time().

获取年月日，时分秒

1> {{Year, Month, Day}, {Hour, Minite, Second}} = calendar:local_time().
{{2013,11,13},{20,10,10}}
2> Day.
13
3> Second.
10

时间转换

% 秒转时间
11> calendar:seconds_to_daystime(86000).
{0,{23,53,20}}
12> calendar:seconds_to_daystime(86400).
{1,{0,0,0}}
13> calendar:seconds_to_daystime(1086400).
{12,{13,46,40}}

% 时间转秒
14> calendar:time_to_seconds({23,53,20}).
86000

时间与时间戳的转换

% 时间转时间戳，格式：{{2013,11,13}, {18,0,0}}
datetime_to_timestamp(DateTime) ->
    calendar:datetime_to_gregorian_seconds(DateTime) -
       calendar:datetime_to_gregorian_seconds({{1970,1,1}, {0,0,0}}).

% 时间戳转时间
timestamp_to_datetime(Timestamp) ->
    calendar:gregorian_seconds_to_datetime(Timestamp +
      calendar:datetime_to_gregorian_seconds({{1970,1,1}, {0,0,0}})).

时间格式化

-module(print_time).
-export([format_utc_timestamp/0]).
format_utc_timestamp() ->
    TS = {_,_,Micro} = os:timestamp(),
    {{Year,Month,Day},{Hour,Minute,Second}} = 
	calendar:now_to_universal_time(TS),
    Mstr = element(Month,{"Jan","Feb","Mar","Apr","May","Jun","Jul",
			  "Aug","Sep","Oct","Nov","Dec"}),
    io_lib:format("~2w ~s ~4w ~2w:~2..0w:~2..0w.~6..0w",
		  [Day,Mstr,Year,Hour,Minute,Second,Micro]).

编译这个模块，运行如下：

1> io:format("~s~n",[print_time:format_utc_timestamp()]).
29 Apr 2009  9:55:30.051711

解决时区问题

我们通过 erlang:now() 或者 os:timestamp() 获取到的时间都是标准世界时间，如果直接转成时间戳将会有偏差。

所以，erlang提供了很多 calendar:xxx_local_xxx 的方法用来做转换，使用时可以注意。见calendar文档

15> calendar:now_to_universal_time(erlang:now()).
{{2015,3,11},{16,43,48}}
16> calendar:now_to_local_time(erlang:now()).
{{2015,3,12},{0,44,13}}
17> calendar:universal_time_to_local_time({{1970,1,1}, {0,0,0}}).
{{1970,1,1},{8,0,0}}

2015/3/12 补充解决时区问题
参考：http://blog.csdn.net/mycwq/article/details/15813753