以太坊测试网ERC20发币

1.准备

在发Token前，你先的确定一下几点：

1. Token的名称
2. Token的标识
3. Token的小数位
4. Token发型量

2.安装MetaMask钱包

在Chrome浏览器中安装MetaMask之后，登陆Metamask， 左上角选择Ropsten。如下图：

3.测试网申请eth

• 给我们的测试账号申请点 eth来测试，如下图点击 buy按钮，再点击ropsten test faucet。
  
  

• 会打开 faucet metamask 网站，点击
  request 1 eth from faucet。成功后会生成 交易记录。
  
• 可以查看到我们的测试账户上已经有了eth可以用了。

 

4.编译合约

打开Solidity Remix Compiler ,remix 是一个在线编译器可以帮我们把智能合约直接发布到以太坊上。

选择Use previous version

4.1 拷贝合约

拷贝以下ERC20合约

pragma solidity ^0.4.24;


/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

    /**
    * @dev Multiplies two numbers, throws on overflow.
    */
    function mul(uint256 a, uint256 b) internal pure returns (uint256 c) {
        // Gas optimization: this is cheaper than asserting 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
        if (a == 0) {
            return 0;
        }

        c = a * b;
        assert(c / a == b);
        return c;
    }

    /**
    * @dev Integer division of two numbers, truncating the quotient.
    */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        // assert(b > 0); // Solidity automatically throws when dividing by 0
        // uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold
        return a / b;
    }

    /**
    * @dev Subtracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend).
    */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        assert(b <= a);
        return a - b;
    }

    /**
    * @dev Adds two numbers, throws on overflow.
    */
    function add(uint256 a, uint256 b) internal pure returns (uint256 c) {
        c = a + b;
        assert(c >= a);
        return c;
    }
}

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * See https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
    function totalSupply() public view returns (uint256);
    function balanceOf(address who) public view returns (uint256);
    function transfer(address to, uint256 value) public returns (bool);
    event Transfer(
        address indexed _from, 
        address indexed _to, 
        uint256 _value
    );
} 

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances.
 */
contract BasicToken is ERC20Basic {
    using SafeMath for uint256;

    mapping(address => uint256) balances;

    uint256 totalSupply_;

    /**
    * @dev Total number of tokens in existence
    */
    function totalSupply() public view returns (uint256) {
        return totalSupply_;
    }

    /**
    * @dev Transfer token for a specified address
    * @param _to The address to transfer to.
    * @param _value The amount to be transferred.
    */
    function transfer(address _to, uint256 _value) public returns (bool) {
        require(_to != address(0));
        require(_value <= balances[msg.sender]);

        balances[msg.sender] = balances[msg.sender].sub(_value);
        balances[_to] = balances[_to].add(_value);
        emit Transfer(msg.sender, _to, _value);
        return true;
    }

    /**
    * @dev Gets the balance of the specified address.
    * @param _owner The address to query the the balance of.
    * @return An uint256 representing the amount owned by the passed address.
    */
    function balanceOf(address _owner) public view returns (uint256) {
        return balances[_owner];
    }

}


/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
    function allowance(address owner, address spender)
        public view returns (uint256);

    function transferFrom(address from, address to, uint256 value)
        public returns (bool);

    function approve(address spender, uint256 value) public returns (bool);
    event Approval(
      address indexed _owner,
      address indexed _spender,
      uint256 _value
    );
}


/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * https://github.com/ethereum/EIPs/issues/20
 * Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

    mapping (address => mapping (address => uint256)) internal allowed;


    /**
    * @dev Transfer tokens from one address to another
    * @param _from address The address which you want to send tokens from
    * @param _to address The address which you want to transfer to
    * @param _value uint256 the amount of tokens to be transferred
    */
    function transferFrom(
        address _from,
        address _to,
        uint256 _value
    )
        public
        returns (bool)
    {
        require(_to != address(0));
        require(_value <= balances[_from]);
        require(_value <= allowed[_from][msg.sender]);

        balances[_from] = balances[_from].sub(_value);
        balances[_to] = balances[_to].add(_value);
        allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
        emit Transfer(_from, _to, _value);
        return true;
    }

    /**
    * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
    * Beware that changing an allowance with this method brings the risk that someone may use both the old
    * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
    * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
    * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    * @param _spender The address which will spend the funds.
    * @param _value The amount of tokens to be spent.
    */
    function approve(address _spender, uint256 _value) public returns (bool) {
        // avoid race condition 
        require((_value == 0) || (allowed[msg.sender][_spender] == 0), "reset allowance to 0 before change it's value.");
        allowed[msg.sender][_spender] = _value;
        emit Approval(msg.sender, _spender, _value);
        return true;
    }

    /**
    * @dev Function to check the amount of tokens that an owner allowed to a spender.
    * @param _owner address The address which owns the funds.
    * @param _spender address The address which will spend the funds.
    * @return A uint256 specifying the amount of tokens still available for the spender.
    */
    function allowance(
        address _owner,
        address _spender
    )
        public
        view
        returns (uint256)
    {
        return allowed[_owner][_spender]; 
    } 

} 

contract KHToken_StandardToken is StandardToken { 
    
    // region{fields}
    string public name;                         
    string public symbol;            
    uint8 public decimals;      
    uint256 public claimAmount;    

    // region{Constructor}
    // note : [(final)totalSupply] >> claimAmount * 10 ** decimals
    // example : args << "The Kh Token No.X", "KHTX", "10000000000", "18"
    constructor(
        string _token_name, 
        string _symbol, 
        uint256 _claim_amount, 
        uint8 _decimals
    ) public {
        name = _token_name;                              
        symbol = _symbol;     
        claimAmount = _claim_amount;                                     
        decimals = _decimals;
        totalSupply_ = claimAmount.mul(10 ** uint256(decimals)); 
        balances[msg.sender] = totalSupply_;   
        emit Transfer(0x0, msg.sender, totalSupply_); 
    }
}

contract KHToken_StandardToken_U is StandardToken { 
    
    // region{fields}
    string public name;                         
    string public symbol;            
    uint8 public decimals;      
    uint256 public claimAmount;    

    // region{Constructor}
    // note : [(final)totalSupply] >> claimAmount * 10 ** decimals
    // example : args << "The Kh Token No.X", "KHTX", "10000000000", "18"
    constructor(
        string _token_name, 
        string _symbol, 
        uint256 _claim_amount, 
        uint8 _decimals,
        address _initial_account
    ) public {
        name = _token_name;                              
        symbol = _symbol;     
        claimAmount = _claim_amount;                                     
        decimals = _decimals;
        totalSupply_ = claimAmount.mul(10 ** uint256(decimals)); 
        balances[_initial_account] = totalSupply_;   
        emit Transfer(0x0, _initial_account, totalSupply_); 
    }
}

4.2选择版本号

4.3点击开始编译

 

5.部署合约

5.1初始账号填自己的账号即可

填写

• Token的名称
• Token的标识
• Token的小数位
• Token发行量
• 初始账号

可以仿照左边截图的参数填写

最后点击transact

6.添加代币

代币地址填写合约地址，即完成添加，就可以看到啦

 

 

以上是测试网发币过程，当然主网发币也是相同的，不过需要消耗主网的eth