【bat】做个一键连接网络打印机的bat

用途：大部分普通用户来说，并不知道怎么连接网络打印机（共享打印机还好）
好处：用户只需双击bat，输入打印机的IP地址，然后敲下回车即可连接（当然你也可以改成一键连接）
优势：相比点击驱动包的setup还要简单几倍，成功率也高（因为驱动安装包会不能搜索出不同网段的打印机，虽然是网络互通）

代码示例的型号是富士施乐的4475，请根据实际情况安装合适的驱动

第三部分，请按实际情况填写

此命令作用是登陆共享，因为公司多数是域环境，防止因本地账号登陆了电脑，导致无法进入共享获取驱动。

net use \\存放驱动的共享地址\ipc$ password /user:domain\user >nul

32位驱动INF安装文件。请根据型号选择确定

\\存放共享的地址\pridriver\4475 32\PCL\Win2000_XP\ApeosPort-V_C7775\FX6SOAL.inf

64位驱动INF安装文件。请根据型号选择确定

\\存放驱动的共享地址\pridriver\4475 64\PCL\x64\ApeosPort-V_C7775\FX6SOAL.inf

第三部分，请按实际情况填写

完整代码

rem 第一部分
@echo off 
echo. 
echo                 DocuCentre-V C4475打印机安装程序
echo. 
echo.继续请按是（Y）
echo.退出请按否（N）
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"
cls
rem 以上是申请管理员权限（无需再右键以管理员身份运行，但要具备管理员权限）


rem 第二部分
echo.
echo.
:input
set /p prnip=ip地址:
echo.开始安装，请耐心等候！
echo 检测IP地址
ping %prnip% -n 2 >nul
if errorlevel 1 goto no
if errorlevel 0 goto yes
:no
cls
echo IP地址输入错误，或与打印机网络连接出现问题，确认以上正确之后请重试。
goto input 
rem 以上部分仅仅只是防呆设置，是避免用户输入错误格式的IP地址而写的。因为仅仅只是ping一下并不能算很严谨的验证方法，但总比没有好。
:yes
echo IP地址输入正确！
rundll32 printui.dll,PrintUIEntry /dl /n "DocuCentre-V C4475"  /q
net stop spooler >nul
net start spooler >nul
xcopy /y "C:\Windows\System32\Printing_Admin_Scripts\zh-CN\prnport.vbs" "%temp%">nul
cscript %TEMP%\prnport.vbs -a -r IP_%prnip% -h %prnip% -o raw>nul
rem 设置打印机端口

rem 第三部分
echo 安装DocuCentre-V C4475打印机......
net use \\存放驱动的共享地址\ipc$ password /user:domain\user >nul
if /i %PROCESSOR_IDENTIFIER:~0,3%==x86 (
    echo. 检测系统为32位，安装兼容驱动
    rundll32 printui.dll,PrintUIEntry /if /b "DocuCentre-V C4475" /f "\\1存放共享的地址\pridriver\4475 32\PCL\Win2000_XP\ApeosPort-V_C7775\FX6SOAL.inf" /r "IP_%prnip%" /m "FX DocuCentre-V C4475 PCL 6"
) else (
    echo.检测系统为64位，安装兼容驱动
    rundll32 printui.dll,PrintUIEntry /if /b "DocuCentre-V C4475" /f "\\存放驱动的共享地址\pridriver\4475 64\PCL\x64\ApeosPort-V_C7775\FX6SOAL.inf" /r "IP_%prnip%" /m "FX DocuCentre-V C4475 PCL 6" 
)
if errorlevel 0 echo 打印机安装成功
rem 以上部分为安装驱动
echo.
echo.

rem 第四部分
echo 将这个打印机设置为默认打印机
rundll32 printui.dll,PrintUIEntry /y /n "DocuCentre-V C4475"
echo;打印机安装完成!
echo.
echo.部分情况可能需要打开“设备和打印机”界面，
echo.
echo.按F5或右键刷新之后才会看到打印机.
:end
echo.
echo.
echo;按任意键退出...
pause>nul