在boot目录下主要有bootsect.s,head.s,setup.s三个汇编文件,三个汇编文件完成了启动引导的流程,过程图如下图所示:
1、bootsect.s程序:
bootsec.s是磁盘引导块程序,驻留在磁盘的第一个扇区中(引导扇区,0磁道,0磁头,第一个扇区)。
2、setup.s程序
setup.s是一个操作系统加载程序,它的主要作用是利用ROM BIOS中断读取机器系统数据,并将这些数据保存到0x90000开始的位置。
3、head.s程序
从这里开始,内核完全都是在保护模式下运行了。
目录:
1.1、代码分析:
entry start ! 告知连接程序,程序从start 标号开始执行。
start: ! 47--56 行作用是将自身(bootsect)从目前段位置0x07c0(31k)
mov ax,#BOOTSEG ! 将ds 段寄存器置为0x7C0;
mov ds,ax
mov ax,#INITSEG ! 将es 段寄存器置为0x9000;
mov es,ax
mov cx,#256 ! 移动计数值=256 字;
sub si,si ! 源地址 ds:si = 0x07C0:0x0000
sub di,di ! 目的地址 es:di = 0x9000:0x0000
rep ! 重复执行,直到cx = 0
movw ! 移动1 个字;
jmpi go,INITSEG ! 间接跳转。这里INITSEG 指出跳转到的段地址。
1.2、bootsect.s文件读入内存示图
1.3、ds,es和ss端处设置
go: mov ax,cs ! 将ds、es 和ss 都置成移动后代码所在的段处(0x9000)。
mov ds,ax !由于程序中有堆栈操作(push,pop,call),因此必须设置堆栈。
mov es,ax
1.4、移动堆栈指针程序分析
mov ss,ax
mov sp,#0xFF00 ! arbitrary value >>512
2.1、磁盘平面图:
2.2、启动文件在磁盘中位置示意图:
2.3、setup读入内存示意图:
2.4、setup读入内存代码分析
mov dx,#0x0000 ! drive 0, head 0
mov cx,#0x0002 ! sector 2, track 0
mov bx,#0x0200 ! address = 512, in INITSEG
mov ax,#0x0200+SETUPLEN ! service 2 , 读4个扇区
int 0x13 ! read it
jnc ok_load_setup ! ok - continue
mov dx,#0x0000
mov ax,#0x0000 ! reset the diskette
int 0x13
j load_setup
2.5、setup读入参数代码分析
ok_load_setup:
mov dl,#0x00
mov ax,#0x0800 ! AH=8 is get drive parameters
int 0x13
mov ch,#0x00
seg cs ! 表示下一条语句的操作数在cs 段寄存器所指的段中。
mov sectors,cx ! 保存每磁道扇区数。
mov ax,#INITSEG
mov es,ax ! 因为上面取磁盘参数中断改掉了es 的值,这里重新改回。
mov ah,#0x03 ! read cursor pos
xor bh,bh ! 读光标位置。
int 0x10
mov cx,#24 ! 共24 个字符。
mov bx,#0x0007 ! page 0, attribute 7 (normal)
mov bp,#msg1 ! 指向要显示的字符串。
mov ax,#0x1301 ! write string, move cursor
int 0x10 ! 写字符串并移动光标。
msg1:
.byte 13,10 ! 回车、换行的ASCII 码。
.ascii "Loading system ..."
.byte 13,10,13,10 ! 共24 个ASCII 码字符。
.org 508 ! 表示下面语句从地址508(0x1FC)开始,所以root_dev
! 在启动扇区的第508 开始的2 个字节中。
root_dev:
.word ROOT_DEV ! 这里存放根文件系统所在的设备号(init/main.c 中会用)。
boot_flag:
.word 0xAA55 ! 硬盘有效标识。
4.1示图
4.2 代码分析
SYSSIZE = 0x3000 ! 指编译连接后system 模块的大小。参见列表1.2 中第92 的说明。
! setup 程序从这里开始;
SYSSEG = 0x1000 ! system loaded at 0x10000 (65536).
! system 模块加载到0x10000(64 kB)处;
ENDSEG = SYSSEG + SYSSIZE ! where to stop loading
!--------------------------------------------------
mov ax,#SYSSEG
mov es,ax ! segment of 0x010000 ! es = 存放system 的段地址。
call read_it ! 读磁盘上system 模块,es 为输入参数。
call kill_motor ! 关闭驱动器马达,这样就可以知道驱动器的状态了。
4.3、read_it
//待分析
4.4、关闭软驱的马达
kill_motor:
push dx
mov dx,#0x3f2 ! 软驱控制卡的驱动端口,只写。
mov al,#0 ! A 驱动器,关闭FDC,禁止DMA 和中断请求,关闭马达。
outb ! 将al 中的内容输出到dx 指定的端口去。
pop dx
ret
5.1、设备号介绍
5.2、内存地址偏移代码:
.org 508 ! 表示下面语句从地址508(0x1FC)开始,所以root_dev
! 在启动扇区的第508 开始的2 个字节中。
root_dev:
.word ROOT_DEV ! 这里存放根文件系统所在的设备号(init/main.c 中会用)。
boot_flag:
.word 0xAA55 ! 硬盘有效标识。
5.3、内存地址偏移如图所示:
5.4 代码分析
seg cs
mov ax,root_dev ! 将根设备号
cmp ax,#0
jne root_defined
seg cs
mov bx,sectors ! 取上面第88 行保存的每磁道扇区数。如果sectors=15
mov ax,#0x0208 ! /dev/ps0 - 1.2Mb
cmp bx,#15 ! 判断每磁道扇区数是否=15
je root_defined ! 如果等于,则ax 中就是引导驱动器的设备号。
mov ax,#0x021c ! /dev/PS0 - 1.44Mb
cmp bx,#18
je root_defined
undef_root: ! 如果都不一样,则死循环(死机)。
jmp undef_root
root_defined:
seg cs
mov root_dev,ax ! 将检查过的设备号保存起来。
jmpi 0,SETUPSEG ! 跳转到0x9020:0000(setup.s 程序的开始处)。