vb.net 教程 3-4 窗体编程 公共控件9 ListView 2

版权声明：本文为博主原创文章，转载请在显著位置标明本文出处以及作者网名，未经作者允许不得用于商业目的。
续前一节，本节主要从代码的角度讨论如何向ListView中添加、删除项目

 

ListView项目的添加、删除主要是通过 ListView.Items进行，

ListView.Items实际上是一个ListViewItemCollection类，提供了Add()、Insert()方法添加项目，以及Remove()、RemoveAt()方法删除项目，Clear()方法清除项目。

下面用实例代码来说明：

 

 

主要代码：

    Private Sub Form6_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        '设置样式到ComboBox1
        ComboBox1.Items.Add("LargeIcon")
        ComboBox1.Items.Add("Details")
        ComboBox1.Items.Add("List")
        ComboBox1.Items.Add("SmallIcon")
        ComboBox1.Items.Add("Tile")
        ComboBox1.Text = "LargeIcon"

        '获得图像并显示序号到ComboBox2
        For i As Integer = 0 To ImageListB.Images.Count
            ComboBox2.Items.Add(i)
        Next
        ComboBox2.Text = "0"

    End Sub

 

    Private Sub ComboBox1_SelectedIndexChanged(sender As Object, e As EventArgs) Handles ComboBox1.SelectedIndexChanged
        '根据选择来设置不同的显示样式
        Select Case ComboBox1.Text
            Case "LargeIcon"
                ListView1.View = View.LargeIcon
            Case "Details"
                ListView1.View = View.Details
            Case "List"
                ListView1.View = View.List
            Case "SmallIcon"
                ListView1.View = View.SmallIcon
            Case Else
                ListView1.View = View.Tile
        End Select
    End Sub

 

    '添加项目
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        '显示的文字
        Dim OptionName As String = TextBox1.Text
        '显示的图标
        Dim OptionIcon As Integer = Integer.Parse(ComboBox2.Text)

        '实例化一个ListViewItem
        Dim lvItem As New ListViewItem(OptionName, OptionIcon)
        '将ListViewItem加入到ListView中
        ListView1.Items.Add(lvItem)
    End Sub

 

    '清除项目
    Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
        ListView1.Items.Clear()
    End Sub

 

    '删除项目
    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        '获得选择的集合
        Dim selectId As ListView.SelectedIndexCollection
        selectId = ListView1.SelectedIndices
        '将集合里面的项目逐一删除
        For Each i As Integer In selectId
            ListView1.Items.RemoveAt(i)
        Next
    End Sub

或者：

    '删除项目
    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        '将选中的项目逐一删除
        For i As Integer = 0 To ListView1.SelectedItems.Count - 1
            ListView1.Items.RemoveAt(ListView1.SelectedItems(i).Index)
        Next
    End Sub

运行试一下，看似很正常

 

事实上有2个比较重大的问题：

1、从ImageList中添加图像序号的时候有问题，正确的代码是：

        For i As Integer = 0 To ImageListB.Images.Count - 1
            ComboBox2.Items.Add(i)
        Next

不知道大家注意到没有。

2、ListView默认是多选的，属性MultiSelect是True，当以上程序只选择一项时候，不会发生错误，但是当选择了多项的时候，就会报错：

 

这个原因，个人理解是，循环的时候，每一次删除后ListView1.SelectedItems.Count值都会减少1，减少到一定程度，就会导致SelectedItems()中的序号产生问题。

考虑只选择了2项进行删除的情况：

第一次 i=0,ListView1.SelectedItems.Count=2,ListView1.SelectedItems(i)中i=0，正确，可以删除

第二次 i=1,ListView1.SelectedItems.Count=1,ListView1.SelectedItems(i)中i=1，实际上，此时选中的项目只有一项了，其实序号是0，所以就出错了。

 

同理，看看选择了5项的情况：

第一次 i=0,ListView1.SelectedItems.Count=5,ListView1.SelectedItems(i)中i=0，0<5正确，可以删除
第二次 i=1,ListView1.SelectedItems.Count=4,ListView1.SelectedItems(i)中i=1，1<4正确，可以删除
第三次 i=2,ListView1.SelectedItems.Count=3,ListView1.SelectedItems(i)中i=2，2<3正确，可以删除
第四次 i=3,ListView1.SelectedItems.Count=2,ListView1.SelectedItems(i)中i=3，3<2显然不正确，出错

 

出错的时候可以将鼠标分别放在i 和 ListView1.SelectedItems.Count上，看看此时i是不是3，ListView1.SelectedItems.Count是不是为2。

大家认真理解一下。

那么该怎么修改呢？

 

只需要将循环倒这来就可以了：

 

    '删除项目
    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        '将选中的项目逐一删除
        For i As Integer = ListView1.SelectedItems.Count - 1 To 0 Step -1
            ListView1.Items.RemoveAt(ListView1.SelectedItems(i).Index)
        Next
    End Sub

 

这下再删除多项试一下，已经没有问题了。

 

最后看看运行结果：

不过好像还有问题，View=Details的时候什么都没有显示，留待下一次讲解。

 

 

 

学习更多vb.net知识，请参看 vb.net 教程 目录